"course correction" by Lucian Smith

The story headline is "An Interactive High Heist"

Release along with cover art and the source text and a file of "Rough outside map." called "Aerie map.png".

The release number is 2.

After printing the banner text, say "For more information, try ABOUT and CREDITS." 

Include Response Assistant by Aaron Reed.
Include Version 7.1.1 of Hybrid Choices by AW Freyr.
Include Basic Screen Effects by Emily Short.
Include Version 6.0.220529 of Undo Output Control by Nathanael Nerode.

Use the American dialect, serial comma, and VERBOSE room descriptions.


When play begins:
	say "[i]Your mother needs you.  The whole village needs you.  You can do this.  You must do this.

[r]The mantra repeats in your head, pushing you on as you wheel in circles over the forest canopy, riding thermals to heights where none but other Falcon Clan members could see you.  And there's no more Falcon Clan in the Royal Aerie--you and the rest of your clan were all banished two years ago.  Three days ago, approaching from underneath worked, as none were expecting it.  But while technically successful, you failed to snatch your intended quarry: the Scroll of Health.  The sages had been unable to tell you what color capsa would hold it: you now know that it's not purple, gold, nor red.

By tonight, you will know.  You're not leaving without it."

[Rules and New Actions by Iron ChIF begins here.]
[Use authorial modesty.]

Book 0 Rules

To say i:
	say "[italic type]";
	
To say b:
	say "[bold type]";
	
To say r:
	say "[roman type]";

To say lb:
	say "[line break]";

To say pb:
	say "[line break][line break]";
	
To say nb:
	say "[run paragraph on]";

To say bstars:
	say "[lb]";
	center "*    *    *[pb]";

To say stars:
	center "*    *    *[pb]";



Chapter New Actions

Section Commenting

Commenting is an action out of world applying to one topic.

Report commenting:
	say "Noted.";[: [the topic understood].";]
	stop the action.

Understand "# [text]" as commenting.

To say comment_regex:
	say "<\p*#+=[']>"

After reading a command when the player's command matches the regular expression "^([comment_regex] ?)\S":
	let T be the "[player's command]";
	replace the regular expression "^[comment_regex] ?" in T with "# ";
	[say "(changed to '[T]')";]
	change the text of the player's command to T;

Section credits

Crediting is an action out of world applying to nothing.  Understand "credits" as Crediting.

Carry out Crediting:
	say "This game would not have been possible without the intense energy of @otistdog on the intfiction forums creating the idea of having an 'Iron ChIF' competition, nor without Ryan Veeder agreeing to be the 'Iron ChIF Inform 7' to compete against.
	
	Particular thanks go to my betatesters, Sarah Willson (day 1), Stephen Granade (day 2), Allyson Gray (day 3), and Dan 'inky' Shiovitz (day 4).  Allyson also contributed her testing skills and other suggestions to this release!  Thanks also to my son and brainstorming partner, Ellric Smith.
	
	Thanks also to the official judges for this competition: Chandler Groover, Victor Gijsbers, J. J. McC, Brian Rushton, and N. Cormier, and technical advisor Zed Lopez.  You all have been great, and your commentary has helped to improve this post-competition release.

	The cover art image is courtesy Greg Hume (Greg5030)/CC BY-SA 3.0
	
	Apologies to N. Cormier for letting her cats out backstage.  I forgot to check the spotlights!"

Section about

Abouting is an action out of world applying to nothing.  Understand "about" as abouting.

Carry out abouting:
	say "Thank you for playing 'course correction'!  A quick word about design philosophy.  The game has many obviously-bad endings, but by design they are all avoidable with a single >UNDO.  So, if anything happens that naturally takes more than one turn, it's probably something you'll have to deal with at some point.  There may be bugs that circumvent that design!  So keep multi-undo and/or save files at the ready.  There is also some choice-based branching in the game.  At the end of the game, a single >UNDO will no longer be sufficient to reach every ending.  If you're the kind of player that prefers to stick with the first ending you find, hopefully you'll find yours satisfying!  If you like exploring, multi-undo and save files are your friend.

	In honor of the many ways to solve a couple of the main puzzles of the game, 'course correction' has achievements!  You can list the ones you've gotten with >ACHIEVEMENTS, or list all possible achievements with >ACHIEVEMENTS FULL.  By default, you won't be notified when you get an achievement, but if you want to know, you can turn on (or off) notifications with >ACHIEVEMENTS ON/OFF.  Achievements persist across play sessions, but if you wish to start over from scratch, >ACHIEVEMENTS RESET will remove them all again.
	
	The original version of this game was written in five days for Episode One of Iron ChIF, where I (as the challenger) wrote this game while Ryan Veeder (the 'Iron ChIF Inform 7') wrote his own game ('The Van der Nagel Papyrus') based on the same prompt:  'a scroll that alters the world around it'.  This is the post-comp release, which fixes some bugs, clears up several points of confusion, and generally fills out the game to be more complete.
	
	Extensive discussion and commentary from that episode can be found on the intfiction.org web site, at
	
	https://intfiction.org/t/iron-chif-season-one-episode-1-lpsmith-vs-afterward-using-inform-7/78122

	and
	
	https://intfiction.org/t/iron-chif-season-one-episode-1-audience-commentary/79065/

	The source code can be found at

	https://github.com/luciansmith/IronChIF/[lb]"

Section Achievements

AchieveListing is an action out of world applying to nothing. Understand "achievements" as AchieveListing.

AchieveOning is an action out of world applying to nothing. Understand "achievements on" as AchieveOning.

AchieveOffing is an action out of world applying to nothing. Understand "achievements off" as AchieveOffing.

AchieveFulling is an action out of world applying to nothing. Understand "achievements full" as AchieveFulling.

AchieveResetting is an action out of world applying to nothing. Understand "achievements reset" as AchieveResetting.

An Achievement is a kind of thing.

The Trophy Room is a room.  The Trophy Room has an object called most_recent.  The most_recent of the Trophy Room is nothing.  The Trophy Room can be on, off, or full.  The Trophy Room is off.

Gaining An Achievement is a recurring scene.  Gaining An Achievement begins when the most_recent of the Trophy Room is not nothing.  Gaining An Achievement ends when the most_recent of the Trophy Room is nothing.

When Gaining An Achievement begins:
	let gained be the most_recent of the Trophy Room;
	if the gained is not in the Trophy Room:
		move the gained to the Trophy Room;
		if the Trophy Room is not off:
			say "[i]Achievement unlocked: [gained][first time] (To turn off achievement notification, enter >ACHIEVEMENTS OFF.  To see a list of your achievements, enter >ACHIEVEMENTS.)[only][r]";
	now the most_recent of the Trophy Room is nothing;
	write out achievements;


Carry out AchieveListing:
	if the number of objects in the Trophy Room is zero:
		say "You have yet to gain any achievements.";
	otherwise:
		say "You have gained the following achievements:[lb]";
		repeat with gained running through the achievements in the Trophy Room:
			say "* [gained]: [description of gained][lb]";
	if the Trophy Room is not full:
		say "[lb][i]Use ACHIEVEMENTS ON/OFF to turn on or off achievement notifications, or ACHIEVEMENTS FULL to list both gained and ungained achievements[r]."

Carry out AchieveOning:
	now the Trophy Room is on;
	say "'course correction' will now tell you when you've gained an achievement.";

Carry out AchieveOffing:
	now the Trophy Room is off;
	say "'course correction' will now give you achievements silently.";

Carry out AchieveFulling:
	now the Trophy Room is full;
	try AchieveListing;
	now the Trophy Room is on;
	let X be a random achievement in the Void;
	if X is nothing:
		say "There are no other achievements in the game!  Congratulations!";
	otherwise:
		say "You have yet to achieve the following:[lb]";
		repeat with awaiting running through all achievements in the Void:
			say "* [awaiting][lb]";

Carry out AchieveResetting:
	now everything in the Trophy Room is in the Void;
	write out achievements;
	say "Achievements have been reset."

Check requesting the score:
	try AchieveListing instead;

Table of Final Question Options (continued)
final question wording	only if victorious	topic	final response rule	final response activity
"get a list of the ACHIEVEMENTS you obtained"	true	"achievements"	endAchieveList rule	--
--	true	"achievements"	endAchieveList rule	--
--	true	"achievements full"	endAchieveListFull rule	--

This is the endAchieveList rule:
	try achieveListing;

This is the endAchieveListFull rule:
	try achieveFulling;

Section Achievement File

The File of Achieving (owned by another project) is called "courseAchievements".

Table of Achieving
gained (text)
with 20 blank rows

To fill the Table of Achieving from the Trophy Room:
	repeat with X running through achievements in the Trophy Room:
		choose a blank row in the Table of Achieving;
		Now the gained entry is the printed name of X;

To load the Table of Achieving into the trophy room:
	repeat with N running from 1 to the number of rows in the Table of Achieving:
		if there is a gained in row N of the Table of Achieving:
			let printed_name be the gained in row N of the Table of Achieving;
			repeat with Ache running through the achievements not in the Trophy Room:
				if the printed name of Ache is printed_name:
					move Ache to the Trophy Room;

To load achievements:
	blank out the whole of the Table of Achieving;
	if the File of Achieving exists:
		read the File of Achieving into the Table of Achieving;
		load the Table of Achieving into the trophy room;

To write out achievements:
	blank out the whole of the Table of Achieving;
	fill the Table of Achieving from the Trophy Room;
	write the File of Achieving from the Table of Achieving;

When play begins:
	load achievements;

After undoing an action:
	load achievements;

Report restoring the game:
	write out achievements;
	load achievements;

Section help

Requesting hints is an action out of world applying to nothing.  Understand "help" as requesting hints.  Understand "hint" as requesting hints.

Carry out requesting hints:
	say "'course correction' does not come with hints, but does reward experimentation.  Every bad ending you encounter can be undone with a single 'undo', until the very very end, and even there, multi-undo should let you back out of situations you don't want to be in any more.  If you're really stuck, you can ask for hints on https://intfiction.org/, or look at the source code at https://github.com/luciansmith/IronChIF/[pb]"

Section Summoning mist

A room can be cloudy or clear.  A room is usually cloudy.
A room can be indoors or outdoors.  A room is usually outdoors.  Forgotten Brig is indoors.  Disused Hallway is indoors.  Librum Itself is indoors.  Upper Great Hall is indoors.  Lower Great Hall is indoors.  Palace is indoors.  Nursery_door is indoors.  Nursery_itself is indoors.

The grey mist is a backdrop.  [It is not scenery.  "[describe the grey mist]."]  The description is "[grey_mist_desc].".  Understand "cloud/clouds/gray/fog/thin/soft/rolling/heavy/thick/choking/impenetrable" as the grey mist.

To say grey_mist_desc:
	if the player is Constance:
		if the location is outdoors:
			say "A [mist density] grey mist swirls and surrounds you, covering you like a blanket";
		otherwise:
			say "Even a Bostrat can't make it truly foggy inside";
	otherwise:
		if the location is outdoors:
			say "A [horatio mist density] grey mist swirls around you, turning the landscape into a collection of vague shapes[first time].  You suppose that as a Falcon Clan, Constance's sharp vision lets her see much better than you[only]";
		otherwise:
			say "Constance's summoned mist fortunately doesn't penetrate inside";

Does the player mean examining the grey mist: it is likely.

The grey mist has a number called thickness.  The thickness of the grey mist is 1.

To say horatio mist density:
	if the thickness of the grey mist is less than 6:
		say "thick";
	otherwise if the thickness of the grey mist is less than 11:
		say "heavy";
	otherwise if the thickness of the grey mist is less than 16:
		say "choking";
	otherwise:
		say "impenetrable";


To say mist density:
	if the thickness of the grey mist is less than 6:
		say "thin";
	otherwise if the thickness of the grey mist is less than 11:
		say "soft";
	otherwise if the thickness of the grey mist is less than 16:
		say "rolling";
	otherwise:
		say "heavy";
	[1-5: thin, 6-10: soft, 11-15: rolling, 16-20: heavy]

Summoning is an action applying to one thing.  Understand "summon [something]" as summoning.

Check summoning something:
	if the noun is not the grey mist and the noun is not the no_mist:
		if the player is Constance:
			say "You're a Bostrat: you can summon mist and clouds, but nothing else." instead;
		otherwise:
			say "You have a very limited ability to summon a wisp of mist, but that's it." instead;
	if the player is Horatio:
		say "You quietly sing a few notes of the song of bostrat, and a small trail of thin mist appears in front of you, twists gently, then dissipates." instead;

Does the player mean summoning the grey mist: it is very likely.
Does the player mean summoning the no_mist: it is very likely.

Carry out summoning:
	if no_mist is in the location:
		now the location is cloudy;
		update backdrop positions;
		move no_mist to the Void;
		say "[one of]Calling on your heritage as a Bostrat, you sing the ancient song of mist and rain and thunder, summoning moisture from the air.  It slowly coalesces into a creeping grey mist, obscuring you from sight.  In gentler times, you would be doing this to ensure the growth of the fields and forests; now you must use it to hide from prying eyes that would keep you from your quarry[or]You sing, summoning an obscuring grey mist to surround you and hide you from prying eyes[stopping].
		
		You stop at the natural inflection point for clouds given today's weather.  You could make it thicker still, though it will dissipate over time.";
	otherwise:
		if the location is indoors:
			say "You sing, drawing the moisture from the room into a wisp of fog, but it twists into nothingness again as the echoes of your song fade.";
		otherwise:
			[1-5: thin, 6-10: soft, 11-15: rolling, 16-20: heavy]
			if the thickness of the grey mist is at least 15:
				now the thickness of the grey mist is 20;
				say "A [mist density] mist is as thick as you can make it--there's simply no more water to pull into the air.";
				stop the action;
			otherwise if the thickness of the grey mist is at least 11:
				now the thickness of the grey mist is 20;
			otherwise if the thickness of the grey mist is at least 6:
				now the thickness of the grey mist is 15;
			otherwise:
				now the thickness of the grey mist is 10;
			say "Your song draws even more moisture into the air, feeding it into the thickening fog.  You feel safer as the now-[mist density] mist wraps around you like a blanket.";

Mist depletion is a recurring scene.  Mist depletion begins when the thickness of the grey mist is greater than one.  Mist depletion ends when the thickness of the grey mist is one.

Every turn during Mist depletion:
	if Being Chased is happening:
		if go go go is happening:
			decrease the thickness of the mist by 5;
			say "The fog quickly evaporates in the heat and sun-song of the Ikniq warriors";
			if the thickness of the mist is less than 2:
				now the thickness of the mist is 1;
				say ", all the way back to equilibrium.";
			otherwise:
				say ", dwindling back to a [mist density] mist.";
		otherwise:
			decrease the thickness of the mist by 2;
			say "The fog evaporates steadily in the heat and sun-song of the Ikniq warriors";
			[1-5: thin, 6-10: soft, 11-15: rolling, 16-20: heavy]
			if the thickness of the mist is less than 2:
				now the thickness of the mist is 1;
				say ", all the way back to equilibrium.";
			otherwise if the thickness of the mist is 4 or the thickness of the mist is 5 or the thickness of the mist is 9 or the thickness of the mist is 10 or the thickness of the mist is 14 or the thickness of the mist is 15:
				say ", dwindling back to a [mist density] mist.";
			otherwise:
				say ".";
	otherwise if the location is outdoors:
		decrease the thickness of the grey mist by 1;
		if the thickness of the grey mist is 1:
			say "[If the player is Constance]Your[otherwise]The[end if] summoned mist thins back to equilibrium.  A [mist density] mist, but still thick enough to mostly obscure you.";
		otherwise if go go go is happening:
			decrease the thickness of the grey mist by 1;
			say "The mist thins more rapidly than normal[if the thickness of the grey mist is 1], back to equilibrium again[end if].";
		otherwise if the thickness of the grey mist is 3 or the thickness of the grey mist is 7 or the thickness of the grey mist is 11:
			say "[If the player is Constance]Your[otherwise]The[end if] summoned fog lightens to a [mist density] mist.";
	otherwise:
		decrease the thickness of the grey mist by 1;
	[say "Thickness: [the thickness of the grey mist] ([mist density]).";]	


After looking during hanging out:
	if cyoa mode is false and the grey mist is in the location:
		If the location is indoors:
			if the thickness of the mist is at least 8:
				say "Even though you're inside, the [mist density] fog outside makes the air in this room thicker, somehow.";
		otherwise:
			if the player is Constance:
				if Constance is cruising and Sneaking is not happening:
					say "You circle through the [mist density] mist, observing but hidden from view.";
			otherwise:
				say "A [horatio mist density] mist surrounds you, summoned by your quarry.";

The surrounding forest is a backdrop.  The description is "The natural forest in this area is mixed deciduous, but several non-native trees have been added to the mix by the Royal Throckwrights in charge of growing the aerie." Understand "forest/trees/woods" as the surrounding forest.

When play begins:
    move the grey mist backdrop to all cloudy rooms;
	move the surrounding forest backdrop to all outdoors rooms;

Section stuff that can fall

A thing can be loose.  A thing is usually not loose.
A thing can be following.  A thing is usually not following.

Section movement

Diving is an action applying to nothing.  Understand "dive" as diving.
Before diving:
	Try going down instead;

Ascending is an action applying to nothing.  Understand "ascend" as ascending.
Before ascending:
	Try going up instead;

Descending is an action applying to nothing.  Understand "descend" as Descending.
Before Descending:
	Try going down instead;

[Understand "fly" as going something.] [Well!  An I7 'abject failure' bug!  Woo!]
Understand "fly" as going.
Understand "glide" as going.
Understand "fly [direction]" as going.
Understand "glide [direction]" as going.

Check jumping:
	say "[if the player is Constance]Pfaugh!  Jumping is for fledglings[otherwise]Your old bones aren't what they used to be.  Jumping is for fledglings[end if]!" instead;

Section song

Singing is an action applying to nothing.  Understand "sing" as singing.
Carry out singing:
	if the player is Constance:
		if Being Chased is happening:
			say "You sing a cry of defiance, as you twist away from a Raven Guard.  He caws angrily back at you.";
		otherwise if the location is the Nursery_itself:
			say "You sing a snatch of an old song you learned as a kid, and Ash immediately joins you.  After you finish, you grin at each other.";
		otherwise:
			say "You'll sing of today's exploits in tonight's evensong.  But right now, you're still trying to be stealthy.";
	otherwise:
		say "The minor songs of magic you can perform made you self-conscious about your normal singing voice.  You haven't sung just for fun in decades.";

Section nostalgia

Xyzzying is an action applying to nothing.  Understand "xyzzy" as xyzzying.
Report xyzzying:
	say "[if the player is Constance]Legends say that the capsa of movement contained such a scroll, but it was lost years ago.  An itinerant troubador once told a tale at the royal court of a Magpie Clan woman who saw the open capsa materialize on her table one morning, and grabbed it just in time to be transported with it to its next location.  She had many fanciful adventures until, years later, it finally took her home again.  She opened the capsa and let it go, hoping that another would have adventures like hers[otherwise]The capsa of movement is incredibly annoying.  Like all capsae, you can feel where it is just at the edge of your senses, so every time it jumps from one location to another, it's like a flicker of movement at the edge of your sight[end if]."

Section look on undo

After undoing an action:
	if cyoa mode is true:
		try looking;
	otherwise:
		say the description of the location;
		say paragraph break;

Section doors

Understand "lock [something]" as locking keylessly. Locking keylessly is an action applying to one thing.

Check locking keylessly:
	if the noun is locked:
		say "[The noun] [are] already locked.  Presumably by someone who had the actual key." instead;
	if the noun is not lockable:
		say "[The noun] cannot be locked." instead;

Carry out locking keylessly:
	say "You've never had the keys for anything around here."

Understand "unlock [something]" as unlocking keylessly. Unlocking keylessly is an action applying to one thing.

Check unlocking keylessly:
	if the noun is the small collection of tiny padlocks:
		say "They are, fortunately, already all unlocked." instead;
	if the noun is not openable:
		say "That's not something that opens, let alone locks." instead;
	if the noun is not lockable:
		say "That's not something you could lock or unlock." instead;
	if the noun is open:
		say "[The noun] is already open, so whether it's locked or not is kind of moot at this point.  You also don't have any keys." instead;
	if the noun is unlocked:
		say "As far as you know, [the noun] is already unlocked." instead;

Carry out unlocking keylessly:
	say "You've never had the keys for anything around here."

First Check opening an open door:
	say "The door is already open." instead;

First Check unlocking an unlocked door with:
	say "As far as you know, the door is already unlocked." instead;

Does the player mean taking something enclosed by the player: it is unlikely.

Section new defaults

Chatting is an action applying to one thing.  Understand "talk to [something]" as chatting.  Understand "talk [something]" as chatting.

Carry out chatting:
	if the noun is not a person:
		say "You try to explain your current situation to [the noun].  It often helps you figure out what to do next.";
	otherwise:
		say "You don't have anything new to say to [the noun] right now.";

First check throwing something at:
	say "[i]Throwing things at other things is not necessary in this game[r].";
	stop the action;

Instead of asking people to try doing something: 
	say "Nobody is going to just do what you tell them to do."

Before dropping something enclosed by the player:
	if the player is not the holder of the noun:
		say "(first taking [the noun] from [the holder of the noun])";
		try taking the noun;
		if the noun is held:
			say "(and now dropping it)";
			continue the action;
		otherwise:
			stop the action;

Instead of waking up:
	if the player is Constance:
		say "It'd be great if the queen would wake up, but she's stuck in her fantasy.";
	otherwise:
		say "You're free for the first time in a decade.  It does indeed feel like waking up.";

instead of sleeping:
	if the player is Constance:
		say "You are unlikely to be able to sleep any time soon.";
	otherwise:
		say "You've done a lot of sleeping over the past decade.  Not today.";

Instead of climbing:
	if the cloak is worn:
		say "This cloak prevents you from that, too!";
	otherwise:
		say "You don't need to climb anything; you can fly.";

Section getting rid of standard library verbs we don't need

Understand nothing as burning.
Understand nothing as tying it to.
Understand nothing as swinging.
Understand nothing as rubbing.
Understand nothing as setting it to.
Understand nothing as waving hands.
Understand nothing as buying.
Understand nothing as switching on.
Understand nothing as switching off.
Understand nothing as squeezing.


[Rules and New Actions ends here.]

[Map by Iron ChIF begins here.]
[Use authorial modesty.]

Book Map

The Void is a room.  [I like having an 'off stage' room for stuff.]

Section High Above

High Above the Royal Aerie is a clear room.  "[high_above_desc]."

To say high_above_desc:
	if the player is Constance:
		if cloudy:
			say "Your summoned mist both obscures you and blocks you from seeing the Royal Aerie.  But you've already memorized its layout,";
		otherwise:
			say "You drift in lazy circles well above the Royal Aerie below.  Your acute eyesight lets you see the entire layout,";
		say " and how it relates to today's air currents, winds, and thermals.  Royal Quarters to the north and down, well defended by circling Raven clan guards.  The Librum to the east and down.  In the center of the Aerie (and directly below you) is the Great Hall.  Other royal aeries dot the forest in the distance, but this complex holds your quarry";
	otherwise:
		say "There's nothing to see here, this high above the Aerie; just a thick mist in every direction.  You would have never been able to find [Constance] if she hadn't been carrying a capsa or two.  You trust that if you circle down from here, you'll be able to find your way once you reach some landmarks";

distant_aerie is scenery in high above.  The printed name is "Royal Aerie".  The description is "[if the grey mist is in the location]As you recall, the[otherwise]The[end if] Royal Aerie was grown and shaped by generations of Throckwrights, and now towers over the surrounding forest canopy.  Lush shades of browns and reds, often woven together in intricate patterns or pictures, cover every landing cradle, wall, and roof."  Understand "royal/aerie/lush/brown/browns/red/reds/woven/patterns/pictures" as distant_aerie.

distant_quarters is scenery in high above.  The printed name is "Royal Quarters".  The description is "[if the grey mist is in the location]As you recall, the[otherwise]The[end if] Royal Quarters is where the queen and her family, servants, and certain privileged royalty live.  Every huge common room; every small or large individual apartment is awash in greenery that looks incredibly inviting and imperially homey, and is in reality subtly precisely hostile to the uninvited.  Every roof pitch is too steep; no branch nor ridge is graspable by talons of any size.  The single landing cradle in the middle of the gardens is surrounded by stern and beautiful tree crowns, beset with nooks and crevices for unseen guards and archers: attempting to land there would mean instant death for any but those who belong."  Understand "royal/quarters/queen/family/servants/royalty/common/room/apartment/small/large/roof/pitch/branch/ridge/landing/cradle" as distant_quarters.

distant_guards are scenery in high above.  They are people.  They are plural-named.  The printed name is "circling guards".  The description is "The last time you were here, the Aerie was not nearly on such high alert.  Now there's guards everywhere, but especially focused on circling the Royal Quarters.".  Understand "raven/circling/guards" as distant_guards.  Understand "raven clan" as distant_guards.

Instead of doing something other than examining with distant_guards:
	say "The guards are too far away.  And, you know, hostile.";
	stop the action;

Instead of doing something other than examining with distant_aerie:
	say "The aerie is too far away.";
	stop the action;

Instead of doing something other than examining with distant_quarters:
	say "The [distant_quarters] is too far away.";
	stop the action;

Instead of doing something other than examining with distant_librum:
	say "The [distant_librum] is too far away.";
	stop the action;

distant_librum is scenery in high above.  The printed name is "the Librum".  The description is "[if the grey mist is in the location]As you recall, the[otherwise]The[end if] Librum was your target the last time out, and where you obtained the capsae you brought back with you. Its landing cradle is simply decorated, grown with interlocking redwood and pine in a way that suggests shelves of books.  The reading nooks grown into the sides of the main building proved a reasonable entrance for a creative supplicant; no doubt that method will have been shut down by now."  Understand "Librum/landing/cradle/reading/nooks" as distant_librum.

distant_great_hall is scenery in high above.  The printed name is "Great Hall".  The description is "[if the grey mist is in the location]As you recall, the[otherwise]The[end if] Great Hall is by far the largest building in the Aerie complex, and indeed the largest building you've ever seen in your life.  If the stories are true, its planning took three years, and its growth was overseen by three [i]generations[r] of Throckwrights.  Every Royal Throckwright since has sought to put their own personal stamp on the Great Hall, leaving it more than a little haphazardly grown by now, but its current form is still impressive, even as it grows less coherent with every new modification."  Understand "great/hall/largest/building/growth/haphazard/haphazardly/coherent/incoherent/cradle" as distant_great_hall.

distant_others are scenery in high above.  The printed name is "other aeries".  The description is "[if the grey mist is in the location]As you recall, the[otherwise]The[end if] other aeries collectively make up the Royal Complex, each mostly grown by a single corps of Royal Throckwrights at some point in your people's history.  But this one is the most important.  The Scroll of Health is here. Somewhere."

no_mist is scenery in high above.  The printed name is "mist".  The description is "The cloud layer today is too high for a naturally obscuring mist; you'll have to summon it yourself.".  Understand "cloud/layer/mist/high/Heathcliff" as no_mist.

The winds are scenery in high above.  The description is "It's a good day for flying.  The winds and thermals are supportive, but not so dominant that you'll have to devote conscious thought to adjusting to compensate for where you want to go."  Understand "air/currents/winds/wind/thermal/thermals" as the winds.

After dropping something in High Above when everything falls is not happening:
	say "[The noun] twists away as it falls below you, towards the Great Hall.";
	Now the noun is in the Great Hall Landing Cradle.

After dropping something during Everything Falls:
	if the gold capsa is enclosed by the location:
		if the noun is the gold capsa or the noun encloses the gold capsa:
			move the noun to the location;
			say "You let go of [the noun].  It remains floating in the air, exactly where you left it.  You push it to a slightly less conspicuous location." instead;
		otherwise:
			move the noun to the location;
			say "You let go of [the noun].  It falls towards the gold capsa and rests there." instead;
		stop the action;


Check going somewhere from High Above:
	if no_mist is in the location:
		say "[one of]If you get any closer to the Aerie without summoning mist first, the guards would surely see you.  It's the reason why you were able to successfully argue why you, as a Bostrat, were the best choice for this mission[or]You'll need to SUMMON MIST first, to cloak your descent[stopping]." instead.

[Trivia:  'Bostrat' comes from 'Nimbostratus' clouds, aka rain clouds.]

After going from High Above:
	if Starting Off is happening:
		say "You descend in wide circles, pulling mist down with you in what you hope is a sufficiently unsuspicious manner, trusting your memorization of the air currents to tell you where you're going...";
	otherwise if the player encloses an open gold capsa:
		now Constance is cruising;
		say "You descend towards the Aerie, though it feels like you're flying upwards, against the pull of the scroll of down.";
	otherwise if go go go is happening:
		now Constance is super-fast;
		say "You dive blindingly fast towards the Aerie through the fog, and the mist swallows you with nary an eddy.";
	otherwise:
		now Constance is speeding;
		say "You tuck in your wings and dive down [if the noun is not down][noun] [end if]towards the Aerie, thrilling to the misty wind streaming through your feathers.";
	continue the action;

Starting Off is a scene.  Starting Off begins when play begins.  Starting Off ends when the player is not in High Above.

Instead of going nowhere from High Above:
	if the noun is up:
		if Being Chased is happening:
			say "You take to the skies even higher.";
			If the closeness of Being Chased is at least 3:
				Now the closeness of Being Chased is 2;
				Now the starting_line of Being Chased is the Void;
		Otherwise:
			say "You're already high enough to avoid being seen from below; there's no need to go higher.";
	otherwise:
		say "From here, you can descend straight down to the Great Hall, descend northward to the Royal Quarters and Gardens, or descend eastward to the Librum.";

Check opening a capsa when no_mist is in the location:
    say "Before you mess with powerful artifacts from the dawn of civilization, you should probably conceal yourself.  You're a Bostrat; the plan was to summon a mist." instead;


Section Great Hall

Great Hall Landing Cradle is below High Above.  "[if the player is Constance]The Landing Cradle of the Great Hall spreads out over nearly a quarter of the vast building.  During your time here, you learned this was so that when a number of important guests and their retinues arrive at the same time, they can land simultaneously, instead of one after the other, which some would invariably take as meaning 'in order of importance'.

The [GHD-open] [Great Hall doors] are on the west side of the landing cradle, and unguarded.  To the north is the Royal Quarters and Gardens, the Librum to the east, and as always, you can return to the skies or descend to the forest.[otherwise]The Landing Cradle of the Great Hall was the first you ever saw of this Aerie, when you arrived ten years ago in the entourage of a Waterfowl delegation.  You were impressed by the [Great Hall doors], large enough to comfortably accomodate even the largest of your distant kin, and the diversity of clans here to meet you was equally fascinating.

To the north is the Royal Quarters and Gardens, the Librum is to the east, the doors to the Great Hall are west, and if your wings are up for it, you could return to the skies and fly up (where Constance circles) or back down to the forest floor.";

To say GHD-open:
	if the Great Hall Doors are open:
		say "open";
	otherwise:
		say "closed";

The Great Hall doors are doors in Great Hall Landing Cradle.  They are plural-named.  The printed name is "huge double doors of the Great Hall".  They are closed and locked.  They are inside from Great Hall Landing Cradle and outside from Upper Great Hall.  The description is "The huge [if open]open[otherwise]closed[end if] double doors are canted hatches that lead from the giant landing cradle into the Great Hall itself.  They are adorned with fine scrollwork[if the player is Constance] whose broad swoops and curls branch off into even finer swoops and curls, even down to the level of detail that only a Falcon Clan like yourself could see.  The Throckwright who grew this must have been an archmaster[end if]."  Understand "huge/door/double/canted/hatch/hatches/fine/scrollwork/broad/swoops/curls/finer/giant/landing/cradle" as the Great Hall doors.

First check opening barred great hall doors:
	say "[closed-great-doors]" instead;

To say closed-great-doors:
	say "You pull at the doors, but not only [if the great hall doors are locked]are[otherwise]were[end if] they locked, but barred as well.  You [if the player is Horatio]vaguely [end if]remember the bar used to sit to one side of the doors inside the hall, gathering dust";
	if the player is Constance and Everything Opens has happened:
		say ".  You suppose rezrov must unlock and open, but not unbar?  The doors give slightly and the bar rattles, but the doors refuse to open.";
	otherwise if the player is Horatio:
		say ".  Rezrov doesn't unbar doors; you'll have to have Constance come back here with rudenj.";
	otherwise:
		say ".  The doors give slightly and the bar rattles, but the doors refuse to open.";

Last Check going Great Hall doors during Being Chased:
	if the location is Upper Great hall:
		continue the action;
	if the hunting cloak is worn:
		continue the action;
	say "You fly through the door, and immediately regret your decision.  In an instant, the Raven Guard has followed you, and you simply don't have any room to maneuver.";
	end the story saying "You have been captured.";

First check opening a closed door during Being Chased:
	say "The Raven Guard is not going to stop chasing you to give you enough time to open [the noun].  Though perhaps if you explained that you only wanted to go into an enclosed space so they could better surround and capture you, they'd consider it?" instead;

The Great Hall doors can be barred.  The great hall doors are barred.

A wooden bar is in Upper Great Hall.  It is loose.  "The wooden bar that once held the Great Hall doors shut lies here, discarded.".  The description is "A large wooden oak bar, used to keep the double doors of the Great Hall closed."  Understand "large/oak" as the wooden bar.

Check taking the wooden bar when Everything Falls is not happening:
	say "The wooden bar is much too heavy to lift by yourself." instead;

Check inserting the wooden bar into the rucksack:
	say "The wooden bar is much to large to fit in the rucksack." instead;

After pushing the wooden bar when the location is Upper Great Hall:
	move the wooden bar to Lower Great Hall;
	say "You push the wooden bar over the edge of the platform, and it crashes to the great floor below." instead;

After taking the wooden bar:
	now the wooden bar is not following;
	continue the action;

Before going inside from Great Hall Landing Cradle:
	try entering Great Hall doors instead;

Instead of going nowhere from Great Hall Landing Cradle:
	if the noun is west, try entering the Great Hall doors;
	otherwise say "From here, you can go north to the Royal Quarters and Garden, east to the Librum, enter the Great Hall itself to the west, or, as always, ascend to the skies or descend to the forest."

hall_open is an achievement in the Void.  The printed name is "Bar None".  The description is "Get the barred and locked doors of the Great Hall open[if helped] (with a little help from your former associates)[end if].".  hall_open can be helped.  hall_open is not helped.

bar_follow is an achievement in the Void.  The printed name is "Fly Quickly, and Tow A Big Stick".  The description is "Fend off the Raven Guard with a huge wooden bar.".

Holy Flying Bars is a recurring scene.  Holy Flying Bars begins when the wooden bar is following and bar_follow is not in the Trophy Room.  Holy Flying Bars ends when the wooden bar is not following.

When Holy Flying Bars begins:
	if the most_recent of the Trophy Room is nothing:
		now the most_recent of the Trophy room is bar_follow;

Every turn during Holy Flying Bars:
	if the most_recent of the Trophy Room is nothing:
		now the most_recent of the Trophy room is bar_follow;


The Halls Are Alive is a scene.  The Halls are Alive begins when the great hall doors are open.  The Halls Are Alive ends when the player is in Upper Great Hall.

Every turn during The Halls Are Alive:
	if the most_recent of the Trophy Room is nothing:
		now the most_recent of the Trophy Room is hall_open;


Upper Great Hall is a room. "[if the player is Constance]There is a small platform just inside the [Great Hall doors], and that's it.  The platform is lined with a single elegant grown-mahogany branch that wraps around the whole platform.  It varies in size and thickness, so that all types of feet fit somewhere along it, so people can comfortably launch themselves into the air to glide down to the floor level, or grab it for stability as they return[otherwise]The small platform just inside the [Great Hall doors] overlooks the hall below, with plenty of space for people of all sizes and shapes to comfortably launch themselves from a smoothly-grown mahogany branch, wrapping around the whole platform[end if]."

The platform is scenery in Upper Great Hall.  "[if the player is Constance]The grown mahogany branch around the platform is a masterpiece of Throckwright engineering.  Not a single delegate or guest ever had problems looking regal as they launched themselves from an appropriate spot[otherwise]You touch the great mahogany branch at the edge of the platform and can just barely hear the echo of the song that grew it, still pulsing in its veins[end if]."  Understand "grown/mahogany/branch/masterpiece/spot/feet/grown-mahogany/elegant" as the platform.

First check entering platform:
	say "[if the player is Constance]You step forward and grip the branch with your talons at your favorite spot.  It's oddly satisfying, and reminds you of times as a kid you'd sneak up here and watch official ceremonies below[otherwise]You step forward to the branch, automatically gravitating to the same spot you launched yourself from the first time you visited.  It's a solid, reassuring spot[end if]." instead;

Instead of going nowhere from upper great hall:
	if the noun is up:
		Try entering the Great Hall doors;
	otherwise if the noun is east:
		Try entering the Great Hall doors;
	otherwise:
		say "From here you can go down, or back out to the east.";


Down from Upper Great Hall is Lower Great Hall.

Report going down from Upper Great Hall:
	say "[if the player is Constance]You step on to your favorite spot on the mahogany branch, and launch yourself downward in a graceful glide[otherwise]You spread your wings to their full extent before launching yourself downward.  You muscles protest, but even just being able to glide again is heavenly[end if].";

Lower Great Hall is a room.  "[if the player is Constance]When not prepared for a particular occasion, like now, the floor of the Great Hall is cleared of everything extraneous.  The exposed floor is absolutely exquisite, with swooping lines interspersed with starbursts, all in multicolored woods of all hues.  What doesn't change about the Great Hall floor is the display nooks along the sides: at least twenty nooks containing all manner of artifacts from around the world[otherwise]The floor of the Great Hall is cleared of the myriad perches and decorations that are brought out for visiting delegations.  It breathes potential, bursting with what it could be, if only.  You wonder if there would even be enough staff to prepare it for a new delegation, with so many sick.  Not that delegations are common, nowadays.

In the display nooks around the edges of the hall are all manner of artifacts from across many ages[end if]."

Various artifacts are scenery in Lower Great Hall.  The description is "[If the player is Constance]Old things, new things, distant things, close things[otherwise]You could spend weeks in here if you were allowed, just cataloguing and recording your impressions of all the artifacts that fill the nooks surrounding the floor.  But right now, all you wanted to do was check to make sure the cloaks were still here[end if]." Understand "old/things/new/distant/close/nook/nooks/twenty" as various artifacts.

The exposed floor is scenery in Lower Great Hall.  The description is "[if the player is Constance]As a kid, you and the now-queen would come in here when it was cleared out like this and make up endless games to play on the patterned wood[otherwise]You don't think you've ever seen this floor exposed like it is now.  It's pretty[end if]."  Understand "exquisite/swooping/lines/starbursts/multicolored/woods/wood" as the exposed floor.

Instead of going nowhere from lower great hall:
	say "The only way out of here is to fly back up to the upper platform.";

Instead of taking various artifacts:
	say "[if the player is Constance]There's a lot of stuff here, but it's all ceremonial or decorative[otherwise]You would love to.  But just the cloaks.  When Constance is here[end if].";

Instead of entering various artifacts:
	say "The nooks are designed to hold the artifacts, and don't have extra space.";

Instead of searching various artifacts:
	say "[if the player is Constance]You poke through the various artifacts, but don't see anything that seems immediately useful[otherwise]Your eyes wander regretfully over the treasure trove of history on display here.  If only you have more time[end if]."

The two cloak posts are fixed in place in Void.  They are plural-named.   Understand "ancient/hunting/post" as two cloak posts.  [The description is "[what's on the posts]"]

Horatio in the House is a recurring scene.  Horatio in the house begins when the player is Horatio and the location is Upper Great Hall.  Horatio in the house ends when the location is Great Hall Landing Cradle.

When Horatio in the House begins:
	move the cloak posts to the Lower Great Hall;

When Horatio in the House ends:
	move the cloak posts to the Void;

Rule for printing a locale paragraph about the posts:
	say "In one of the nooks are two posts, designed for displaying ancient hunting cloaks";
	if the cloak is in the posts:
		if the cloak is purple:
			say ", with two purple hippotomai cloaks hung from them[if the player is Horatio], right where they should be[end if].";
		otherwise:
			say ".";
	otherwise:
		say ".";
	now the posts are mentioned;
	rule fails;


Check examining the posts:
[To say what's on the posts:]
	if the cloak is in the posts:
		if the cloak is purple:
			say "Two purple cloaks" instead;
		otherwise:
			say "Two posts for displaying cloaks." instead;
	otherwise:
		say "Two posts for displaying cloaks." instead;

Instead of touching the two cloak posts:
	if the hunting cloak is on the posts:
		snatch the cloak;
		rule fails;

Check taking the cloak:
	if the cloak is on the two cloak posts:
		snatch the cloak instead;

Check touching the cloak:
	if the cloak is on the two cloak posts:
		snatch the cloak;
		rule fails;

To snatch the cloak:
	if the player is Horatio:
		say "You verify that the cloaks are actually here, but leave them alone.  [if No More Purple is happening]When you couldn't see them, you worried that they might actually have been moved, but no--Constance's ingenuity meant that she's already activated igram.  [end if]With any luck, the drama of being able to see what igram does in person will cancel out the inherent ridiculousness of igram.";
	otherwise if the cloak is on the two cloak posts:
		move the cloak to the player;
		if the cloak is invisible:
			say "You reach for the post, and feel the cloak you saw.  With a sense of wonderment, you pick it up.  Next to you, Horatio picks up the other, equally-invisible cloak.";
		otherwise:
			say "You reach out and pick up the cloak.  It seems none the worse for wear from having been invisible.  Next to you, Horatio picks up the other.";



The hunting cloak is a wearable object on the cloak posts.  The hunting cloak can be purple or invisible.  The hunting cloak is purple.  The description is "[hunting cloak description]."  Understand "hippo/hippotomai/dark/purple/variegation/camouflage/camoflage/cloaks" as the hunting cloak.  The printed name of the hunting cloak is "[if the hunting cloak is purple]purple[otherwise]invisible[end if] hunting cloak".

To say hunting cloak description:
	if the player is Constance:
		if the hunting cloak is on the cloak posts:
			if the hunting cloak is purple:
				say "A plaque by the cloaks claims that in prehistoric times, people made these cloaks out of hippotomai skins to mask their scent.  The dark purple variegation also helped with camouflage.  You couldn't fly with them on, but some prey had gotten extremely adept and spotting flying enemies, so hunters took to sneaking up on foot";
			otherwise:
				say "The cloak posts appear to be empty";
		otherwise:
			if the hunting cloak is purple:
				say "In prehistoric times, people apparently made these cloaks out of hippotomai skins to mask their scent.  The dark purple variegation also helped with camouflage.  You couldn't fly with them on, but some prey had gotten extremely adept at spotting flying enemies, so hunters took to sneaking up on foot.  On foot!  You shake your head";
			otherwise:
				say "You can feel the supple folds of the cloak, but cannot see it at all";
	otherwise:
		say "These hunting cloaks date back to aboriginal times, perhaps even earlier than the capsae and scrolls.  The tough dark purple hippotomai skins they're made of meant they were cumbersome to wear, but would last forever.  You believe several different clans had to cooperate to make them, as no one clan posessed the skills, dexterity, and toughness necessary to both hunt the hippotomai and put the cloaks together";

Does the player mean doing anything with the hunting cloak:  it is very likely.

Does the player mean opening the hunting cloak:  it is unlikely.
Does the player mean closing the hunting cloak:  it is unlikely.

Check wearing the cloak:
	if Being Chased is happening:
		say "You don't have time to land and put on the cloak while you're being chased.  And you wouldn't be able to fly afterwards!" instead;
	if the location is in_forest:
		say "You wouldn't be able to fly back up!" instead;
	if the location is High Above:
		say "Might I remind you that you can't fly with that cloak on?  And that you are currently [i]very high[r] in the air?" instead;

Report wearing the cloak:
	if the location is outdoors:
		say "You land and put on the cloak, itching to get back to the skies.";
		stop the action;

Section Librum

Librum Landing Cradle is east of Great Hall Landing Cradle.  "[if the player is Constance]The Landing Cradle of the Librum is beautifully set with interlocking redwood and pine, suggesting shelves of books.  The [Librum door] leads inward to the Librum itself.

To the west is the Great Hall, and to the northwest is the Royal Quarters and Gardens.  You can also re-ascend to the skies or descend to the forest below.  The door to the Librum is to the east[otherwise]For the last ten years, this place has been the focus of your subconscious.  Always knowing where capsae are can be wearing when you're this close for so long.  Every time one would be taken out for training, every time one would be moved for cleaning, every time their display case was bumped, it was a little 'ding' for your subconscious mind to notice, and probably pass up to your conscious mind, because, let's face it, there wasn't a lot else to notice from that cell.  The Librum was always the focus.  Until Constance.

From here, the Great Hall is west, the Royal Quarters northwest, and the [Librum door] east (though guarded).  Or you could fly off again, either up or down[end if]."

Up from Librum Landing Cradle is High Above.
Down from Librum Landing Cradle is in_forest.
East from High Above is Librum Landing Cradle.

Instead of going nowhere from Librum Landing Cradle:
	if the noun is east:
		try entering Librum door;
	Otherwise:
		say "From here, the Great Hall is to the west, the Royal Quarters and Gardens are to the northwest, and the doors to the Librum are east.  You can also fly up again, or descend to the forest below."

The Librum door is a door in Librum Landing Cradle.  It is closed and locked.  It is inside from Librum Landing Cradle and outside from Librum Itself.  The description is "A canted [if open]open[otherwise]closed[end if] hatch to the Librum, on the east side of the landing cradle."

First Check opening a closed Librum door:
	if the lone guard is in the location:
		if the player is Constance:
			say "The guard is entirely too watchful to let you do that[if Momentum is happening], even going as fast as you are[end if]." instead;
		otherwise:
			say "Right.  An old buzzard, facing off against a fresh-beaked Raven Guard, and an Ikniq, at that.  You'll leave opening the door to rezrov." instead;

First Check unlocking a locked Librum door with:
	if the lone guard is in the location:
		if the player is Constance:
			say "The guard is entirely too watchful to let you do that." instead;
		otherwise:
			say "Right.  An old buzzard, facing off against a fresh-beaked Raven Guard, and an Ikniq, at that.  You'll leave opening the door to rezrov." instead;

Before going inside from Librum Landing Cradle:
	try entering Librum door instead;

Last Check going Librum door during Being Chased:
	if the location is Librum itself:
		continue the action;
	if the hunting cloak is worn:
		continue the action;
	say "You fly through the door, and immediately regret your decision.  In an instant, the Raven Guard has followed you, and you simply don't have any room to maneuver.";
	end the story saying "You have been captured.";


Last Check going Librum door:
	if the player is Constance:
		if the lone guard is in the location:
			if Horatio is in the location:
				if Momentum is happening:
					say "Using the extra speed from your dive, you quietly plunge through the Librum door behind the distracted guard, pulling up sharply on the other side before crashing into anything.";
				otherwise if Super-Momentum is happening:
					say "With everything sped up, including (presumably) the guard's reactions, you try to be as precise as you can, entering exactly behind her, straight for the far corner of the door.  You needn't have bothered.  Horatio is talking a mile a minute, and his annoyingness level must have quintupled, as every feather on the guard's back is sticking out at various odd angles.  You swoop in and land inside with ease.";
				otherwise if the thickness of the grey mist is at least 10:
					say "The thicker mist conceals your gliding approach from the distracted guard, as you carefully glide in, tuck your wings in at the last second, and land quietly inside.";
				otherwise if Go go go is happening:
					say "Horatio's distraction patter has doubled in speed, which in and of itself is something to behold, but the guard's irritation factor seems to have quintupled in annoyance in response, which is, quite frankly, hilarious: every feather on the guard's back is sticking out at various odd angles.  You watch until the guard starts making a quiet keening sound with her eyes closed, and you glide in from above and behind her, unseen.";
				otherwise:
					say "Horatio is distracting the guard by discussing [one of]the ethics of a monarchy[or]his grandchildren[or]regrettable fashion choices from the youth of today[or]whether the dot on the back of looks infected[or]how to get to moncrepistan (is that a real place?) from here[or]whether her mother was the Isabella he once knew[or]some meandering story about flying to the park[cycling], but you can't just [i]glide in[r]." instead;
			otherwise:
				if Sneaking is happening and No More Purple is happening:
					say "Invisibly, you sneak behind the guard and through the doors.";
				otherwise:
					say "The guard is entirely too watchful to let you do that." instead;
		otherwise if the location is Librum Itself:
			[*Leaving* the Librum.  We'll assume the guard and Horatio are still outside.  And, sigh, not make this a puzzle.]
			say "Listening to Horatio talk with the guard, you enter the shadows just inside the Librum door, where you can watch the guard but not be seen.  When the moment is right, you launch yourself through, and back up into the safety of the mist.";
	otherwise:
		[We're Horatio]
		say "You spent so much time in the Librum those first few months, before the previous queen imprisoned you.  You'd love to return, to see what's changed; to revisit some of your favorite books.  Maybe soon, again?  For now, there's a guard.  She won't let you in.  You're going to have to get Constance to do it." instead;

Check closing the purple capsa of opening when the location is the Librum Itself:
	say "The guard would close the door again, and you'd be trapped!
	
	[i]Are you one of my testers?  It feels like you're one of my testers.  If you're not, you should be one of my testers.  Give me a call.  -LS[r][lb]" instead.

A lone guard is a woman in Librum Landing Cradle.  "A lone Raven guard stands in front of the door, dark eyes shifting as she watches the mist."  The description is "[lone_guard_desc]."  Understand "raven/dark/eyes/wing/wings" as lone guard.

To say lone_guard_desc:
	if the player is Constance:
		say "The raven guard wears the well-fitting uniform of the Queen's Guard, complete with a small red insignia on her shoulder.  The silvered knives on her talons are retracted while she stands, and golden razors line her beak[if the collection of tiny padlocks is in the Void].  Oddly, her uniform seems to be covered with... tiny closed padlocks?  That's not the insignia of any order you know[end if]";
	otherwise:
		say "You wouldn't be surprised if this lovely young dangerous woman was a fledgling when you arrived, lo these ages past.  Now she's doing a bang-up job of keeping you and Constance out of the Librum.  Fortunately, she looks polite, like she wouldn't arrest a kindly old buzzard for talking her ear off while a certain Falcon Clan slips in to the Librum behind her[if the black capsa is not enclosed by the Librum itself].  You're kind of glad you won't have to exploit her like that, as Constance seems to have extricated the black capsa on her own already[end if]";

The well-fitting uniform is worn by the lone guard.  The description is "[if the player is Constance]Her uniform consists of loose straps, designed to fit precisely under flagfeathers and provide support while not hampering movement nor flight.  The insignia on her shoulder reads 'Ikniq' under an icon of a tongue of fire: the logo of the fire warriors[otherwise]You wonder if this young guard knows the Ikniq fire insignia on her shoulder was first used by Heron Clan warriors, two centuries ago[end if]."  Understand "loose/straps/under/support/insignia/shoulder/ikniq/icon/fire/warrior/warriors" as well-fitting uniform.

Tiny closed padlocks are part of the well-fitting uniform.  The description is "[if the player is Constance]Yes, those are definitely tiny padlocks, each attached to small leather loops stitched to her uniform.  You peer more intently.  The stitching where the loops attach is definitely newer than the stitching on the rest of the uniform.  They must have been added recently[otherwise]Those tiny padlocks must be a rezrov-detection system.  The queen must have had her top people working on it, knowing Constance would return[end if]."  Understand "stitching/loops/attach/padlock" as the tiny closed padlocks.

Instead of doing anything other than examining to the tiny closed padlocks:
	if the player is Constance:
		say "You're not getting anywhere near the guard's uniform if you can help it.";
	otherwise:
		say "Even if you were trying to distract her, that doesn't seem wise.";

A small collection of tiny padlocks are in the Void.  They are plural-named.  "In the cradle [if Being Chased is happening]where the guard was[otherwise]next to the guard[end if] is a small collection of tiny padlocks, each open."  The small collection of tiny padlocks are loose.  The description is "[if the player is Constance]Several tiny padlocks, each one opened.  Cheap light metal that could easily be bent open, so you suppose their only purpose is to serve as notice that rezrov was activated[otherwise]A collection of tiny, cheap 'padlocks', each designed to close and open and that's it--useless for actually holding anything together, but perfect for detecting the wave of magic from the rezrov scroll when its capsa opens.  You wonder if similar detection systems could be used to detect the waves of magic from other scrolls.  Maybe all magic flows outward at the same rate, but maybe not?  You don't think anyone's ever tried to measure it before[end if].".  Understand "padlock/light/metal/lock/locks" as the small collection of tiny padlocks.

Instead of locking or unlocking or opening or closing or locking keylessly the small collection of tiny padlocks:
	say "Doing that to the entire collection would be both tedious and pointless.";

Silvered knives are worn by the lone guard.  The description is "[if the player is Constance]Silvered knives, retracted now, but extendable at will[otherwise]The silvered knives the Ikniq warrior wears are basically the same design as they've been for a century.  And as effective as they've been for a century[end if]."  Understand "silver/retracted/retractable/extendable" as silvered knives.

Golden razors are worn by the lone guard.  The description is "[if the player is Constance]The golden razors increase the Queen's Guard fighting abilities, allowing them to slash with their beaks as well as sharpening their bite[otherwise]The golden razors worn on the guard's beak look impressive, but they only work well with a particular fighting style.  You'd guess they'll only be in fashion for a few years, before people realize that if you have to fight in a highly-constrained way, it's much easier to learn how to defend yourself against it[end if]."

After dropping the small collection of tiny padlocks:
	if the location is the Librum Landing Cradle and the lone guard is in the location:
		say "As you pass by overhead, you drop the tiny padlocks so they'll land near the guard, then disappear into the mist.  You hear an angry song of fire behind you, as she tries to burn your mist away, but it holds.  You chuckle to yourself." instead;

answering the lone guard that something is talking your way past.
telling the lone guard about something is talking your way past.
asking the lone guard about something is talking your way past.
asking the lone guard for something is talking your way past.
chatting the lone guard is talking your way past.

instead of talking your way past:
	if the player is Constance:
		say "If you spoke at all, she would be on you in a heartbeat.";
	otherwise:
		say "You have plenty of stories to tell this young woman, but they aren't endless.  Better to wait until Constance is ready to take advantage of you distracting her, before the guard gets bored and starts watching the mist again.";

Instead of attacking the lone guard:
	if the player is Constance:
		say "Against those talons?  Not a good idea.";
	otherwise:
		say "Even in your youth, you wouldn't have lasted long against a trained warrior.";

Instead of kissing the lone guard:
	if the player is Constance:
		say "You're not a huge fan of getting your beak slashed by razors.";
	otherwise:
		say "You do give off a grandfatherly aura, but the sharpness of her gaze tells you it wouldn't be nearly enough.";

Instead of showing something to the lone guard:
	if the player is Constance:
		say "If you showed yourself at all, she would be on you in a heartbeat.";
	otherwise:
		say "You'd rather hold off on your distraction arsenal until Constance is ready to take advantage of it.";

Instead of giving something to the lone guard:
	if the player is Constance:
		say "If you showed yourself at all, she would be on you in a heartbeat.";
	otherwise:
		say "You'd rather hold off on your distraction arsenal until Constance is ready to take advantage of it.";

Instead of waking the lone guard:
	if the player is Constance:
		say "She's... not asleep?  I suppose you could awaken her to the idea of your presence, though that seems decidedly unhelpful.";
	otherwise:
		say "She's plenty alert already!"


Librum Itself is a room.  The printed name is "Librum".  "The Librum contains two levels of scrolls and books, with easy access to all of the curving shelves, and plenty of reading roosts with natural and artificial lighting.  You know from your childhood where the best roosts are, and what sections contain the most exciting stories.  In the center of the lower room is a lavish display case, now hastily boarded over, which three days ago held the purple, gold, and red capsae.  The [Librum door] is back up at the top level."

Librum contents are scenery in Librum itself.  "The worst part about this room is the shadows of all the memories spent here in the company of the now-queen."  Understand "two/levels/scrolls/books/access/curving/shelves/reading/roosts/natural/artificial/lighting/childhood/sections/exciting/stories/worst/shadows/memories/queen/now-queen" as the Librum contents.

Instead of taking librum contents:
	say "As much as you'd love to grab a book and lose yourself in a fantastical story about another world, right now you have responsibilities.";

The lavish display case is scenery in Librum Itself.  "The boarded-over display case, like many of the shelves, was grown here as a permanent fixture.  It hasn't always displayed capsae, but there was always something to show off.  Well.  Until now."  Understand "boarded/over/boarded-over/display/case/grown/permanent/fixture/jewels/money/treasury" as the lavish display case.

Instead of going nowhere from the Librum Itself:
	If the noun is up or the noun is west:
		try entering the Librum door instead;
	otherwise:
		say "You can exit the Librum by going up, out the door." instead;

Before going outside from the Librum Itself:
	try entering the Librum door instead;

Instead of opening or taking the display case:
	say "[one of]On a whim, you pull back a board to see if anything's in the display case.  There is.  Jewels and money.  At an estimate, maybe a quarter of the queen's personal treasury.  You shake your head, disgusted.  Well, that's why this building was being guarded[or]You don't need [i]money[r].  What you're after is much more valuable to your community[stopping].";

Section Royal Gardens

Royal Gardens is a room. It is north of Great Hall Landing Cradle, and northwest of Librum Landing Cradle.  "[if the player is Constance]The Royal Gardens is the most lavishly opulent and sensuous entrance to any aerie you've seen in your life.  Trees, vines, and flowers of every variety spring up from everywhere, each seemingly placed in the exactly appropriate spot.  The landing cradle next to the [garden door] to the Royal Quarters themselves is nestled between gracious arcs of poplar trunks, each bedecked with shaded and inviting roosts.  Which, as you know from your childhood days swooping and laughing through these gardens, invariably contain at least eight guards.  Probably ten or more today.

From here, you can return to the skies or descend to the forest.  The Great Hall is to the south, and the Librum to the southeast.  The door to the very-guarded Royal Quarters is to the north[otherwise]All the vegetation throughout the Royal Garden is much, much more vibrant than you remember it being a decade ago.  But things are subtly off-kilter:  a rose bush with too-large roses that has to be propped up with almost-hidden forked sticks.  A roost canted at an odd angle from its tree bending south.  Fireball bromeliads threatening to strangle their host hickory trees, despite signs of agressive pruning.  You felt taclor being moved to the Royal Quarters a little over a year ago, and it's been active ever since.  The foliage is out of balance.

The Great Hall is south of here, the Librum southeast, and the well-guarded [garden door] north.  Above, Constance circles in the fog, and the forest floor is beneath[end if]."

Up from Royal Gardens is High Above.
Down from Royal Gardens is in_forest.
North from High Above is Royal Gardens.

Instead of going nowhere from Royal Gardens:
	if the noun is north:
		try entering garden door;
	otherwise:
		say "From here, you can fly south to the Great Hall, or southeast to the Librum. You can also fly up to the skies, or down to the forest.  The guarded doors to the Royal Quarters are to the north."

The royal landing cradle is scenery in Royal Gardens.  The description is "[if the player is Constance]The cradle's aesthetics have suffered somewhat from having to be re-grown every time the royal insignia changes, but it's still tastefully lavish[otherwise]The royal insignia on the cradle is an interesting amalgamation of of the traditional Red Wing crest, overlaid on elements of several other clan crests, conveying that the Red Wings are over but also supported and held up by a large diverse community of people[end if]."  Understand "aesthetics/insignia/opulent" as the royal landing cradle.

The poplar trunks are scenery in Royal Gardens.  They are plural-named.  The printed name is "[if the player is Constance]poplar trunks[otherwise]foliage[end if]".  The description is "[if the player is Constance]The poplars around the landing cradle contain five guards that you can see (since you know where to look), and almost certainly at least another five that you cannot (since you know where you can't look)[otherwise]The foliage is overgrowing and out of balance.  But it's undeniably vibrant[end if]."  Understand "arcs/shaded/inviting/roosts/rose/roost/tree/trees/Fireball/bromeliads/hickory/bush/pruning/foliage/rose/bush/bushes/vegetation" as the poplar trunks.

Some guards are scenery in Royal Gardens.  They are plural-named.  They are people.  The description is "[if the player is Constance]The guards here get this job by being the best.  They've vigilant and highly skilled[otherwise]The guards here seem much more watchful than the one assigned to you[end if]."  Understand "guards/guard/eight/five/ten/vigilant/skilled" as some guards.

The flowers_and_vines are scenery in Royal Gardens.  The printed name is "flowers and vines".  The description is "The particular varieties of flowers have changed over the years, but not their beauty."  Understand "flower/flowers/vine/vines/quarters/garden/gardens" as the flowers_and_vines.  Understand "flowers and vines" as the flowers_and_vines.

The garden door is a door in Royal Gardens.  It is closed and locked.  It is inside from Royal Gardens and outside from Palace.  The description is "[garden_door_desc]."

To say garden_door_desc:
	if the player is Constance:
		say "A canted [if open]open[otherwise]closed[end if] hatch to the Royal Quarters, nestled in the center of the garden.  Absolutely surrounded by guards";
	otherwise:
		say "Beyond the canted hatch is taclor, tantalizingly closer than it's been in years.  But you'll need Constance's help.";

First Check opening a closed Garden Door:
	if the player is Constance:
		say "There are way too many guards for that to have any chance of working." instead;
	otherwise:
		say "Even if the guards were in the habit of admitting locked-up heretics into the Royal Quarters, what then?  The queen would still hold taclor.  You need Constance." instead;

First Check unlocking a locked Garden Door with:
	if the player is Constance:
		say "There are way too many guards for that to have any chance of working." instead;
	otherwise:
		say "Even if the guards were in the habit of admitting locked-up heretics into the Royal Quarters, what then?  The queen would still hold taclor.  You need Constance." instead;

Before going inside from Royal Gardens:
	try entering Garden Door instead;

Last Check going Garden Door:
	if the player is Constance:
		If Sneaking is happening:
			if Being Chased is happening:
				if the player encloses an open gold capsa:
					say "You hold the gold capsa in front of you, and immediately start falling sideways across the roof of the Aerie, towards the door.  It's sort of like flying?  Except you can't stretch out your wings in this stupid cloak, so you have almost zero control over your trajectory.  You do still manage to aim yourself at the door, and expertly/accidentally twist at the last second, sending yourself catapulting straight into the Royal Quarters.  You made it!
					
					...and then, of course, the Raven Guard pour in through the door after you, because the gold capsa is still pointing at you.";
					end the story saying "You have been captured.";
					stop the action;
				otherwise if the hunting cloak is purple:
					say "You absolutely cannot make it across the open space between you and the door wearing a purple cloak that keeps you from flying." instead;
				otherwise:
					continue the action;
		If Being Chased is happening:
			say "You fly through the door, and immediately regret your decision.  Not only does the Raven Guard who were chasing you follow, but so do the guards that stayed behind to guard, well, this door.";
			end the story saying "You have been captured." instead;
		otherwise if Sneaking is not happening:
			say "No way.  It wouldn't matter how fast you were or how thick the mist was.  You just can't get in there as you are without someone seeing you." instead;
		otherwise if the hunting cloak is purple:
			say "Not only would you be caught, but you'd be humiliated for your entire life for being caught walking, wearing an ancient purple cloak." instead;
	otherwise:
		say "You think you can make it in, but only with Constance, igram, and the cloaks.  Constance first." instead;

After going Garden Door:
	say "OK.  Walking.  [if Being Chased is happening]While everyone's after you.  [end if]Right.  You raise yourself up on the tips of your talons, feeling ridiculous, but not wanting to flatten the grass with your (shudder) footsteps and give yourself away.  You wait for one of the guards to pass, then carefully take cautious steps towards the door.  [if being chased is happening]The Raven Guard fly past overhead, screeching in anger and frustration as they know you're close, but just can't seem to find you[otherwise]Nobody reacts[end if].  Hardly daring to breathe, you proceed further, antsy and ready to take to the skies any second.  Which wouldn't work, because you have this damn cloak on.  Whatever.  Two more steps.  You reach the door.  [if being chased is happening]More cawing overhead.  [end if]You hop (shudder) across the lintel.
	
	You're in.
	
	A few more steps, and a voice behind you whispers 'We should take the second hallway.' You nearly yelp, but stop yourself.  You knew Horatio would be here.  You were expecting him.  Right.
	
	You take a deep breath.  'Lead on,' you whisper back.
	
	'I can't; I'm invisible.  I will tell you where to go, and follow you,' he replies.  Right.[bstars]";
	wait for any key;
	[In case Being Chased is happening:]
	Now the woodpeckers are not activated;
	Move the Raven Guard to the Void;
	Move the Lone Guard to the Librum Landing Cradle;
	Now the closeness of Being Chased is 0;
	Now Constance is cruising;
	clear the screen;
	say "You make your way, with Horatio's direction, through the Royal Quarters.  A time or two Horatio leads you to a place you'd have to fly to get past, but you know this place well, and even though you never walked anywhere, you still know the walking ways.  There's fewer guards to avoid than you expected, meaning that the queen either has them all outside guarding the entrance, or she just doesn't have them to spare.
	
	As you get closer to your objective, a growing sense of unease forms in the pit of your stomach.  One by one, you pass all the places you pegged as most likely for it to be: the throne room, the vault, even storerooms.
	
	Then:  'This is it,' says Horatio.
	
	Oh no.";
	wait for any key;
	Move Horatio to Nursery_door;
	Now Horatio is stage five;
	Move the player to Nursery_door;
	now the most_recent of the Trophy Room is snuck_in;
	stop the action;

Palace is a room.  "If you're seeing this, I either haven't finished writing the finale, or you found a bug.  Hopefully, you're a tester, and that's your job.  Thank you!  Come back for a later version with the finale!";

Nursery_door is a room.  The printed name is "Nursery Door".  "You're standing in a hallway, just south of the nursery door, to the west.  The door is open.  All the doors have been open.  You can't see inside yet.  Your heart pounds in your chest."

Instead of going nowhere from Nursery_door:
	say "The nursery is to the west.  The scroll of health is to the west.  [i]Health[r].  Taclor.";

Check going west from Nursery_door:
	if the hunting cloak is worn:
		say "'Horatio,' you whisper.  You feel a tap on your shoulder in response.  'I can't go in there wearing this cloak.  I just can't.'
		
		A pause.
		
		'Then take it off,' he replies." instead;

After taking off cloak in Nursery_Door:
	say "You take a deep breath and take off the cloak.  Next to you, Horatio takes his own cloak off as well.";
	stop the action;

After going west from Nursery_door:
	move Horatio to the Nursery_itself;
	continue the action;

Snuck_in is an achievement in the Void.  The printed name is "The Old Cruising Grounds".  The description is "Make it back inside the Royal Quarters.";




Nursery_itself is a room.  It is west of Nursery_door.  It is northwest of Nursery_door.  The printed name is "Nursery".  "The Nursery is not exactly how you remember it.  It was set up to grow new walls and furniture over time, to keep any occupant engaged and growing.  But the rhythm of it is baked into your bones.  The place for the roosts, along the north wall.  The [desk], grown to the size of the user.  The endless parade of ropes and balls and other toys along the south, some grown and some brought in.  The giant [window] to the west, overlooking the beautiful, beautiful forest."

Some roosts are scenery in Nursery_itself.  They are supporters and enterable.  The description is "[You and aubrey] would swing from roost to roost, competing to see who could make the most jumps without opening your wings at all."  Understand "roost/north/wall" as roosts.

Some The_toys are scenery in Nursery_itself.  The description is "[You and aubrey] cycled through so many, many toys.  You would break one by accident, and she would imperiously demand new ones of the guards."  Understand "ropes/balls/rope/ball/south/toy/toys" as the_toys.  The printed name of the_toys is "toys".

The window is an enterable supporter in Nursery_itself.  The description is "Absolutely the best view anywhere.  [You and aubrey] could watch a storm roll in across the sky for hours.  You learned how to enhance the storm to make it more dramatic based on Aubrey's excited trills." Understand "view/best/beautiful/forest" as the window.

The desk is a supporter in Nursery_itself.  The description is "It's smaller now than you ever remember it being.  You never knew her at that age." Understand "small/smaller/grown/user" as the desk.

[To see the capsa, see Pc and Rucksck.i7x!  Sigh.]

To say You and aubrey:
	say "[first time]You and the now-Quee--  No.  [only]You and Aubrey"



Section Forest Below

in_forest is a room.  It is below Great Hall Landing Cradle.  The printed name is "In the Forest".  "[if the player is Constance]The trees below the Royal Aerie grow more closely together than in the rest of the forest, and include a wider variety, so that differently-colored woods could be incorporated into the buildings above.  This makes it harder to navigate down here--or it would if you weren't so amazing at navigation[otherwise]The tightly-growing trees and [horatio mist density] fog surround you.  It would be oppressive, but for the echo of the Throckwright song you can just sense, flowing through the veins of these trees still.  That, and the fact that you've been confined to a single room for a decade, so any contrast is welcome[end if]."

tree_varieties are scenery in in_forest.  The printed name is "trees".  The description is "[if the player is Constance]Birch, pine, redwood, alder, ash, elm, poplar, and probably several other types as well[otherwise]A wide variety of tree types grow up to the Aerie above, each lending its own strength, suppleness, and color to the Royal Aerie grown above[end if]."  Understand "Birch/pine/redwood/alder/ash/elm/poplar" as the tree_varieties.

A fine net is here.  It is fixed in place.  "[if the player is Constance]Even through the mist, your sharp eyes spot a fine net, stretched between the trees.  It seems to be set to prevent anyone from coming up from the forest below[otherwise]The net that caught you stretches in every direction, preventing both entrance to and egress from the rest of the forest[end if]."  The description is "[if the player is Constance]A fine, strong net, stretched between and among the trees[first time].  It wasn't here three days ago, which means they spent a lot of effort... to keep you on the Aerie-side of it.  You grin to yourself[only][otherwise]Even in your cell, you could hear the work being done to install this net.  For all the good it did them[end if]."

Check taking the net:
	say "Besides being way too large to carry, the net is attached firmly to the trees and branches, not allowing anything larger than a feathers-length through it[if cell door is open].  Though not, you notice, with knots that could be undone by the scroll of Opening.  Everything is just... folded.  Very deliberately[end if]." instead.

Check cutting the net:
	say "Your beak isn't strong enough to cut through the net." instead;

Check attacking the net:
	say "Your beak isn't strong enough to cut through the net." instead;

Up from in_forest is Great Hall Landing Cradle.
North from in_forest is Royal Gardens.
East from in_forest is Librum Landing Cradle.

Instead of going nowhere from in_forest:
	if the noun is down:
		say "The net prevents you from reaching the forest floor.  Fortunately, [if the player is Constance]you're already where you want to be[otherwise]your quarry is above the Aerie, not below it[end if].";
	otherwise:
		say "The net prevents you from reaching the forest floor and from exploring the rest of the lower forest area, but you can go straight up to the Great Hall, east (and up) to the Librum, or north (and up) to the Royal Quarters and Gardens.";

After going from in_forest:
	say "[going_from_forest].";
	continue the action;

To say going_from_forest:
	if the player is Constance:
		say "You gracefully flit between the trees back up [if the noun is north]north [otherwise if the noun is east]east [end if]above the canopy";
	otherwise:
		say "Forcing your tired wings to flap again, you rise above the forest floor, past the level of your cell, up [if the noun is north]north [otherwise if the noun is east]east [end if]above the canopy"

After going to in_forest:
	if the player is Constance:
		If Everything Falls is happening:
			say "You descend towards the forest floor, though it feels like you're flying upwards, against the pull of the scroll of down.";
			now Constance is cruising;
			continue the action;
		Otherwise If Constance is super-fast:
			say "Your wings tighten close to your body as you rocket through the mist, your keen eyesight only barely sufficient to keep you from crashing into branches and trees[first time].
			
			It is, without a doubt, the most thrilling dive of your entire life.
			
			At the last second, you flare your wings, and feel like they're about to rip off of your shoulders.  You skim over the netting, your curved talons juddering across the lines, making your whole body tremble until you pull up again to dodge more tree trunks.  You allow yourself a triumphant cry, safe in the knowledge that nobody could catch you at these speeds.  Nobody[only].";
			continue the action;
		otherwise:
			if Constance is speeding:
				now Constance is super-fast;
			otherwise:
				now Constance is speeding;
				if go go go is happening:
					now Constance is super-fast;
					say "You dive into and through the forest, twisting expertly as you dodge trees and branches.  The fog closes behind you with a quiet 'shhhhmp', leaving no record of your passing.";
				otherwise:
					say "You tuck in your wings and dive down into the forest below the Aerie, dodging tightly-spaced trees with acrobatic precision.";
			continue the action;
	otherwise:
		say "Wings splayed to their full extent, you coast in wide circles, back down to the forest floor.  Or, as close to the forest floor as the net allows.";

[Map ends here.]



[PC and Rucksack by Iron ChIF begins here.]
[Use authorial modesty.]

Book Cast

Section Constance

Constance is a woman in High Above.  "Constance, a powerful Falcon Clan female, is here, her large black eyes watching you with fierce intensity."  The description of Constance is "[Constance_desc]."  Understand "constance/powerful/falcon/clan/large/black/eyes/yellow/scalp/mottling/wings/throat/underwings/brown/striations/talons" as Constance.

To say Constance_desc:
	if the cloak is worn and the black capsa is open:
		say "Right now, you don't look like anything: you're completely invisible in this ridiculous cloak.  It covers your wings, though, and you can't fly at all.";
	otherwise:
		say "As a member of the Falcon Clan, [your] most striking features are [your] large black eyes, offset with yellow, and slightly recessed under a grey-feathered scalp.  The grey blends from [your] head, mottling along [your] back and the backside of [your] wings, while [your] front, throat, and underwings are feathered white with brown striations[if the player is Constance].  A close encounter with a Raven during [your] previous mission left a few missing contour feathers and some down, but not enough to hinder movement or flight[end if]";

To say your:
	if the player is Constance:
		say "your";
	otherwise:
		say "her";

[As might be predicted, the 'let's go with this for now' decision has been solidified in stone.]

The player is Constance.

[Note: I looked up 'famous falconers' and one of them was King Frederick II.  So I looked up his wife's name, found our there were at least four of them (!), and 'Constance' stood out to me as a good PC name.]

Constance can be wounded.  Constance is not wounded.

The wound is in the Void.  The description is "[if the player is Constance]Your wound isn't incredibly serious, but you don't want to get hit again[otherwise]Constance seems to be lightly wounded, but it's not affecting her movement or agility in the slightest[end if]."  Understand "cut/bleeding/blood/flow/flowing/ache/bleed/lightly/light/" as the wound.  Understand "open wound" as the wound.

Instead of doing anything with the wound:
	if the current action is closing:
		say "Unfortunately, you didn't bring a first-aid kit with you.";
	otherwise if the current action is examining:
		continue the action;
	otherwise:
		say "Messing with the wound is not going to help.  It'll heal on its own eventually.  You hope.";

Slice is a recurring scene.  Slice begins when Constance is wounded.  Slice ends when Constance is not wounded.

When Slice begins:
	move the wound to Constance;
	now the wound is part of Constance;

When Slice ends:
	move the wound to the Void;

[The carrying capacity of Constance is 1.][Not sure about this--it would be strong motivation to turn off rezrov, though!]

A leather rucksack is a player's holdall worn by the Constance.  Understand "sack/backpack/pack/bag" as leather rucksack.  The leather rucksack is loose.

Section capsae and scrolls

A capsa is a kind of openable container.  A capsa is usually closed.  A capsa is usually loose.  The plural of capsa is capsae.

Does the player mean taking a capsa:
	it is likely;

Check taking something:
	if the noun is inside a capsa:
		say "Like all of the Ancient Scrolls, the scroll is inextricably tied to its capsa." instead.

Check removing something from a capsa:
    say "Like all of the Ancient Scrolls, the scroll is inextricably tied to its capsa." instead;

Check inserting something into a capsa:
	say "Nothing goes into a capsa other than the scroll placed there by the gods." instead;

A scroll is a kind of a thing.  A scroll has a text called name.  The name of a scroll is usually "FOO".

Does the player mean doing something to a scroll:  it is likely.

Does the player mean opening or closing a capsa:  it is very likely.

The description of a scroll is "While '[name]' can be clearly read at the top of the scroll, the rest (or at least, the top few lines that you can see) is in some arcane script you [one of](and the people and sages of your village) were[or]are[stopping] unfamiliar with."

[LS DEBUG:  maybe change above to 'while you can see while it's rolled up', though then we'll need to implement 'roll/unroll scroll', so maybe later.]

Section rezrov

A purple capsa of opening is a capsa in the rucksack.  The description is "The purple capsa turned out to contain a scroll of opening[first time], as became evident when every buckle and lock in your village flew open when you opened the capsa to investigate[only].  It is [if the purple capsa of opening is closed]closed, preventing the power of the scroll from affecting the area[otherwise]open, allowing the scroll's power to open and hold open any closed object in the area[end if]."  Understand "rezrov" as the purple capsa of opening.

A scroll of rezrov is a scroll in the purple capsa of opening.  The name is "REZROV".  Understand "opening" as the scroll of rezrov.

Last check opening the purple capsa for the first time:
	say "You take a deep breath.  If you're going to get past any of the doors here, this is the only way.";
	continue the action;

Everything Opens is a recurring scene.  Everything Opens begins when the purple capsa of opening is open.  Everything Opens ends when the purple capsa of opening is closed.

When Everything Opens begins:
	carry out everything rezrovving;

To carry out everything rezrovving:
	say "As you open the purple capsa, an almost-palpable wave of force emanates from it, as the power of the revealed scroll of rezrov is released.[lb]";
	if the lone guard is in the location:
		if the tiny closed padlocks are enclosed by the lone guard:
			say "As the shockwave of magic reaches the guard, the padlock on her uniform closest to you pops open.  Then in succession, all the other padlocks she's wearing pop open as well, in perfect concentric circles in order of how distant they are from the scroll.  [if Sneaking is happening and No More Purple is happening]You[otherwise]As her eyes lock with yours, you[end if] realize, somewhat belatedly, that you've given her the ability to triangulate on your position[if Sneaking is happening and No More Purple is happening].  Even though you're invisible, she looks directly at you and leaps as she sings a song of fire[otherwise].  Without hesitation, she sings a song of fire and leaps straight at you[end if], before you even have time to let go of the capsa.
			
			The door behind her opens silently as your feathers crisp and she tackles you to the ground.";
			end the story saying "You have been captured.";
			stop the action;
		otherwise if the collection of tiny padlocks are in the location:
			if the sense_of_duty of the lone guard is greater than 3:
				say "The shockwave of magic reaches the guard, and the few padlocks she's been able to re-attach to her uniform spring open and fall off again.  She looks down at them in shock for a second, then gives an angry cry and takes to the sky, calling her fellow squad mates.[lb]";
				now the closeness of Being Chased is 1;
	repeat with item running through lockable things:
		if the item is locked:
			now the item is unlocked;
			if the player can see the item:
				say "[The item] clicks as it unlocks!";
	repeat with item running through openable things:
		if the item is closed:
			if the item is a capsa:
				if the player can see the item:
					say "The magic of [the item] prevents it from being opened.";
			otherwise if the item is the great hall doors:
				if the great hall doors are barred:
					if the player can see the item:
						say "The doors strain to open, but are blocked by something.";
				otherwise:
					now the great hall doors are open;
					say "The double doors of the great hall fly open!";
			otherwise:
				now the item is open;
				if the player can see the item:
					say "[The item] flies open!";
	if the rucksack is worn:
		say "The straps and buckles on your rucksack fly open and it falls!";
		now the rucksack is carried by the player;
		if Everything Falls is happening and the gold capsa is enclosed by the location:
			say "Fortunately, it hovers in midair due to the scroll of down, so you're able to immediately grab it again.";
		otherwise:
			try dropping the rucksack;
	if the location is Librum Landing Cradle:
		now the closeness of Being Chased is 1;
		if (the small collection of tiny padlocks is not in the location or the sense_of_duty of the lone guard is less than 4) and the reset state of the woodpeckers is 5:
			say "[lb]The guard takes off into the sky, calling her squad mates to join her.";
	if the lone guard encloses the tiny closed padlocks and the Librum Landing Cradle encloses the lone guard:
		move the tiny closed padlocks to the Void;
		move the small collection of tiny padlocks to the Librum Landing Cradle;
	If the reset state of the woodpeckers is 5:
		Now the woodpeckers are activated; [Starts the 'being chased' scene]
		Now the reset state of the woodpeckers is 0;

Check closing something openable during Everything Opens:
	if the noun is not a capsa:
		say "Try as you might, a mystical force prevents you from closing [the noun]." instead.


Check locking something with during Everything Opens:
	say "Try as you might, a mystical force prevents you from locking [the noun]." instead.

Check wearing the rucksack during Everything Opens:
	say "A mystical force prevents you from fastening the buckles on the rucksack, and you are unable to put it on." instead.

Reset Sensors is a recurring scene.  Reset Sensors begins when Everything Opens ends.  Reset Sensors ends when the reset state of the woodpeckers is 5.

Every turn during Reset Sensors:
	if Everything Opens is happening:
		now the reset state of the woodpeckers is 0;
	otherwise:
		increase the reset state of the woodpeckers by 1;
		if the reset state of the woodpeckers is 1:
			say "From everywhere in the Aerie, you hear the woodpeckers drumming in the Pounding dialect: 'Reset Locks!  Repeat!  Reset Locks!";
		if go go go is happening and the reset state of the woodpeckers is less than 5:
			increase the reset state of the woodpeckers by 1;
		
Doors Re-close is a recurring scene.  Doors Re-close begins when Everything Opens ends.  Doors Re-close ends when cannot-close.  

The lone guard has a number called sense_of_duty.  The sense_of_duty of the lone guard is 0;

Every turn during Doors Re-close:
	if Being Chased is not happening:
		if the Librum door is open:
			now the Librum door is closed;
			if the player can see the Librum door:
				say "The guard closes the Librum door.";
		otherwise if the Librum door is unlocked:
			now the Librum door is locked;
			if the player can see the Librum door:
				say "The guard locks the Librum door.";
		otherwise if the small collection of tiny padlocks is in the Librum Landing Cradle:
			if the sense_of_duty of the lone guard is 0 and the player can see the lone guard:
				say "The lone guard looks at the collection of tiny padlocks, then at her uniform, and sighs.";
			otherwise if the sense_of_duty of the lone guard is 1 and the player can see the lone guard:
				say "The lone guard kicks at tiny padlock, and watches it balefully.";
			otherwise if the sense_of_duty of the lone guard is 2 and the player can see the lone guard:
				say "The lone guard looks at the collection of tiny padlocks, then peers into the mist.";
			otherwise if the sense_of_duty of the lone guard is 3 and the player can see the lone guard:
				say "The lone guard sighs, and slowly begins re-attaching the tiny padlocks to loops on her uniform.";
			otherwise if the sense_of_duty of the lone guard is 4 and the player can see the lone guard:
				say "The lone guard gets stuck trying to attach a recalcitrant padlock to her left shoulder strap, but finally gets it attached again.";
			otherwise if the sense_of_duty of the lone guard is 5:
				if the player can see the lone guard:
					say "The lone guard picks up the last of the tiny padlocks and attaches it to her belt with a definitive 'click'  Sighing, she resumes her post.";
				move the collection of tiny padlocks to the Void;
				move the tiny closed padlocks to the well-fitting uniform;
				now the tiny closed padlocks are part of the well-fitting uniform;
			increase the sense_of_duty of the lone guard by 1;
		otherwise if the small collection of tiny padlocks is not in the Void:
			if the player can see the lone guard:
				if a random chance of one in four succeeds:
					say "The guard runs a talon over the empty loops on her uniform, and angrily glares into the mist.";
		if the garden door is open:
			now the garden door is closed;
			if the player can see the garden door:
				say "A guard flies down and closes the garden door.";
		otherwise if the garden door is unlocked:
			now the garden door is locked;
			if the player can see the garden door:
				say "The guard locks the garden door and returns to their perch.";
		[LS DEBUG:  revisit this if I implement other guarded doors at some point.]

To decide whether cannot-close:
    if Everything Opens is happening, decide yes;
    decide no.

Check taking during Being Chased:
	if the noun is the rucksack:
		say "You snag the straps of your rucksack as you swoop by.";
		continue the action;
	otherwise if the noun is not following and go go go is not happening and the noun is not enclosed by the player:
		say "You don't have time to grab things!" instead;

Check taking the small collection of tiny padlocks:
	if the small collection is in the location and the lone guard is in the location:
		if sneaking is happening and the hunting cloak is invisible:
			say "Even when you're invisible, if you take something right from under the guard's beak, she's going to notice.  And when you're (shudder) walking, you wouldn't be able to get away." instead;
		otherwise:
			say "You are pretty sneaky, but not sneaky enough to snag a pile of padlocks from underneath the lone guard's beak." instead;
		


Section down

The gold capsa of down is a capsa in the rucksack.  The description is "The gold capsa turned out to contain a scroll of Down[first time], as became evident in the disorienting moment when the sages first opened the capsa, and everyone and everything suddenly fell towards it[only].  It is [if the gold capsa is closed]closed, preventing the power of the scroll from affecting the area[otherwise]open, allowing the scroll's power to pull everything towards itself, instead of towards the ground[end if]."  Understand "rudenj" as the gold capsa.

A scroll of rudenj is a scroll in the gold capsa.  The name is "RUDENJ". Understand "down" as the scroll of rudenj.

lost_gold is an achievement in the Void.  The printed name is "Didn't Need That, Anyway".  The description is "Escape the Raven Guard by sacrificing the capsa of down.";

After dropping the gold capsa during Everything Falls:
	if Being Chased is happening:
		if the great hall doors are barred:
			now hall_open is helped;
		say "You put on a burst of speed to temporarily disappear from view in the mist, then toss the gold capsa one direction and fly off the opposite direction (easy enough to tell:  it's 'straight up') while it drifts into the mist.  It works:  you feel 'down' shift direction as the Raven Guard plow into it, and in the confusion, you disappear further into the fog.
		
		They take it with them all over the Aerie as they search for you, maybe hoping you'll fall into them, but you've practiced enough back in the village to know how to adjust your flight to stay aloft.  [if the great hall doors are barred]You hear some commotion as they search for you near the Great Hall.  You can't make out the words, but it has the cadence of an argument about who's to blame for something.  [end if]Finally, gravity rights itself again--they've given up!  They have the gold capsa, but they've given up chasing you.";
		now the great hall doors are not barred;
		if the purple capsa is open:
			now the great hall doors are open;
			move hall_open to the Trophy Room;
			write out achievements;
		now the gold capsa is closed;
		move the gold capsa to the Void;
		now the most_recent of the Trophy Room is lost_gold;
		escape and recover instead;

Check dropping the rucksack during Everything Falls:
	if Being Chased is happening and the rucksack encloses the gold capsa:
		say "You could ditch the gold capsa and get away by using it as bait, but you'd rather not lose the rucksack in the process." instead;

Check opening the gold capsa in the Librum Itself:
	say "In case of emergencies, most things in the Librum were locked down so as to not fall over if the gold capsa of 'down' was accidentally opened[if black_escape is greater than 0] (though the old storage cabinet's attachments seem to not have held)[end if].  So nothing flies off the shelves to hit you when you open the gold capsa of 'down' in here on purpose.  Which is good!  Less good is that since 'down' now points straight at you, the guard outside was alerted to your presence.  She shows up at the door with a wicked grin.";
	end the story saying "You have been captured." instead;

Check opening the gold capsa in the Upper Great Hall:
	if the wooden bar is in Upper Great Hall:
		say "The large wooden bar that once held the double doors closed flies right at you!  You try to dodge, but there's just not enough room, and it hits you hard enough to knock the wind out of you.  The Raven Guard arrives before you can recover.";
		end the story saying "You have been captured." instead;

['rudenj' from rudenį: 'fall' in Lithuanian.]

Everything Falls is a recurring scene.  Everything Falls begins when the gold capsa is open.  Everything Falls ends when the gold capsa is closed.

Cantedness is a kind of value.  The cantednesses are grounded and upended and offline.

Everything falls has a cantedness.  The cantedness of Everything falls is upended.

Is_now_up is a room that varies.  Is_now_up is the Void.

When Everything Falls begins:
	Now is_now_up is the location;
	if the gold capsa is enclosed by in_forest:
		now Everything falls is grounded;
		say "Immediately, 'down' now means 'towards the gold capsa' instead of 'towards the earth'.  Even being ready for it, it takes you a few flaps to reorient yourself, and you blink away the slight dizziness.  Then you pause.  No sounds from the Aerie.  Apparently, the new 'down' is close enough to the old 'down' that whatever sensors they have up there didn't detect a change.  Good.";
	otherwise if the location is Lower Great Hall:
		say "Immediately, dozens of artifacts and collectibles rain down, flying out of the display nooks all around you.  When the Raven Guard shows up, it's almost more of a rescue than a capture, as they have to dig you out of a huge pile of detritus before finally being able to reach and close the gold capsa.
		
		It's still definitely also a capture, though.";
		end the story saying "You have, indeed, been captured.";
	otherwise:
		say "Immediately, 'down' now means 'towards the gold capsa' instead of 'towards the earth'.  After a brief moment of disorientation, you right yourself, wings pulling you 'up' with just enough force that you remain level.
		
		[i]Note: for convenience, 'down' and 'up' comands will continue to work as they did, referencing ground-relative geography instead of gold capsa-relative geography[r].";
		now Everything Falls is upended;
		now the woodpeckers are activated;

Every turn during Everything Falls:
	if the gold capsa is enclosed by in_forest:
		now Everything falls is grounded;
	otherwise:
		now Everything Falls is upended;
		now the woodpeckers are activated;
	if the gold capsa is enclosed by the player:
		repeat with X running through things in the location:
			if X is following:
				if X is the wooden bar:
					if a random chance of 1 in 4 succeeds:
						if Constance is wounded:
							say "Your luck runs out as you dodge the wrong way, and the wooden bar smacks into your side.  You get the wind knocked out of you, the bar stops blocking the guard from following, and in an instant, they've swarmed you, bearing down on you from all directions.";
							end the story saying "You have been captured.";
							stop the action;
						otherwise:
							now Constance is wounded;
							say "As you dodge to avoid a Raven Guard, the wooden bar catches your side as it spins by, leaving a gash!";
					otherwise:
						say "The wooden bar pinwheels past you as you change direction yet again, then spins back, keeping the Raven Guard at bay.";
				otherwise if a random chance of 1 in 2 succeeds:
					if the gold capsa is enclosed by the rucksack:
						if the rucksack is open:
							move X to the rucksack;
							say "[The X] finally spirals towards the gold capsa and falls into the rucksack!";
						otherwise:
							say "[The X] crashes into the rucksack, bounces off, and arcs back towards you.";
					otherwise:
						say "[The X] bounces off the gold capsa, pinwheeling away before arcing back towards you again.";
				otherwise:
					say "[The X] spins past you as you dodge away from the Raven Guard, and turns in a lazy arc to follow you again.";
			otherwise if X is loose:
				now X is following;
				say "[The X] falls towards you, only missing because you keep dodging to avoid the Raven Guard.";
		if is_now_up is not the location:
			repeat with X running through things in is_now_up:
				if X is following:
					move X to the location;
					say "[The X] follows you from [the is_now_up], spiraling towards the gold capsa of down.";
	if location is Great Hall Landing Cradle and the gold capsa is enclosed by the player:
		if the Great Hall doors are barred:
			now the great hall doors are not barred;
			move the wooden bar to the Upper Great Hall;
			say "As you swoop over the Great Hall, you hear a crash from the other side of the doors";
			if Everything Opens is happening:
				say ", and they fly open";
				now the great hall doors are open;
			say "!";
		Otherwise if the the great hall doors are open and the wooden bar is in Upper Great hall:
			move the wooden bar to the location;
			now the wooden bar is following;
			if the hunting cloak is worn:
				say "Suddenly the great wooden bar that had been holding the Great Hall doors closed tumbles towards you!  You instinctively try to spread your wings to fly out of the way, the cloak stops them, and you overbalance and fall over.  The bar finishes its trajectory and lands on you, leaving you unable to move.  [if the hunting cloak is invisible]The Raven Guard can't see you, but they have no trouble following 'down'.";
				end the story saying "You have been captured.";
				stop the action;
			otherwise if the closeness of Being Chased is at least 2:
				now the closeness of Being Chased is 2;
				say "Suddenly the great wooden bar that had been holding the Great Hall doors closed gets dislodged, and flies at you!  You turn and weave, managing to keep it from hitting you.  The Raven Guard fall back as the spinning bar careens through the air!";
			otherwise:
				say "Suddenly the great wooden bar that had been holding the Great Hall doors closed gets dislodged, and flies at you!  You turn and weave, managing to keep it from hitting you.";
	if location is Librum Landing Cradle and the gold capsa is enclosed by the player and the black capsa is enclosed by the Librum itself and the Librum door is open and black_escape is 4:
		say "A black capsa flies through the doors of the Librum, up towards you!";
		move the black capsa to the location;
		now the black capsa is following;
		now the most_recent of the Trophy Room is no_reading;
	Now is_now_up is the location;



When Everything Falls ends:
	Now Everything Falls is offline;
	Now is_now_up is the Void;
	if the woodpeckers are activated:
		say "You [if Sneaking is happening]stagger[otherwise]twist and right yourself[end if] as 'down' returns to its normal state[if the closeness of Being Chased is at least 2].  The Raven Guards struggle to right themselves again, and take a moment to recover[end if].";
		if the closeness of Being Chased is greater than 2:
			now the closeness of Being Chased is 2;
	otherwise:
		say "You steady yourself as 'down' returns to its normal state.";
	repeat with X running through loose things:
		[say "[the X].";]
		now the X is not following;
		if the X is not enclosed by the player and the X is enclosed by the location:
			if the location is High Above:
				say "[The X] plummets down towards the Aerie.";
				move the X to the Great Hall Landing Cradle;
			otherwise:
				say "[The X] falls to the ground, ignored by the Raven Guard.";
		if the X is the wooden bar and X is enclosed by the player:
			say "The wooden bar is ripped from your talons and falls!";
			try dropping the wooden bar;

Last Check taking when the player is Horatio:
	say "You don't need anything.  You just need to find the prodigal." instead;



[When Everything Falls begins:
	carry out everything rudenjing;
]
[To carry out everthing rudenjing:
	If the location is in_forest:
]

Section Hasten

The red capsa of hasten is a capsa in the rucksack.  The description is "The red capsa turned out to contain a scroll of hasten[first time], which you and the sages eventually determined when it became clear that everyone was acting as if they were high on guarana berries[only].  It is [if the red capsa is closed]closed, preventing the power of the scroll from affecting the area[otherwise]open, allowing the scroll's power to make everything happen much faster[end if]."  Understand "haste/quiste" as the red capsa.

A scroll of quiste is a scroll in the red capsa.  The name is "QUISTE".  Understand "haste/hasten" as the scroll of quiste.

[quiste: quick + haste]

Does the player mean examining the red capsa: it is likely.

Go go go is a recurring scene.  Go go go begins when the red capsa is open.  Go go go ends when the red capsa is closed.

When go go go begins:
	say "You speed up, and so does the wind[if the location is librum landing cradle and horatio distracts the guard is happening], and Horatio's chatter[end if].  You wriggle, feeling the delightfully fast responses from every muscle in your body.
	
	From everywhere in the Aerie, you hear the drumming of Woodpeckers in the Pounding dialect:  'Target is quick, repeat, target is quick.  Remember you are too.'  Gah; of course they would have practiced flying in a hasted state.  You'll just have to rely on the fact that the increase is proportional.";

When go go go ends:
	if the location is not Nursery_Door and the location is not Nursery_itself:
		say "From everywhere in the Aerie, you hear the drumming of Woodpeckers in the Pounding dialect: 'Target is slow again, repeat, target is slow.'  Just in case they couldn't tell they were slow themselves.  Actually, you do recall some Raven Guards from your childhood that would have needed to be told.  Ah, poor James.";

Section Zork Grand Inquisitor Live Forever

A black capsa is a capsa in the Librum Itself.  "[if black_escape is 0]In the back of the lower level, in a storage cupboard, you find the black capsa, just as Horatio described to you.  You wonder how he managed to find out where it was, but suppose the man has his conversational tricks[otherwise if black_escape is 1]In the back of the lower level, the storage cupboard Horatio told you about has fallen over, but the black capsa is in it, just as he said it would be[otherwise if black_escape is 2]You find the storage cupboard Horatio told you about, but it's fallen over, and the drawers have been pulled out.  You do see the black capsa in a corner of an open drawer[otherwise if black_escape is 3]The storage cupboard Horatio told you about has fallen over and looks like it was sacked--there's random detritus all over the Librum.  Fortunately, you also see the black capsa in a corner of the upper level[otherwise]The black capsa is sitting right at the base of the Librum door.  If the door had been open when you flew by with the gold capsa activated, you're sure it would have just flown out the door[end if]."  The black capsa can be explained.  The black capsa is not explained.  The description is "[igram_description].".  Understand "igram" as the black capsa.

A storage cupboard is scenery in the Librum Itself.  It is an open openable container.  The description is "A disused storage cupboard sits in a corner of the lower level.  It's the one Horatio told you the black capsa would be[if black_escape is greater than 0].  Of course, that was before you flew by with 'down' on, and basically looted the place remotely[end if]."  Understand "drawer/drawers/fallen/over/pulled/open/sacked/detritus" as the storage cupboard.

The black capsa can be named.  The black capsa is not named.

After opening the black capsa:
	now the black capsa is named;
	continue the action;

To say igram_description:
	if Horatio is not remembered:
		if the black capsa is named:
			say "The black capsa contains a scroll of 'igram'.  You don't think that means 'health', but there's a lot you don't know about the capsae in general.  Did you just miss it, last time?  ";
		otherwise:
			say "It's another capsa, from the Librum!  Did you just miss it, last time?  ";
	otherwise:
		say "The black capsa contains a scroll of igram, [if the black capsa is explained]which apparently turns purple things invisible.  The only capsae you've heard of having an ability even vaguely like that, you assumed were jokes.  Now you're not so sure.[otherwise]but Horatio won't tell you what that means.[end if]  ";
	say "It is [if the black capsa is closed]closed, preventing the power of the scroll from affecting the area[otherwise]open, freeing the scroll's power[end if]"

A scroll of igram is a scroll in the black capsa.  The name is "IGRAM".  Understand "make purple things invisible" as the scroll of igram.  Understand "invisible/invisibility" as the scroll of igram.

No More Purple is a recurring scene.  No More Purple begins when the black capsa is open.  No More Purple ends when the black capsa is closed.

When No More Purple begins:
	Now the hunting cloak is invisible;
	if the purple capsa of opening is visible:
		say "For a moment, the purple capsa seems to flicker.  But you look again, and nothing seems to have changed.";
	if the various artifacts are visible and the cloak posts are not in the location:
		Move the cloak posts to the location;
		say "Suddenly, two hunting cloaks in a display of ancient pre-historical artifacts disappear!";
	otherwise if the hunting cloak is on the cloak posts and the cloak posts are in the location:
		say "The hunting cloaks disappear again.";
	otherwise if the hunting cloak is visible:
		say "The hunting cloak disappears again.";

When No More Purple ends:
	Now the hunting cloak is purple;
	if the various artifacts are visible and the cloak posts are not in the location:
		Move the cloak posts to the location;
		say "Suddenly, two hunting cloaks in a display of ancient pre-historical artifacts appear!";
	otherwise if the hunting cloak is on the cloak posts and the cloak posts are in the location:
		say "The hunting cloaks appear again.";
	otherwise if the hunting cloak is visible:
		say "The hunting cloak appears again.";
	If the location is Nursery_Door:
		say "Horatio reappears, wearing the other cloak.";

back_in_black is an achievement in the Void.  The printed name is "One Bird's Trash".  The description is "Obtain the black capsa of igram.".

Got The Black is a scene.  Got the Black begins when the player encloses the black capsa.  Got the Black ends when the player encloses the cloak.

When Got The Black begins:
	now the most_recent of the Trophy room is back_in_black;


A green capsa is an open capsa on the desk.  The description is "The green capsa of health contains a scroll of taclor.  It is [if the green capsa is closed]closed, preventing the power of the scroll from affecting the area[otherwise]open, allowing the scroll's power to heal to affect the area[end if]."  Understand "taclor/heal" as the green capsa.

A scroll of taclor is a scroll in the green capsa.  The name is "TACLOR".  Understand "heal/health" as the scroll of taclor.


[PC and Rucksack ends here.]


[Lucian's Scenes by Iron ChIF begins here.]
[Use authorial modesty.]

Book 0 Ongoing Effects

[Being Chased by Iron ChIF begins here.]
[Use authorial modesty.]

Constance can be cruising, speeding, or super-fast.  Constance is cruising.

Momentum is a recurring scene.  Momentum begins when Constance is speeding.  Momentum ends when the time since Momentum began is two minutes.

When Momentum ends:
	if Constance is speeding:
		now Constance is cruising;
		say "The momentum you had from your dive wears off[if Being Chased is not happening].  Fun while it lasted![otherwise].[end if]";

Super-momentum is a recurring scene.  Super-momentum begins when Constance is super-fast.  Super-momentum ends when the time since Super-momentum began is three minutes.

When Super-momentum ends:
	if Constance is super-fast:
		now Constance is cruising.

Woodpeckers are people in the Void.  The description is "I dunno if you'll ever actually see these guys; they just sound the alarms from offstage."
Woodpeckers can be activated. Woodpeckers are not activated.
Woodpeckers have a number called reset state. The reset state of the Woodpeckers is 5.

The Raven Guard are people in the Void.  They are plural-named.  "Several members of the Raven Guard fly at you, as you dodge and circle to avoid them."  The description is "Black as night, apart from the silvered knives they wear on their talons, and the golden razors that line their beaks[if the Librum landing cradle is visited].  It looks like the lone guard from the Librum has joined them, too[end if]."  Understand "guards/black/silvered/knives/talons/golden/razors/beaks/ravens/squad/lone" as the raven guard.

answering the raven guard that something is talking your way out.
telling the raven guard about something is talking your way out.
asking the raven guard about something is talking your way out.
asking the raven guard for something is talking your way out.
chatting the raven guard is talking your way out.

instead of talking your way out:
	say "The Raven Guard will be happy to 'discuss things' with you after you are safely captured.";

Instead of attacking the raven guard:
	say "The Raven Guard are built for combat.  You are not.  You are built for speed and visual acuity.";

Instead of kissing the raven guard:
	say "The enemies-to-lovers trope works slightly better outside of an active combat scene.";

Instead of showing something to the raven guard:
	say "The Raven Guard will be happy to look at [the noun] after they've captured you and are going through your things.";

Instead of giving something to the raven Guard:
	say "The Raven Guard will be happy to look at [the noun] after they've captured you and are going through your things.";

Instead of waking the raven guard:
	say "They are [i]most decidedly[r] not asleep.";

Instead of touching or pushing or pulling or rubbing the raven guard:
	say "As tempting as it is to bonk one of them on the head as you skim by, you unfortunately are not quite that much better than they are.";

Being Chased is a recurring scene.  Being Chased begins when the woodpeckers are activated.  Being chased ends when the woodpeckers are not activated.

Being Chased has a number called closeness.  The closeness of Being Chased is 0.
Being Chased has a room called starting_line.  The starting_line of Being Chased is the Void.

When being chased begins:
	Now the starting_line of Being Chased is the location;
	Move the lone guard to the Void;
	Now the sense_of_duty of the lone guard is 0;
	say "From... well, from everywhere in the Aerie, it seems, Woodpeckers start drumming out messages in their Pounding dialect:  [if Everything Falls is happening and Everything Falls is not grounded]'Intruder!  The enemy is DOWN. Repeat!  The enemy is DOWN.'  You realize that creating a gravity well pointing straight at you makes you an easy target to find[otherwise]'Intruder! Estimated direction is...' and then each one individually seems to be telegraphing the direction from them to you.  You can't discern any one drummer from any other drummer, but you can at least tell that each seems to be drumming on sheets of metal that differ from each other, so every frequency is unique.  That makes the information somewhat useless to you, because you've not been trained to distinguish Pounding at different frequencies.  And because you already know where you are.  Sadly, the Raven Guards are indeed trained to distinguish Pounding frequencies.
	
	And if they didn't know where you were, they do now[end if].";

Constance can be quick-doing.  Constance is not quick-doing.

Before examining something during Being Chased:
	say "Lightning fast, you glance over:  [nb]";
	continue the action;

First check opening a closed door during Being Chased:
	say "The Raven Guard is not going to stop chasing you to give you enough time to open [the noun].  Though perhaps if you explained that you only wanted to go into an enclosed space so they could better surround and capture you, they'd consider it?" instead;

Every turn during Being Chased:
	If the current action is not examining and the current action is not taking inventory:
		Increase the closeness of Being Chased by 1;
		[say "closeness: [the closeness of being chased].";]
		If the closeness of Being Chased is 1:
			If the thickness of the grey mist is 1:
				say "You suddenly feel warmer, and hear an exultant song of the sun in the distance.  The [one of]queen must have Ikniq working for her[or]queen's Ikniq warriors are at it again[stopping], trained to try to burn away your fog.";
			otherwise:
				say "A pervasive heat along with an exultant song of the sun wash over you, and in a flash, [nb]";
				If the thickness of the grey mist is at least 14:
					now the thickness of the grey mist is 8;
					say "the heavy mist you summoned half-boils away[nb]";
				Otherwise if the thickness of the grey mist is at least 10:
					now the thickness of the grey mist is 4;
					say "the rolling mist you summoned boils away to almost nothing[nb]";
				Otherwise if the thickness of the grey mist is greater than 1:
					say "the [mist density] mist you summoned boils away back to equilibrium[nb]";
					now the thickness of the grey mist is 1;
				say "[one of].  Crap.  The queen must have Ikniq working for her now[or].  The queen's Ikniq warriors are after you again[stopping].";
		Otherwise if the closeness of Being Chased is 2:
			move the raven guard to the location;
			If the hunting cloak is worn:
				if No More Purple is happening:
					if Everything Falls is happening and Everything Falls is not grounded:
						say "The Raven Guard fly in, unable to see you, but flying 'down' straight at you.  Stuck in this cloak, you hardly have any mobility, and after the first confused guard crashes into you, it doesn't take the rest long to figure out where you are.";
						end the story saying "You have been captured.";
						stop the action;
					otherwise:
						say "[if the location is outdoors]You manage to hobble away from where you were just far enough that when the Raven Guard show up, you're no longer there.  You remain silent while they fly in frustrated circles, unable to find you[otherwise]You press yourself against the wall, barely daring to breathe as the Raven Guard fly in and search everywhere for you.  But they're not searching for anything invisible, and eventually give up in anger[end if].";
						escape and recover;
				otherwise:
					say "The Raven Guard fly in, and see your purple cloak almost immediately against the foliage.";
					end the story saying "You have been captured.";
					stop the action;
			Otherwise if the location is Upper Great Hall:
				say "The Raven Guard pour through the double doors, and you have nowhere to maneuver.";
				end the story saying "You have been captured.";
				stop the action;
			Otherwise if the location is not the starting_line of Being Chased:
				If the starting_line of Being Chased is High Above:
					say "You've dived straight into a squad of Raven Guards, on their way up to accost you.  Fortunately, your speed helped you avoid most of them, but one guard's talon catches you on your side as you twist by them.";
					Now Constance is wounded;
				Otherwise if the starting_line of Being Chased is in_forest:
					say "Your ascent brings you right into a squad of Raven Guards, on their way to accost you.  You see them only barely before they see you, and it's just enough to mostly avoid them.  Still, a slash from a Raven Guard beak catches you in the side as you twist past.";
					Now Constance is wounded;
				Otherwise:
					say "You've barely left the [the starting_line of Being Chased] when a squad of Raven Guards wheels in from behind, hot on your tail!";
			Otherwise:
				say "A squad of Raven Guards appears, and their war cries exalt as they spot you.  You weave through the air, tumbling and twisting as you try to avoid them.";
			Now the starting_line of Being Chased is the location;
		Otherwise if the closeness of Being Chased is at least 3:
			move the raven guard to the location;
			If the starting_line of Being Chased is not the location:
				Now the starting_line of Being Chased is the location;
				Now the closeness of Being Chased is 2;
				determine evasion;
			Otherwise if the wooden bar is following:
				say "The guards try to reach you, but keep getting blocked by the large spinning wooden bar.";
				now the closeness of Being Chased is 2;
			Otherwise if the closeness of Being Chased is 3:
				say "The guards charge, but you manage to evade their attack.";
			Otherwise if the closeness of Being Chased is 4:
				say "Two guards snap at you, and while both touch nothing but feathers, a third slashes you with his silvered talons.  They're about to overwhelm you.";
				Now Constance is wounded;
			Otherwise:
				say "You're faster and more maneuverable than they are, but there are more of them.  One charges you directly, and when you veer off to avoid her, another crashes into you.  The rest swarm you instantly.";
				end the story saying "Your luck has run out.";
				stop the action;

[Note: 'Ikniq' actually means 'Fire' in Iñupiaq.  According to The Internet.]

go_go_go is an achievement in the Void.  The printed name is "Go, Go, Go!"  The description is "Escape the Raven Guard by diving while 'haste' is active."

falcon_dive is an achievement in the Void.  The printed name is "Hunting Stoop".  The description is "Escape the Raven Guard with a very long dive.";

true_down is an achievement in the Void.  The printed name is "True Down".  The description is "Escape the Raven Guard by altering where 'down' is.";

falcon_mist is an achievement in the Void.  The printed name is "Mist Me!".  The description is "Escape the Raven Guard into your summoned fog.";



To determine evasion:
	If Everything Falls is happening and Everything Falls is upended:
		say "You dodge and weave and almost get away from your pursuers, but when 'down' always points straight at you, even when they can't see you, they always know where you are.";
	Otherwise if Super-Momentum is happening:
		if go go go is happening:
			say "Your extra speed from the capsa of haste lets you pull ahead, since your pursuers are only proportionally faster than they were.  You manage to use the extra distance to dodge behind a poplar and plummet, out of view of any stray Raven.";
			now the most_recent of the Trophy Room is go_go_go;
		otherwise:
			say "You expertly twist at breakneck speeds, weaving through three Ash trunks, over a branch, and around and behind a Redwood, where you halt, twist, and dive straight down the trunk, out of view of any stray Raven.";
			now the most_recent of the Trophy Room is falcon_dive;
		escape and recover;
	Otherwise if Momentum is happening:
		If the thickness of the grey mist is at least 10:
			say "You dive into the thickest spot of mist you can find, and put on a final burst of speed before changing direction and dropping like a stone.  It works:  your pursuers fly blindly into the mist where you used to be, cawing angrily when they realize they can't see you any more.";
			now the most_recent of the Trophy Room is falcon_mist;
			escape and recover;
		Otherwise if Everything Falls is happening and Everything Falls is grounded and the player does not enclose the gold capsa:
			say "As you dive, you use your knowledge of 'true down' to give yourself an edge, pulling around a tree at an angle that should be impossible; diving and twisting through gaps in the branches that shouldn't be possible.  Your closest pursuer crashes into a branch, and the others peel off to avoid him.";
			now the most_recent of the Trophy Room is true_down;
			escape and recover;
		Otherwise:
			say "Your speed puts more distance between you and your pursuers, but it's not quite fast enough, or the mist isn't thick enough, or both, and your pursuers manage to keep you in sight.";
	Otherwise:
		If the thickness of the grey mist is at least 12:
			say "The [mist density] mist is too thick for the Raven Guard to pursue you far.  You dodge around a tree, and disappear.";
			now the most_recent of the Trophy Room is falcon_mist;
			escape and recover;
		Otherwise:
			say "The Raven Guard pursues you determinedly through the [mist density] mist.";

To escape and recover:
	Now the woodpeckers are not activated;
	Move the Raven Guard to the Void;
	Move the Lone Guard to the Librum Landing Cradle;
	Now the closeness of Being Chased is 0;
	[Now the thickness of the grey mist is 1;]
	Now Constance is cruising;
	say "[lb]The Ravens[apostrophe] frustrated caws echo through the [mist density] mist as they fly off.  In time, the woodpeckers cease their drumming, and the cawing fades as well.  Protocol would dictate that they return to guarding priority items.  If there were any reserves left, they would be called up, but the Red Plague has affected the Raven Guard as sorely as your own community.";
	if Horatio is not remembered:
		if the rucksack is not enclosed by the player:
			say "[lb]You retrieve your rucksack and any fallen capsae, and plot a now-unseen course back to the familiar currents above the Aerie to ponder your next move.";
			move the rucksack to the player;
		otherwise:
			say "[lb]You plot a now-unseen course back to the familiar currents above the Aerie to ponder your next move.";
		if the purple capsa of opening is not enclosed by the player:
			move the purple capsa of opening to the rucksack;
		if the red capsa is not enclosed by the player:
			move the red capsa to the rucksack;
		if the gold capsa is open:
			now the gold capsa is closed;
		if the gold capsa is not enclosed by the player and the gold capsa is not in the Void:
			move the gold capsa to the rucksack;
		if the black capsa is not enclosed by the player and the black capsa is not in the Librum itself:
			move the black capsa to the rucksack;
		move the rucksack to the player;
		move the purple capsa of opening to the rucksack;
		move the red capsa to the rucksack;
		Move the player to High Above, without printing a room description;

After waiting during Being Chased:
	if the hunting cloak is worn:
		say "You wait, anxiously skittish, and unable to fly." instead;
	otherwise:
		say "You circle evasively, trying to avoid the Raven Guard." instead;

When Being Chased ends:
	if cell door is open:
		now Horatio is remembered;
	otherwise:
		try looking;

Hanging out is a recurring scene.  Hanging out begins when constance is cruising and the closeness of Being Chased is 0.  Hanging out ends when constance is not cruising or the closeness of Being Chased is not 0.

[Being Chased ends here.]


Not Recovering is a recurring scene.

Not recovering begins when Constance is wounded and the capsa of opening is open.
Not recovering ends when the capsa of opening is closed.

Not recovering has a number called timer.  The timer of not recovering is zero.

Every turn during Not Recovering:
	if the player is not Horatio and Horatio is not stage three:
		if the timer of not recovering is at least six:
			if go go go is happening:
				say "[one of]Your wound continues to bleed.  It's not a huge wound, but the blood is flowing rather quickly[or]Your wound aches.  You look down at it, and it's still open and a fast small trickle of blood drips down your side[or]Your open wound really should have closed by now, but it continues to bleed[stopping].";
			Otherwise:
				say "[one of]Your wound continues to lightly bleed[or]Your wound aches.  You look down at it, and it's still open and bleeding[or]Your open wound really should have closed by now, but it continues to lightly bleed[stopping].";
			now the timer of not recovering is 0;
		otherwise:
			increase the timer of not recovering by one;

[Above code courtesy of ideas from https://intfiction.org/t/every-third-turn/1443]

Actually Recovering is a recurring scene.
Actually Recovering begins when Constance is wounded and the capsa of opening is closed.
Actually Recovering ends when Constance is not wounded.

When Actually Recovering begins:
	[Perhaps eventually check to see if the capsa of health is open, but the premise of the game is that it's open the entire time; we'd have to let the player close it and then get wounded for this to not happen.]
	[Never had to worry about this!  Grabbing the capsa of health triggers the end-game, so it's literally always open.]
	now Constance is not wounded;
	say "You feel your skin prickle where you were wounded, and look down.  To your amazement, your wound has closed and the bleeding stopped.  As you watch, even the line from the cut disappears, and the feathers around it fluff out again[first time].
	
	It's the scroll of Health.  It [i]has[r] to be.  It's actually here!  And active.  Hmm[only]."
	[We'd need different text if the player gets wounded more than once, but right now, they can't even get wounded once, so let's just leave it for now.]
	[Nor this!  Eventually added a thing that will knock Constance out if she was wounded, but there's always only ever two levels: fine or wounded]

Sneaking is a recurring scene.  Sneaking begins when the player is wearing the hunting cloak.  Sneaking ends when the player is not wearing the hunting cloak.

Check going up during Sneaking:
	say "You can't fly with this damn cloak on!" instead.

Check going down during Sneaking:
	say "You can't fly with this damn cloak on!" instead.

Last Check opening a capsa when the location is Nursery_itself or the location is Nursery_Door:
	if the noun is the purple capsa:
		say "All the doors are already open.  You made it." instead;
	otherwise if the noun is the gold capsa:
		say "There's no need." instead;
	otherwise if the noun is the red capsa:
		say "Things are already moving too quickly." instead;
	[Don't worry about the green, black, or blue]

Check wearing the hunting cloak when the location is Nursery_itself:
	say "No, not with Ash here." instead;

Before giving the green capsa to someone:
	say "You're going to need to take it first.  And decide what to do with it." instead;

Last Check closing a capsa when the location is Nursery_itself or the location is Nursery_Door:
	if the noun is the purple capsa:
		say "You're already past all the doors; you don't need to open or close them again." instead;
	otherwise if the noun is the gold capsa:
		[It shouldn't be possible to get here with an open capsa of down, but just in case]
		now the gold capsa is closed;
		say "You return gravity to its normal state." instead;
	otherwise if the noun is the red capsa:
		now the red capsa is closed;
		say "You close the capsa of haste, hoping your beating heart will slow a bit.  It does not." instead;
	otherwise if the noun is the green capsa:
		say "No.  Ash needs it." instead;
	[Don't worry about the black or blue]

Ash_chat is a scene.  Ash_chat begins when the player is in the Nursery_itself for the first time.

When Ash_chat begins:
	say "Perched on the open window looking out over the forest is a fledgling Red Wing Clan.  As you enter, they turn and their face and feathers perk up with delight.  'Aunty Constance!' they chirrup, and dash across the room to bury their face in your downfeathers.
	
	You stroke the feathers on their head gently.  The feathers crackle worryingly.  'Hi, Ash,' you say.  'It's good to see you, too.'
	
	Their face sufficiently smothered, Ash pops out again excitedly.  'It's been so long!  Did you know there's a whole new wing of the southwest aerie?  Momma took me there just the other day, and...'"

Every turn during Ash_chat:
	say "Ash prattles happily, telling you [one of]about how they're putting in a huge room just for sick people[or]about meeting a Throckwright, and getting to see his pouch of seeds[or]about a model treehouse they made out of sticks[or]a long convoluted story about drama between their stuffed animals[or]about a flock of wild birds that lived beneath their window for a whole season[or]that they secretly dislike dust baths[or]how they need to build another treehouse because Mr. Featherstick doesn't like the first one[or]about a song they're trying to learn[or]that Loudbeak Threewings can't go anywhere without her special stash of dried fruits for snacks[cycling]."

Ash is a person in Nursery_itself.  "Ash doesn't look particularly healthy, but they're in high spirits."  The description is "Ash's flight feathers are starting to come in, though they won't be able to actually fly for at least another year.  Worryingly, the feathers are drooping and seem brittle; early signs of the Red Plague.  It's not a stage of the plague you've ever seen before; maybe the capsa halted the disease's progression, but didn't cure it?  How long have they been like this?"


answering the Ash that something is chit-chat.
telling the Ash about something is chit-chat.
asking the Ash about something is chit-chat.
asking the Ash for something is chit-chat.
chatting the Ash is chit-chat.

instead of chit-chat:
	say "There's no way you're getting a word in edgewise in this chatterfall.";

Instead of attacking the Ash:
	say "You playfully bat Ash on the head.  They stick their tongue out at you.";

Instead of kissing the Ash:
	say "You give Ash a peck on the shoulder.  They preen.";

Instead of showing something to the Ash:
	say "You consider doing that, but are enjoying the chatter too much to break it up.";

Instead of giving something to the Ash:
	say "You'd never see it again, and you probably need it.  Maybe later.  If there's time.  If.";

Instead of waking the Ash:
	say "Hoo boy, if Ash fell asleep you definitely would not wake them up again.";

Instead of eating Ash:
	say "What is it about children that makes them seem so delicious?  You playfully peck at Ash's head, and they squeal in delight.";

Instead of taking Ash:
	say "You could take Ash with you.  When you go.  Maybe."

Constance can be determined.  Constance is not determined.

Last check taking green capsa:
	if Constance is not determined:
		now Constance is determined;
		say "You take a deep breath.  Once you take the green capsa, you'll be the 'holder' of taclor, and Horatio will ask you for your decision.  Should you get it now?";
		if player consents:
			say "You're right.  It's time.";
		otherwise:
			say "You turn to look at Ash and the Nursery once more.  Before things change." instead;
	otherwise:
		say "It's time.";

Report taking green capsa:
	stop the action;


Finale is a scene.  Finale begins when the player encloses the green capsa.

When Finale begins:
	switch to cyoa at F1

F1 is a page.  The description is "[one of]You hold the capsa of health in your hands, turning it over and looking at it from all sides.  It's what you came here for.  To take it back home and save your mother.  Your people.  Is it still that simple?

'You are now the holder of the scroll of taclor' says Horatio, as Ash continues to tell you about what it was like to see a real jaguar this one time.  'Will you have me read it?'[or]Horatio looks at you expectantly.[stopping]"

F2a is a dead-end.  It is for F1.  It is one-off.
The cdesc is "'Ash was holding it before.  Why can't they make the decision?'"
The description is "Horatio looks at Ash, then looks at you.  Ash continues to tell you about having to get their desk grown twice in two months because they were growing [i]so fast[r].

Yeah, OK, fair."

F2b is a dead-end.  It is for F1.  It is one-off.
The cdesc is "'What will happen when you read it?'"
The description is "'I know not,' Horatio replies.  'I know that it will grant a power related to the scroll's effect to some percentage of all people.  Everywhere.  Regardless of class or heritage or clan.  My guess is that it will improve their health--perhaps make them immune, perhaps give them regeneration, perhaps grant them an immortality, of sorts.'

'Will it affect people right now?' you ask, 'Or just people in the future?  People hatched tomorrow?  Eggs laid tomorrow?'

'The stories do not say,' he replies.  'What difference is five years; twenty years to the march of history?'

'It makes a difference to me,' you say.

'Indeed,' he replies."

F2c is a dead-end.  It is for F1.  It is one-off.
The cdesc is "'Why not let the queen... let Aubrey decide?'"
The description is "The feathers on Horatio's neck ruffle.  'She has already denied me.  Every day, I send a new request, and every day, she sends her rejection.  If you leave, I will keep asking her.  She may change her mind.  She may not.  You may know her better than I.'"


F3 is a page.  It is for F1.
The cdesc is "Leave without the capsa."
The description is "[i]{Switching to Horatio.}[r]

You watch as the struggle plays out across Constance's face, while Ash happily prattles behind her.  Slowly, she sets the capsa back down on the desk, and just stares at it.  'I can't do it,' she finally says.  'I can't condemn Ash for the sake of my people.  I can't condemn anyone for the sake of a fairy-tale promise.'"

F3A is a page.  It is for F3.  It flips to F3_1.
The cdesc is "Try to explain, again, that it's not a fairy tale.".
The description is "'It's no fairy tale,' you say.  'It is my heritage.  I know---'

Constance cuts you off.  'You don't know what will happen.  The fairy tale is that it will help me, today.  That it will help Ash.  That my mother--' her voice goes quiet, hoarse, 'won't die.'

It's true. You hope things will get better, in the end.  You believe it, with all your being.  But you can't say anything about her people, or Ash.";

F3B is a page.  It is for F3.  It flips to F3_1.
The cdesc is "Let her process.".
The description is "Though it's difficult, you try not to bristle.  She has no particular reason to believe you, and you don't even have much hope to offer.  She might even believe, as you do, that eventually things would be better.  But she has to live with what's true now.";

F3_1 is a page.
The description is "Constance reaches out a wing, and strokes Ash's head.  'I love you, kid,' she tells them.  'Say hi to your mom for me.'

'You're not staying?' they ask, suddenly stricken.  

Constance shakes her head, steps onto the window ledge, and launches herself into the mist.  A keening cry from Ash, of confusion and loss.  You feel it as well, as you've felt it for years.  You had forgotten it could be given voice.

As if summoned by the cry, the queen--Aubrey--rushes in, with her own cry of worry, replaced by one of relief.  She engulfs Ash in her wings.  'You're okay; you're okay,' she repeats like a mantra, eyes closed, holding Ash tight.  She opens them to see taclor on the desk.  A questioning look at you.  'She didn't take it?  She didn't have you read it?'

'No,' you reply.  'She held it.  She could have done either.'

Aubrey breathes out and deflates.  The fight that sustained her for so long is over.  When your opponent concedes, victory in their grasp, what then?  You sense an opening."

F3_1A is a page.  It is for F3_1.
The cdesc is "Ask her to let you read the scroll."
The description is "'You are, once again, the holder of taclor,' you say.  'Will you let me read it, and release its power to everyone, as the Gods intended?'

Aubrey stares out at the impenetrable mist.  At nothing; at everything; at Constance.  She's actually considering the question, perhaps for the first time in years.  Ash looks up at her, a question and the beginnings of understanding on their face.  'Ask me again tomorrow,' she finally says, eyes fixed on the mist; Ash under her wing.

'Indeed,' you reply."

A page-toggle rule for F3_1A:
	move world_change to the Trophy Room;
	write out achievements;
	end the story finally saying "The question is reconsidered."

F3_1b is a page.  It is for F3_1.
The cdesc is "Now is not the time."
The description is "An opening, yes, but if you move too quickly, you risk it closing again.  Aubrey catches your eyes and you gaze at each other for a long moment, understanding passing between you.  Ash watches you both, looking back and forth.

Aubrey sighs.  'Your imprisonment is rescinded.  You're obviously safe.  And if you will, I would have you be Ash's ward.  They cannot leave the scroll, but there are those who also need it, so they both will need to travel.'  She looks out into the mist, and you imagine that the whorls of mist spilling into the window are the echoes of Constance's wingbeats.  'Teach them what you know.  There may be more we can do.' You raise an eyebrow. 'More we can do short of that.'

'I will do my best to protect and teach the child,' you promise.  'What I know.  And what I believe.'

Aubrey nods absently, still looking out the window.  Ash closes their eyes, and rests their head under her wing."

A page-toggle rule for F3_1B:
	move world_change to the Trophy Room;
	write out achievements;
	end the story finally saying "A generational transfer begins."



F4 is a dead-end.  It is for F1.  It is one-off.
The cdesc is "Leave with the capsa, and leave Ash behind."
The description is "This is what you came here to do.  You have the capsa of health.  Your mother; your village needs it.  You could leave.  

If it hadn't been Ash who would suffer, you probably could do it.  Random people working for the queen versus your own mother?  Your own people?

But not Ash.  You have to find another way."


F5 is a page.  It is for F1.
The cdesc is "Leave with the capsa, and take Ash with you."
The description is "[i]{Switching to Horatio.}[r]

Constance closes her eyes and sighs.  'I can't do it,' she says.  'I can't condemn Ash for the sake of my people.  I can't condemn my people for the sake of Ash.  I can't condemn both for the sake of a fairy-tale promise.'  You wince at that; you had hoped you had been [i]slightly[r] more convincing.  But before you can object, Constance has moved on.

'Kid,' she says, turning to Ash.  'Put this on.  We're going on a trip, and it's cold out there.'  Ash delights in putting on a genuine invisibility cloak, then hops on her back, vibrating with anticipation.

Constance turns to you.  'You're welcome to join us.  But if you stay, can you... try to explain?  To Aubrey?'  The queen."

F5A is a page.  It is for F5.
The cdesc is "Leave with Constance."
The description is "If Constance ever changes her mind about taclor, you want to be there when she does.  'I will go with you,' you say, and Constance nods.  You join the two of them on the window ledge, and silently launch yourselves into the mist.  Behind you, you hear a strangled cry of a familiar Red Wing.  Constance flinches, but doesn't look back.

'She'll come after you, you know,' you say.

'Yes,' she sighs.

You wait.  From her back, a disembodied voice exclaims, 'Aunty Constance!  I can't see myself [i]at all[r]!'

'This was always the plan,' she continues quietly, after a moment.  'Get the capsa of health, gather everyone, then... migrate.  Like our ancestors[if C5a is previously displayed].'  She turns to look at you.  'I've been thinking about our conversation, about taking the capsa to where it's needed.  It'll make us easier to find, but you're right that hoarding is what got us into this mess in the first place[end if].'

You feel a surge of empathy for this brash young woman, trying her best to patch together a good outcome for as many people as she can manage.  She may change her mind and let you read the scroll one day, but even if she doesn't?  Migrating with it to try to help people doesn't seem so bad."

A page-toggle rule for F5A:
	move world_change to the Trophy Room;
	write out achievements;
	end the story finally saying "A new migration begins."

F5B is a page.  It is for F5.
The cdesc is "Stay to talk with the queen.".
The description is "'I will stay,' you tell her.  Contance holds your gaze for a moment, then nods and launches herself into the mist.

You steel yourself.  Sure enough, the queen bursts into the room scant minutes later.  When she sees you and not Ash nor the capsa of health, she screams and flies at you, knocking you to the floor, talon on your neck.  'Where are they?' she shrieks.

Crap.";

F5B1 is a page.  It is for F5B.
The cdesc is "Try to explain."
The description is "You had hoped to have a day or two first.  To explain after the shock wore off.  That plan is not to be, and you can barely breathe.  'Constance-' you choke, 'her mother.  Couldn't sacrifice Ash.  Tried to-'

The queen cuts you off.  'WHERE?' she demands.";

F5b2 is a page.  It is for F5B and F5B1.  It flips to F5_cellEnd.
The cdesc is "Refuse to speak."
The description is "There's nothing you can say that will divert this force of nature.  But you don't have to participate.  You close you eyes and wait for the inevitable.

Which doesn't come.  The pressure from the talons relents, there's commotion and rattling and the Pounding of woodpeckers, and by the time you open your eyes, the room is filling with guards and the queen is staring out the window at the thinning fog."


F5B3 is a page.  It is for F5B and F5B1.  It flips to F5B4.
The cdesc is "Offer to lead her to them."
The description is "'I can sense... capsae,' you wheeze.  'Lead you... taclor.'

The queen lets you up, and you gasp.  She stabs a button, and woodpeckers somewhere in the complex pound out a message.  In seconds, guards fill the room.

'Gather arms,' she tells them.  'We strike the Falcon Clan tonight.'

[bstars]";

F5B4 is a page.
The description is "All too soon, you're flying at the front of a well armed war party.  Constance's mist has long since evaporated, and a full moon and a thousand stars light your way over the forest.  For far too long, the capsa of health stays in one place, and your guidance is hardly needed--they knew where the Falcons nested.  And then--thank the gods--the capsa moves again.  You breathe a quiet prayer to Stohleblanc, and bank to the south.

'What?' the queen demands, suspicious.

'Course correction,' you reply.  'They're moving out.'

The queen consults the guards, and sends a handful straight on anyway, before joining you with the rest.  'If they haven't left, things will not go well with you.  Or them.'

You shrug.  'I cannot say who left and who didn't.  I only know the capsa of health is on the move.'

Eventually, the dispatched guards join you again, reporting that the Falcon nests were indeed abandoned.  You continue your trek south, and feel the capsa gradually getting further and further away to the north.   You'll never get to read it.  But maybe it can do some good.";


A page-toggle rule for F5B4:
	move world_change to the Trophy Room;
	write out achievements;
	end the story finally saying "Taclor is no longer hoarded.";

F5C is a page.  It is for F5.
The cdesc is "Stay, but wear the cloak of invisibility.".
The description is "'I will stay,' you tell her, 'but I doubt she will listen right away.  I will wait for the right moment.'  

Contance nods.  'Thank you,' she says.  'For everything.'  Then she turns and launches herself into the mist.

You disappear under the cloak, and turn to the door.  But before you can leave the room to find a quiet spot in the castle to hide, the queen rushes in to the room.  'Ash!' she cries.  'Ash!'  Then her eyes fall on the empty desk where taclor sat, and a high, thin warbling cry escapes her throat.  Her legs buckle, and she collapses to the floor, her keening only broken when she plucks at her feathers in distress.

You can't stay here and watch without her knowing you're here.  You had hoped to wait a few days, for the shock to pass.  But you simply can't.  You pull back the hood, and let the cloak fall behind you.  She doesn't see you.  She isn't seeing anything.

'Aubrey,' you say.  The name you once knew her by, when her mother was still queen, and you were still free to wander the Aerie, watching her and Constance play.

Her head whips around and she's on you in a flash, wing against your throat, talon pushing you into the wall.  'What did you do?  Where are they?'  Fierce, pure anger; grief abandoned.

'Constance took the capsa of health for her people.  For her mother.  But she was unwilling to sacrifice Ash to do so.'  You try to keep your voice calm, measured.

Reluctant understanding flashes across Aubrey's face, replaced quickly with grim determination.  'That's no reason to [i]kidnap my child[r],' she rasps."


F5C1 is a page.  It is for F5C.  It flips to F5_cellEnd.
The cdesc is "'Indeed.'"
The description is "Aubrey glares intently at you, then releases your chest to stab at a hidden button with a talon.  Distant woodpeckers rattle some sort of call in their Pounding dialect, which you never learned, but can guess what it must mean.  'Please--' you start, but Aubrey cuts you off with a look.  In seconds, the room fills up with guards."

F5_cellEnd is a page.  The description is "'Take this one back to his cell,' she tells them.  'Then gather arms.  We hit the Falcon Clan tonight.'

[bstars]
It's hard to gather any information from your cell, but the fact that you continue to feel taclor moving in the distance tells you what you most wanted to know.  It never returns to the Aerie.  And you never hear the name 'Ash' again."

A page-toggle rule for F5_cellEnd:
	move world_change to the Trophy Room;
	write out achievements;
	end the story finally saying "Constance and taclor are free."

F5C2 is a page.  It is for F5c.
The cdesc is "Offer to take her to them, alone."
The description is "'Do you want to talk to her?' you ask.  'Alone?'  You can't be the go-between.  Somehow, the two of them need to talk.

Emotions play across her face, and her feathers rise and settle, then rise and settle again.  She fixes you with a steady glare that you try to meet as calmly as you can, though talons are digging into your stomach.  Then, with quiet intensity, 'yes'.  She stares at you longer, unflinching.  You nod slightly.

Then she releases you, and in one fluid motion, she's out the window, flying after Constance, her friend, her love, her subject, her enemy.  You follow, focusing on the pull of taclor.  The same pull that guided you here a decade ago.  A pull, for all its mystique, much more straightforward than the pull between Constance and Aubrey.

You hope you can guide them together.  And to where they can let go."

A page-toggle rule for F5C2:
	move world_change to the Trophy Room;
	write out achievements;
	end the story finally saying "A meeting awaits."



F6 is a page.  It is for F1.
The cdesc is "Let Horatio read the scroll of taclor."
The description is "'I can't do it,' you say.  'I can't take the scroll for only myself.  There's no good solution here.  Even the scroll itself only halts the disease; it doesn't cure it.  Nobody wins.'

You turn to Horatio.  'And maybe nobody I care about wins if you read this, but lots of people I don't know win.  And maybe we win anyway.  Or maybe you're just crazy.  It's a risk.  Life is risk.  In the balance, maybe that's enough.'

You take a deep breath, and hand him the scroll.  'Read it,' you tell him.

Horatio nods, pulls out a small key, inserts it into the side of the capsa, and begins to slowly turn it, exposing the rest of the writing as the scroll is rolled from one rod to the next.  He reads.

Or, rather, he sings.  You've never heard a buzzard sing like this before, but then again, you've never heard [i]anyone[r] sing like this before.  It's a deep, primal song of awakening; of understanding; of comfort.  Ash's beak drops open in amazement and wonder.

Then Aubrey, your friend, your love, your queen, your enemy, bursts through the door.  'Ash!' she cries, then, seeing them safe, turns to Horatio.  'No!' she gasps, and launches herself at him."

F6a is a page.  It is for F6.  It flips to F7.
The cdesc is "Get between Aubrey and Horatio."
The description is "You fling yourself across the room to stop her, but before she even reaches you, a wave of sound catches her and stops her in her tracks.  Her eyes roll back, and she falls twitching to the floor."

F6b is a page.  It is for F6.  It flips to F7.
The cdesc is "'Aubrey, no!'"
The description is "You start to shriek at Aubrey to stop, that this is the only way, that you love her but she can't hoard this power for only herself, or even for Ash, but before you even get a word out, a wave of sound catches her and stops her in her tracks.  Her eyes roll back, and she falls twitching to the floor."

F7 is a page.  The description is "Horatio continues to sing.  Ash's face is a mixture of horror and delight."

F7a is a page.  It is for F7.  It flips to F8.
The cdesc is "Rush to Aubrey's side."
The description is "You rush to the side of your love, cradling her head with your wing.  'Aubrey, darling, be all right.  Listen to me.  [i]Be all right[r].  I need you.  I need the true you.'".

F7b is a page.  It is for F7.  It flips to F8.
The cdesc is "Shield Ash from the sight."
The description is "'Ash!' you cry.  You wrench them physically so they stand facing Horatio and away from their stricken mother.  'Listen to the song.  Remember it!' you cry."

F7c is a page.  It is for F7.  It flips to F8.
The cdesc is "Tell Horatio to stop.".
The description is "'Horatio!  It's too much!  You have to stop!' you cry.  You might better yell at a waterfall.  The song tumbles from his mouth, filling the room, the Aerie, the world with sound."

F7d is a page.  It is for F7.  It flips to F7.  It is a one-off.
The cdesc is "The song's affecting Aubrey, but not you and Ash.  Why?"
The description is "Your eyes dart wildly across the scene, trying to figure things out; trying to understand.  A ripple; a run in the music.  A corresponding shudder in Aubrey's wings.  You spread your own wings.  Nothing."

F8 is a page.  The description is "The song reaches a crescendo.  The Aerie itself threatens to shake apart."


F8a is a page.  It is for F8.  It flips to F9.  It is cancelled by F7b and F7c.
The cdesc is "Hold Aubrey tight."
The description is "You close your eyes and wrap Aubrey with both wings, not to shield her from the song, which is everywhere, even your bones, but just to let her know she's not alone.  She can't be alone when she dies."

F8b is a page.  It is for F8.  It flips to F9.  It is cancelled by F7a.
The cdesc is "Turn to Aubrey."
The description is "You turn to see Aubrey's arched back, and she spasms again on the cold floor.  You dash to her side, just as her wing flails out sideways, knocking you off your feet.  You land heavily on the ground, in the perfect position to see Horatio's feet, lifted slightly off the ground, though his wings are tucked in tight."

F8c is a page.  It is for F8.  It flips to F9.  It is cancelled by F7a.
The cdesc is "Physically attack Horatio."
The description is "You rush at Horatio, but before you get within a wingspan, you hit some sort of wall of--energy?  Magic?  Sound?  You hammer futilely against it."

F8d is a page.  It is for F8.  It flips to F9.  It is cancelled by F7a.
The cdesc is "Wait for the inevitable."
The description is "You can do nothing to stop this.  You can do nothing to help.  But you can listen.  And you can remember.  The song burns its way into your memories."

F9 is a page.  The description is "You didn't expect the apocalypse to be this pretty.

The song is everywhere.  The song is everything.  It is morningsong.  It is evensong.  It is the tide, and the moons, and the stars.

And threading it together, it is life.  Health.  The roost.  The nest.  A bubble of comfort pushing back against the dark.

And then it's done.  The writing fades from the scroll, and Horatio gently rewinds it back to the title.  'TACLOR'.

Aubrey relaxes, wakes.  Looks into your eyes.  'I'm so sorry,' she whispers.  She glances at her child.  'Ash...' she explains.

'I'm sorry, too,' you answer.  'My mother,' you explain.  You both look at the other with glistening eyes.

Then Aubrey gets a strange expression on her face.  'I... I [i]remember[r],' she says.  'The... Ash.  Come here.'

Obediently, Ash comes and perches by her side.

Aubrey begins to sing.  It's not The Song.  Nothing will ever be The Song.  But it's an echo.  The song of the Taclorim.

As she sings, Ash's pallor fades, and their feathers straighten.  A hunch you didn't realize they had straightens out.  'Oh!' they exclaim.  'OH!'  Their eyes shine.

You help Aubrey to her feet and she rises to her full height, full of queenly majesty.  The four of you look at each other.  'Come,' she says.  'We have work to do.'"

A page-toggle rule for F9:
	move world_change to the Trophy Room;
	write out achievements;
	end the story finally saying "You have changed the world.";

world_change is an achievement in the Void.  The printed name is "Taclor".  The description is "Finish the game, deciding what to do with the scroll of health.".

[Lucian's Scenes ends here.]

[Horatio by Iron ChIF begins here.]
[Use authorial modesty.]

Horatio's story is a scene.  Horatio's story begins when Horatio is remembered.  Horatio's story ends when the location is High Above.

Forgotten Brig is a room.  "A small but cosy cell, grown with austerity but basic comfort in mind.  Your now-unlocked [cell door] leads west."

Instead of going nowhere from Forgotten Brig:
	say "Your cell door is west.  There are no other exits.";

The cell door is a door.  It is west of Forgotten Brig and east of Disused Hallway.  It is closed and locked.  The description is "Ironwood-grown and maintained; your cell door is [if the cell door is closed]closed[otherwise]open[end if]."

cell_contents is scenery in Forgotten Brig.  The printed name is "cell contents".  The description is "A straight roost by a desk for writing, and a scooped roost for sleeping.  Enough space to spread your wings.  A rope wall for excercise.  Not bad."  Understand "cell/contents/austerity/comfort/straight/scooped/roost/space/spread/rope/wall/desk" as cell_contents;

Does the player mean examining cell_contents: it is likely;

Horatio is a man in Forgotten Brig.  "[Horatio room desc]."  The description is "[Horatio_desc]."  Understand "buzzard/bald/head/talons/hunched/shoulders/mottled/black/brown/feathers/wing/wings/neck/sage" as horatio.  Understand "red head" as horatio.  Understand "red talons" as horatio.

To say Horatio room desc:
	If the location is the Librum Landing Cradle:
		if Being Chased is happening:
			say "Horatio is perched clutching a redwood branch on the edge of the cradle, watching you";
			if Everything Falls is happening and Everything Falls is upended:
				say ", and swaying different directions as you pass by overhead and the gold scroll pulls him around";
				if black_escape is less than 4:
					say ".  He seems to be trying to get your attention.  So, one more thing to worry about, in addition to the armed guard after you";
		otherwise:
			say "Horatio is talking [if go go go is happening]quickly[otherwise]slowly[end if] to the [lone guard] about [one of]the ethics of a monarchy[or]his grandchildren[or]regrettable fashion choices from the youth of today[or]whether the dot on the back of his neck looks infected[or]how to get to Zenostan (is that a real place?) from here[or]whether her mother was the Isabella he once knew[or]some meandering story about flying to the park[cycling], driving the guard quietly insane";
	otherwise:
		if the hunting cloak is worn and the hunting cloak is not purple:
			say "Horatio is nearby.  You can sense him, though you can't see him";
		otherwise:
			say "Horatio is here, watching you with quiet aplomb and patience";

To say Horatio_desc:
	if the player is Horatio:
		say "You're a member of the Buzzard Clan, and fit the stereotype fairly well: bald red head and red talons, hunched shoulders, mottled black and brown feathers.  You've balded down past your neck now, betraying your advanced age";
	Otherwise If Everything Falls is happening and Everything Falls is upended and black_escape is less than 4:
		say "Horatio has his head cocked as if paying attention to something he can sense but not see.  He makes eye contact with you, and points to [the entry black_escape of librum_directions]";
	otherwise:
		say "Horatio is an ancient Buzzard Clan sage of sorts, you suppose, given that he was jailed for heresy back in the day"

Horatio can be remembered.  Horatio is not remembered.

The blue capsa of mist is a capsa carried by Horatio.  The description is "[If the player is Horatio]The blue capsa of mist contains a scroll of bostrat, but its power has long since faded, as the Gods intended[otherwise]You suppose that now that the scroll's power has been spread to Bostrat everywhere, that capsa itself is little more than a trinket; a curiosity.  But you can't help but think of it almost reverentially.  In a very real sense, it [i]made[r] you.  A part of you[end if]."  Understand "bostrat" as the blue capsa.

A scroll of bostrat is a scroll in the blue capsa.  The name is "BOSTRAT".  Understand "mist/water" as the scroll of bostrat.

The description of the scroll of bostrat is "While '[name]' can be clearly read at the top of the scroll, the rest of the script has faded away[if the player is Constance].  That power now lives, in part, within your own being[end if]."

Instead of dropping the blue capsa when the player is Horatio:
	say "The queen and her advisors were unimpressed by the capsa, dismissing it as an obvious fake.  But you think you can use it to convince Constance.  Better hang on to it.";

Instead of inserting the blue capsa into something when the player is Horatio:
	say "The queen and her advisors were unimpressed by the capsa, dismissing it as an obvious fake.  But you think you can use it to convince Constance.  Better hang on to it.";

Disused Hallway is a room.  It is east of Nope.  "The only time you ever saw anyone in this hallway was when Georg came to give you your meals, or clean the cell.  The living walls, still elegantly patterned, even here, self-replenish, and the floor carries away shed bark through the [grate].  It leads west into the living area, and your old [cell door] leads east.";

A grate is a closed openable enterable container in Disused Hallway.  The description is "The grate conveys unneeded materials to the outside, and the forest floor.  [if open]Rezrov has done its job there, too: it lies open[otherwise]The grate is folded down, closed[end if].";

Check going west from Disused Hallway:
	say "Your place is not with the denizens of this Aerie, but with the prodigal daughter, now returned, and the capsa she seeks." instead.

After opening grate:
	say "You grasp the grate with your talons and carefully fold it upward, allowing access.";
	stop the action;

Before taking the grate:
	try opening the grate;

Before attacking the grate:
	try opening the grate;

Instead of going nowhere from Disused Hallway:
	if the noun is down:
		try entering the grate instead;
	if the noun is inside:
		try entering the grate instead;
	otherwise:
		say "The hallway runs east to west, and there's a grate on the floor you could enter.";

After entering the grate:
	say "You flatten yourself to the floor and, hearing your bones creak, roll into the space behind the grate.  Using your minimal throck ability, you whisper a song to the veins of this place: 'I am extra.  I am not needed.  Take me from this place, which will renew itself through my absence.'
	
	After a few moments, you feel an undulation in the slick rippled floor beneath you, and you are compressed even further, as its peristalsis slides you slowly, and then more rapidly, away from your only home for the last ten years.  Then with a sudden >plop<, you're ejected into space.
	
	You try to spread your wings, but your reaction time is not what it was, and you hit wirey netting before fully stopping yourself.
	
	No matter.";
	Move Horatio to in_forest;
	Now cell door is open; [Just in case]
	stop the action;


When Horatio's story begins:
	say "[bstars]";
	wait for any key;
	clear the screen;
	say "You wait, expectantly.";
	wait for any key;
	say "[lb]Silently, your cell door unlocks, then swings open.";
	wait for any key;
	say "[lb]Well above your cell, you sense [if the gold capsa is not in the Void]quiste, [end if]rezrov, and rudenj settle in their movements until they make lazy circles, high above the Aerie[if the gold capsa is in the Void].  Quiste follows a different path, and ends up inside the Royal Quarters, you think.  Unfortunate[end if]";
	if the black capsa is enclosed by Constance:
		say ".  Oh, and igram is with them.  Resourceful girl.  Taclor remains in place, quiet";
	otherwise:
		say ". Igram and taclor remain in place, quiet";
	say ".[lb]It is time.";
	Now the player is Horatio;
	Try looking;

When Horatio's story ends:
	say "[bstars]";
	wait for any key;
	clear the screen;
	switch to cyoa at H1.


Section Pull the Black

librum_directions is a list of directions that varies.  librum_directions is {northwest, west, up}.
black_escape is a number that varies.  black_escape is 1.

When play begins:
	sort librum_directions in random order;
	[say "[librum_directions]";]


Before going from Librum Landing Cradle during Everything Falls:
	if black_escape is 1:
		if the noun is entry black_escape of librum_directions:
			say "As you fly off, you hear a distinct 'thunk' from inside the Librum.  Something significant fell over or shifted in there.";
			now black_escape is 2;
	otherwise if black_escape is 2:
		if the noun is entry black_escape of librum_directions:
			say "As you dodge a closing Raven Guard and fly [noun], you hear another whump from inside the Librum.";
			now black_escape is 3;
	otherwise if black_escape is 3:
		if the noun is entry black_escape of librum_directions:
			say "You loop under a tree branch and head [noun], but before you get very far, ";
			if the Librum door is open:
				say "a black capsa flies out through the Librum doors, following you!";
				move the black capsa to the location;
				now the black capsa is following;
				now the most_recent of the Trophy Room is no_reading;
			otherwise:
				say "you hear something whap against the Librum door behind you.  Something almost escaped from in there.";
			now black_escape is 4;

no_reading is an achievement in the Void. The printed name is "If Constance Will Not Come To The Capsa...".  The description is "Get the black capsa out of the Librum without actually entering the Librum[if not helped] (and without Horatio's help)[end if].".  no_reading can be helped. no_reading is helped.

Section The Chat

H1 is a page.
The cdesc is "Start a new conversation with Horatio."
The description is "'Hello, Constance,' you say as you approach to fly adjacent to her broad circling.  'Good job.'

She peers at you, and you know she can make out every barb on each of your feathers.  Patiently, you wait.

'You're Horatio,' she finally says.  'Didn't the queen... imprison you for heresy?'

'Indeed,' you reply.

'And I just unlocked your cell,' she says.

'Indeed,' you reply.

'They wouldn't tell me what the heresy was.  I guess that's the point of trying to suppress dangerous ideas.'

This time, you just wait, and slightly incline your head.  Saying 'Indeed' again might make her self-conscious about her babbling.

There's a pause.

'What was it?' she asks."

H2 is a page.  It is for H1 and H3a and H3b.  It is cancelled by H2a.
The cdesc is "Tell her about capsae."
The description is "'I believe that the gods gave us the capsae to benefit everyone,' you say.

Constance frowns.  'That's not... a dangerous idea.  I mean, people may not truly believe in the gods much today, but they're generally seen as having been... nice?  I guess?'".

H2a is a page.  It is for H2.
The cdesc is "Explain."
The description is "'When I say everyone, I mean everyone.  In the whole world.  As far as the Clans extend.'

Constance chuckles.  'A little hard for the capsae to do [i]that[r].  Longest range I know of is, like, two miles.'

'Indeed,' you reply.

Constance locks her wings so she can turn and look at you intently for several seconds as she glides.  She probably thinks she's being tested.  Which would be good, because she is.  You wait.

'So.  You believe that the capsae are being misused.  That the kingdoms hoarding them should instead... share them?  Move them around?  Shuffle them, so each kingdom gets a bit of their power every so often?'

'Misused, yes,' you reply.  'And, yes, it would be in the spirit of that initial gift to share them more.  But what I proposed to your queen, and to other queens and kings of other realms, goes beyond this.'

Constance thinks for a bit.  [if H3 is not previously displayed]Then she rolls her eyes.  'OK, yeah, I have no idea what you're talking about.'[otherwise]Then her eyes widen.  'You want to read the scrolls!' she exclaims.[end if]"

H2b is a page.  It is for H2a.  It is cancelled by H3.
The cdesc is "Ask her about scrolls."
The description is "'What do you do with scrolls?' you ask.

Constance scoffs.  'Read them!' she exclaims, then laughs, as another thought occurs to her. 'Which is the one thing you [i]can't[r] do with the scrolls in the capsae, because nobody knows...'  She trails off, and gives you another look.  'Wait, really?  You?'";

H2c is a page. It is for H2a.  It is cancelled by H3.
The cdesc is "Tell her about scrolls."
The description is "'The scrolls were meant to be read, not hoarded', you say.

Constance thinks.  'Hmm.  So, you want to research the dead language on the scrolls?  Figure it out again?  Do some sort of cross-Kingdom research project, where everyone agrees to send the texts of their capsae to everyone else?  That seems reasonable, but again, it's not a particularly dangerous idea.'"

H3 is a page.  It is for H1, H2b, and H2c.
The cdesc is "Tell her what you can do."
The description is "'You've seen the scrolls themselves?  The writing on them?'

'[apostrophe]Indeed,[apostrophe]' Constance replies, raising an eyebrow.  You grin.

'What you may not know is that those symbols are not found in any other form of known writing.  There are fragments of writing from before the capsae.  They differ.  Some say it is the language of the gods themselves.'

'Woo, fancy,' says Constance.  'In other words, they're gibberish.'

'No,' you reply.  'I can read them.'

'Oh?  What do they say?' Constance asks."

H3a is a page. It is for H3.
The cdesc is "Tell her the truth."
The description is "'I don't know,' you tell her.

Constance sputters.  'But you--' she begins, then cuts herself off, looking at you askance again.  She's a clever woman.  You wait, tipping your wings synchronously with hers as you turn into another circuit.

'So.  You learned the language from somewhere.'  She thinks.  You wait.  'No, you said the symbols matched no other writing.  You were born knowing the language.  It's your heritage, as I was born knowing how to summon mist.'

You let her think, the lack of any contradiction from you enough of an encouragement.

'Which means you've either just never seen an actual scroll--which seems unlikely; the queen didn't get mad at you until several days had passed--or,' she slows down, but continues, 'or you were born with the ability to read, but not understand.'

'Inde--'  Constance shoots you warning look.  'Yes.  That's it exactly.  Congratulations.'  You bob your head and splay your wingfeathers in a grin of approval.

[if H2 is not previously displayed]'So I assume this is some sort of backstory for what your heresy actually is?' Constance asks[otherwise]'So, you want to read a capsa's scroll.  And you won't know what you're reading.' says Constance[end if]."

H3b is a page. It is for H3.
The cdesc is "Wax poetical a bit."
The description is "'I have read and felt what it was like to thunder across the plains as a gazelle from the scroll of izyuk.  I have read and felt the desperate yen of attraction from the scroll of obidil. From the scroll you now hold in your possession, I have read and felt what it is to be the very earth itself, spinning through the cosmos.'

Constance looks at you.  A beat.  'So you don't know.'

'I don't know,' you agree.

Constance waits.  OK, you can give her this one.

'I don't know because reading is my heritage, as the ability to summon mist is yours.  But understanding is not part of that gift.'

'Well that sucks,' Constance says.

'It is a touch of the language of the gods,' you say, simply.  'It is enough.'

The two of you make another circuit.  The mist streams off the ends of your outstretched wings in curled eddies.

[if H2 is not previously displayed]'So I assume this is some sort of backstory for what your heresy actually is?' Constance finally asks[otherwise]'So, you want to read a capsa's scroll.  And you won't know what you're reading.' says Constance, after a bit[end if]."

H4 is a page.  It is for H3a, H3b, and H2a.  It needs H2 and H3.
The cdesc is "Share your speculation."
The description is "'I will not know what it is I'm saying, but I have a guess about what will happen.

And no capsae holder I have yet met will risk such a thing,' you say."

C1a is a page.  It is for H4.
The cdesc is "[if the player is Horatio][i]{Switching to Constance}: [end if][r]Scoff at 'capsae holder'."
The description is "You scoff.  'No queen or king, you mean.'

'You personally currently hold three capsae, more than some kingdoms,' replies Horatio, 

You laugh.  '[apostrophe]Cause I stole [apostrophe]em!  And they weren't even the one I wanted; I just didn't know what color I was after!'

'Nevertheless,' you tell her, 'you are their holder. If you told me you wanted me to read one, I then could.'"

A page-toggle rule for C1a:
	now the player is Constance;


C2 is a page.  It is for C1a.
The cdesc is "He needs instructions?"
The description is "'Wait.  So, I could order you to read a capsa?  And the magic would compel you to do it?' you ask, incredulously.

'No.  I will not read one without the holder's permission, but I may refuse any order,' Horatio replies.

'[apostrophe]Will not.[apostrophe]  So you're not compelled to follow instructions, but you're also not compelled to ask permission.  It's just a personal choice,' you say.

Horatio winces slightly.  'I suppose, technically, you are correct.  It is a tradition among the Readers who know the history.'"

C2a is a page.  It is for C2.  It flips to C3.
The cdesc is "Getting information out of this guy is like pulling mist out of the desert.  Say nothing."
The description is "You say nothing, and wait expectantly."

C1b is a page.  It is for H4 and C1a.  It flips to C3.
The cdesc is "[if the player is Horatio][i]{Switching to Constance}: [r][end if]Ask about his guess."
The description is "'So, what's your guess?' you ask.  'Is that your heresy?'"

A page-toggle rule for C1b:
	now the player is Constance;

C3 is a page.
The description is "In response, Horatio offers you the blue capsa he's holding.  It's [if the blue capsa is open]open[otherwise]closed[end if], and you cock your head questioningly at him.  'It is safe.  Nothing happens when you open it.'

Weird trap if it was a trap.  Fine.  You [if the blue capsa is open]close and [end if]open the blue capsa, bracing yourself... and nothing happens.  You look at the scroll, which seems to have no symbols on it at all apart from the title:  'BOSTRAT'."

A page-toggle rule for C3:
	move the blue capsa to the rucksack;

C3b is a page.  It is for C3.
The cdesc is "Is that real?"
The description is "Horatio shrugs.  'I cannot prove it is so.  Many have chosen not to believe.  But I can sense capsae, so I sought this one out, and found it in the ruins of Creshim.'";

C3a is a page.  It is for C3 and C3b.
The cdesc is "Wow."
The description is "'Wow,' you say, amazed by the implication.

'Indeed,' Horatio replies.  'At one time, if my research and the ancient tales I have collected are correct, this capsa, when activated, would bring rain to the land around it.'

'And now... any Bostrat anywhere in the world can bring rain,' you conclude.  'If they work together,' you amend.

Horatio nods, seriously.  'In the past, this scroll could alter its surroundings.  When it was finally read, it [i]changed the world[r].'

You gaze in wonder at the capsa.  Your heritage.  You can't say for sure it's genuine any more than Horatio can, but you feel the stirrings of some sort of pull towards it."

C4a is a page.  It is for C3a.
The cdesc is "Ask about the other abilities."
The description is "'And the Throckwrights?  The Ikniq?' you ask.

Horatio nods.  'From the stories I have collected, I believe 'throck' was the first of the scrolls to be read out and gifted to the people, and a renaissance of agriculture and architecture resulted.  When civilization pushed into the barren boundaries of the known world, bostrat was next, and spread our people across the desert.'

He stops.  There's an obvious Part Three, but you'll be damned if he makes you ask for it.  You wait.  You make another complete circuit together, and you realize there's a tear in his eye.  You're suddenly glad you gave him space to be emotionally ready to finish the story, though you're worried you already know where this is going.

Finally, with a deep breath, he speaks.  'Yes.  The first two gifts benefitted the herbivore clans more than the carnivore clans, or so they claimed.  Ikniq was next chosen, and hunting did indeed become easier.'  He pauses.

'But so did hunting each other,' you conclude, quietly.  Horatio nods.  The Great Wars.  Entire clans wiped out.  Whole swaths of countryside burned to the rock, where still nothing grows, a thousand years later."


C4b is a page.  It is for C3a and C4a.
The cdesc is "Pull everything together."
The description is "'So that's your heresy,' you conclude.  'You want to read a capsa's scroll.  And change the world again.'

'Not just any capsa.  The scroll of health.  Taclor.  Ten years ago, I would have been happy to read any.  Now, it must be that one.  But I will not make that choice on my own.  Every Reader like myself has the innate ability to Read a single scroll, and I will yield to the will of its holder, as my predecessors swore to do in the aftermath of the Great Wars.  But I will not waste my ability on anything else.'"

C5a is a page.  It is for C4b and C5b.
The cdesc is "But you need the scroll for your mother!"
The description is "'You can't read that scroll,' you say.  'I need it to save my mother.  To save the village.'

'The whole world,' Horatio turns his head to face to you, 'could say the same.'

'But [i]I'm here[r]!' you shout.  'I have [i]three capsae[r].  I didn't start any wars!  I didn't force people to live with their livestock and kickstart the Red Plague!  The queen's hoarding the capsa for gods-know-what reason, probably so the selfish bastard could ensure she doesn't come down with it herself...'

Horatio flinches.  That's right, he knew you when you and the now-queen were... closer.  Inseparable.

'I'll take it around the world!' you declare.  'I'll take it to every village in this kingdom; wherever the need is greatest.  I'll take it to other kingdoms!'

Horatio nods.  'When you are the holder, you may do as you wish,' he says, simply.  'But first, you must become the holder.  And for that, you will need igram.  [if the black capsa is enclosed by the player]Which you have.  So we'll need something from the Great Hall[otherwise]It's in the Librum[end if]."

C5b is a page.  It is for C4b.
The cdesc is "You need more details."
The description is "'So, what will happen?  What would it do if it was read?' you ask.

'I cannot say.  The gods created the scrolls with their local effects, I believe, to give people a taste of what was to come.  Throck, as a capsa, encouraged vegetation to grow.  Throckwrights push vegetation to grow in very specific ways.  Bostrat, as a capsa, caused rain by itself, but the bostrat must work together to do the same.  Ikniq... I can find no record of what it did as a capsa.  That information must have been purged.'  He pauses.  You let him collect his thoughts.

'My best guess is that it will give people the ability to heal themselves; perhaps even to regenerate.  Maybe it will make them immune to disease.  Maybe to death.  The gods only know.'"

C6 is an end-page.  It is for C5b and C5a.
The cdesc is "Figure out what's next."
The description is "'So, what do we do next?' you ask.

'I can sense the capsae.  Taclor, health, is in the Royal Quarters.  [if the black capsa is enclosed by Constance]And with Igram, which you got from the Librum, I can lead you to it,' Horatio tells you.  'We'll ned something from the Great Hall.  I'll meet you there.'

'What does it--you know, never mind, you obviously don't want to tell me,' you say.  'Fine.  Let's go.'  You turn [otherwise]Igram is in the Librum.'

'I ransacked the Librum last time; there was only these three,' you protest.

'It was considered worthless, and was discarded.  With it, I can lead you to taclor,' Horatio tells you.

'What does it--you know, never mind, you obviously don't want to tell me.  How do I get it?' you ask.

'It is in the Librum,' he says, simply.  'Therefore, either you must go into the Librum, or the capsa must come out.  I will talk to the guard to distract her, if that helps,' Horatio offers.

Gods, yes, you can inflict this man on someone you hate.  'Perfect,' you say, grimly. You shake yourself, and turn [end if]to your new task."

Horatio can be distracting.  Horatio is not distracting.

A page-toggle rule for C6:
	now the player is Constance; [Just in case]
	now Horatio is distracting;

Section fooling around - not for release

become_constance is an end-page.  It is for H1, H2, H2a, H2b, H3, H3a, H3b, H4, H4a, H4b, C1a, C1b, C2, C2a, C3, C3a, C3b, C4a, C4b, C5a, C5b.  
The cdesc is "OK, I'm a tester and I need to skip ahead and be Constance, fiddling with scrolls and stuff."
The description is "Done!  Thank you for testing!  If you want to come back to this conversation at the start, just >TOUCH HORATIO.";

A page-toggle rule for become_constance:
	now the player is Constance;
	now the blue capsa is in the rucksack;
	now Horatio is distracting;

start_over is a page.  It is for H1, H2, H2a, H2b, H3, H3a, H3b, H4, H4a, H4b, C1a, C1b, C2, C2a, C3, C3a, C3b, C4a, C4b, C5a, C5b.
The cdesc is "I'm also a tester, and I just want to go back to the beginning of this conversation."
The description is "Done!  Thank you for testing![bstars]".
start_over flips to H1.

A page-toggle rule for start_over:
	repeat with X running through every page:
		now X is not previously displayed;
	now the player is Horatio;

Instead of touching Horatio:
	switch to cyoa at H1.

Section Horatio in act 3

Horatio distracts the guard is a scene.  Horatio distracts the guard begins when Horatio is distracting and the black capsa is enclosed by the Librum Itself.  Horatio distracts the guard ends when the black capsa is not enclosed by the Librum Itself.

When Horatio distracts the guard begins:
	Move Horatio to the Librum Landing Cradle;
	say "With a solemn nod to you, Horatio explains where the black capsa of igram should be, then banks to the east, and descends to the Librum.";

Horatio tries to make zgi less ridiculous is a scene.  Horatio tries to make zgi less ridiculous begins when Horatio is distracting and the black capsa is not enclosed by the Librum Itself.  Horatio tries to make zgi less ridiculous ends when the player encloses the hunting cloak.

When Horatio tries to make zgi less ridiculous begins:
	if Horatio is in High Above and Constance is in High Above:
		say "With a solemn nod to you, Horatio tells you to meet him in the Great Hall with the black capsa, then turns and glides away.";
		move Horatio to Lower Great Hall;

Horatio can be stage one or stage two or stage three or stage four or stage five.  Horatio is stage one.

Every turn during Horatio tries to make zgi less ridiculous:
	If Horatio is stage one and the location is not Librum Landing Cradle and Horatio is not in the Lower Great Hall and the location is outdoors:
		if the location is Royal Gardens:
			if a random chance of one in three succeeds:
				say "Where is Horatio?  Didn't he say to get the capsa of igram, and then you'd both go in the Royal Quarters?";
		otherwise:
			say "Horatio glides out of the mist and circles near you.  He nods at the black capsa.  'Excellent work.  Now, we need something from the Great Hall.'[lb]";
			if the Great Hall doors are closed:
				Move Horatio to the Great Hall Landing Cradle;
				Now Horatio is stage two;
				if the location is not the Great Hall Landing Cradle:
					say "Horatio glides away, heading towards the Great Hall.";
				otherwise:
					say "Horatio looks at the double doors.  'After you get them open, of course,' he amends.";
			otherwise:
				Move Horatio to the Lower Great Hall;
				Now Horatio is stage three;
				if the location is the Great Hall Landing Cradle:
					say "Horatio glides through the open double doors of the Great Hall.";
				otherwise:
					say "Horatio glides away, heading towards the Great Hall.";
	Otherwise if Horatio is stage two and the Great Hall doors are open:
		Now Horatio is stage three;
		Move Horatio to the Lower Great Hall;
		If the location is the Great Hall Landing Cradle:
			say "With a nod to you, Horatio heads inside the Great Hall.";
	Otherwise if Horatio is stage three and the location is Lower Great Hall:
		now Horatio is stage four;
		say "You circle down and land near Horatio.  'So.  [i]Now[r] will you tell me what igram does and why it's so important?' you ask.
		
		'It is better to show you,' he replies.  'Try it.'
		
		You sigh.  Fine."

When Horatio tries to make zgi less ridiculous ends:
	move Horatio to the void;
	Now the black capsa is explained;
	say "You turn to Horatio, questions bubbling in your head.  'So, nothing else here turned invisible.  Does the scroll work on cloaks?  Things for hunting?  Ancient materials?  Hides?'
	
	Horatio looks a little uncomfortable.  'No.  It works on... purple.'
	
	'Purple?!?' you exclaim/ask.
	
	'Purple,' he confirms.
	
	'It [i]turns purple things invisible[r]?  Purple things!  The gift from the gods, on a scroll written in their secret language!  To turn [i]purple things invisible[r]!'  You cackle in glee.
	
	Horatio looks uncomfortably affronted.  'The hippotomai were common in those days.  It made sense...'
	
	You continue to laugh, cutting him off, but unable to contain your utter delight.  'Herds of invisible hippotomai!  Grass on the marshy banks disappearing into nowhere!  Weird divots in the lakes!  I bet--wait!  The trickster god!  Ape, the trickster!  Stohleblanc!'  You laughter gets more hysterical and you nearly can't breathe.
	
	With as much dignity as he can muster, Horatio waits solemnly for you to finish laughing.  You fail to do so.  Finally he gets impatient and turns to go.  'We can enter the Royal Quarters cloaked.  I will follow you.'
	
	'Wait,' you sputter, trying to push down the hysteria.  'How will you follow me?  I'll be invisible!'
	
	'I can sense the capsae.  I will know where you are,' he replies, and with a deep breath, he gathers himself and flies up and out of the Great Hall.";


answering the Horatio that something is Horatio_talk.
telling the Horatio about something is Horatio_talk.
asking the Horatio about something is Horatio_talk.
asking the Horatio for something is Horatio_talk.

Instead of Horatio_talk:
	if the player is Constance:
		if being chased is happening:
			say "While Horatio seems willing to distract a guard or two, you're not going to draw the guards[apostrophe] attention to him just to try to escape them.";
		otherwise if Horatio distracts the guard is happening:
			say "Horatio is chatting with the guard right now; it would be rude to interrupt.  And potentially lethal.";
		otherwise:
			say "You've already had an in-depth conversation with Horatio, but if you want to talk about your current situation, just >TALK TO HORATIO.";
	otherwise:
		say "'OK.  We have a chance, here,' you tell yourself.";

Carry out chatting Horatio:
	if the player is Constance:
		if being chased is happening:
			say "While Horatio seems willing to distract a guard or two, you're not going to draw the guards[apostrophe] attention to him just to try to escape them.";
		otherwise if Horatio distracts the guard is happening:
			say "Horatio is chatting with the guard right now; it would be rude to interrupt.  And potentially lethal.";
		otherwise if Horatio is stage one:
			say "Horatio is chatting with the guard right now; it would be rude to interrupt.  And potentially lethal.";
		otherwise if Horatio is stage two:
			say "Horatio says 'You'll need to get this door open.  I assume they've barred it shut from the inside, but fortunately, you have the capsae you need.'";
		otherwise if Horatio is stage three:
			if the cloak posts are in the Lower Great Hall:
				say "You ask Horatio, 'So what do I do now?'

				'Go ahead and take one,' he says.  If he thought this was obvious, it doesn't show on his face.";
			otherwise:
				say "Slightly exasperated, you ask Horatio, 'What do you want me to do now?'

				'You have igram.  Try it here, and see what happens,' he replies.";
		otherwise if Horatio is stage four:
			say "'We are ready,' says Horatio.  'Taclor awaits within the Royal Quarters.'";
		otherwise if Horatio is stage five:
			say "'Taclor is here.  It's time to make a decision,' says Horatio.";
	otherwise:
		say "'OK.  We have a chance, here,' you tell yourself.";
	stop the action;
	

Instead of giving something to Horatio:
	if being chased is happening:
		say "While Horatio seems willing to distract a guard or two, you're not going to draw the guards[apostrophe] attention to him just to try to escape them.";
	otherwise if Horatio distracts the guard is happening:
		say "Horatio is chatting with the guard right now.";
	otherwise:
		say "Horatio shakes his head.  'It is yours,' he says."

Section sensing capsae

Some distant_capsae are a backdrop. They are not scenery.  "Distant capsae pull at your senses."  The description is "[all the capsae locations]." Understand "distant/capsa/capsae/rezrov/rudenj/quiste/bostrat/igram/taclor/" as the distant_capsae.

To say all the capsae locations:
	if the gold capsa is in the Void:
		if the black capsa is enclosed by Constance:
			say "Rezrov, quiste, and igram circle high above you.  Rudenj and taclor are within the Royal Quarters to the north, though separate from each other.  And you carry bostrat";
		otherwise:
			say "Rezrov and quiste circle high above you.  Igram remains in the Librum.  Rudenj and taclor are within the Royal Quarters to the north, though separate from each other.  And you carry bostrat";
	otherwise:
		if the black capsa is enclosed by Constance:
			say "Rezrov, quiste, rudenj, and igram circle high above you.  Taclor remains within the Royal Quarters to the north.  And you carry bostrat";
		otherwise:
			say "Rezrov, quiste, and rudenj circle high above you.  Igram remains in the Librum, and taclor remains in the Royal Quarters.  And you carry bostrat";

Some capsae across the world are a backdrop.  They are undescribed.  The description is "Once a capsa is far enough away, it's usually dim enough that you have to focus to sense it.  But they're out there.  The spent scroll of ikniq, buried in the Sirroc Desert.  Xyzzy, continuing to travel from place to place.  Espnis, in the Catacombs of Miznia.  Cogthrix and Finna, in the port of Tirathmia.  Countless others.".  Understand "ikniq/xyzzy/espnis/cogthrix/finna/catacombs/miznia/tirathmia" as some capsae across the world.

Being Horatio is a recurring scene.  Being Horatio begins when the player is Horatio.  Being Horatio ends when the player is not Horatio.

When Being Horatio begins:
    now the distant_capsae are everywhere;
	now the capsae across the world are everywhere;

When Being Horatio ends:
	now the distant_capsae are nowhere;
	now the capsae across the world are nowhere;

Every turn during Being Horatio:
	If the time since Being Horatio began is 50 minutes:
		say "A twitch, in the distance.  Xyzzy on the move again.";

[Horatio ends here.]



Chapter Testing - not for release

[Intro:]
test unrandomize with "random/restart".
test summon with "d/n/summon mist/d/u/d/u".
test scenery with "x aerie/x royal quarters/x librum/x great hall".
test map with "d/u/n/u/e/u/d/e/nw/s/n/se/w/d/u/e/d/e/d/n/d/u/u".
test cant_go with "u/w/d/s/in/e/se/in/nw/nw/in/d/d/w/u/u".

[One chase to Horatio:]
test quick_chase with "take off rucksack/open haste/open purple/close purple/d".

[Get black capsa before Horatio]
test quick_black with "summon mist/open gold/e/w/e/u/".

[Horatio's journey:]
test quick_horatio with "x cell/x desk/x cell door/w/w/close grate/open grate/enter grate/u/u".

[Chase tests]
test chase_ustart with "open purple/close purple/e/nw/u".
test chase_dstart with "d/d/open purple/close purple/n/se/u".
test chase_mstart with "d/open purple/close purple/e/w/u".

[Escape tests]
test mist_escape with "summon mist/d/summon mist/e/summon mist/nw/summon mist/u".
test dive_escape with "d/d/u/u/".
test haste_escape with "open haste/d/u/close haste".
test fastmist_escape with "summon mist/summon mist/d/summon mist/u".

[Environmental tests]
test haste_dive with "open haste/d/d/close haste/u/u".
test lock_unlock with "e/lock librum/open librum/e/lock door/unlock door/unlock guard/nw/lock door/unlock door/s/lock door/unlock door/d/unlock net/u/u/".

[quickest way to get to Horatio]
test horatio_speedrun with "summon mist/d/u/open purple/d/d"

[Open the great hall doors]
test hall_open with "open gold/d/u/close gold/d/d/u/u"