"Willy's Manor" by "Josh Hetzel"

Book 0 - Declaring Variables and World Rules

Chapter 1 - Declaring Variables

WentSwimming is a truth state that varies. WentSwimming is initially false.

ToolCheck is a truth state that varies. ToolCheck is initially false.

PanInTree is a truth state that varies. PanInTree is initially true.

HasBookshelfMoved is a truth state that varies. HasBookshelfMoved is initially false.

HasEnteredWall is a truth state that varies. HasEnteredWall is initially false.

BeeSleep is a truth state that varies. BeeSleep is initially false.

GotHoneycomb is a truth state that varies. GotHoneycomb is initially false.

WorkBenchCheck is a truth state that varies. WorkBenchCheck is initially false.

LeavesTaken is a truth state that varies. LeavesTaken is initially false.

LighterLit is a truth state that varies. LighterLit is initially false.

LeavesLit is a truth state that varies. LeavesLit is initially false.

SouthPicEx is a truth state that varies. SouthPicEx is initially false.

NorthPicEx is a truth state that varies. NorthPicEx is initially false.

TableEx is a truth state that varies. TableEx is initially false.

DoorEaten is a truth state that varies. DoorEaten is initially false.

CabinetChewed is a truth state that varies. CabinetChewed is initially false.

CabinetBroken is a truth state that varies. CabinetBroken is initially false.

PlayerHasRoast is a truth state that varies. PlayerHasRoast is initially false.

Before taking roast:
	now PlayerHasRoast is true;
	continue the action;

Before dropping roast:
	now PlayerHasRoast is false;
	continue the action;

Chapter 2 - Four Seasons Room Steps

FourSeasonSteps is a number that varies. FourSeasonSteps is initially 2.

Instead of going to Four Seasons Northeast:
	increment FourSeasonSteps;
	continue the action;

Instead of going to Four Seasons Northwest:
	increment FourSeasonSteps;
	continue the action;

Instead of going to Four Seasons Southwest:
	increment FourSeasonSteps;
	continue the action;

Chapter 3 - Shooting Action

Shooting it with is an action applying to one carried thing and one thing.

Understand "shoot [something preferably held] at [something]" as shooting it with.

Understand "shoot [something] with [something preferably held]" as shooting it with (with nouns reversed).

Check shooting something with something:
	if player does not have the slingshot, say "You don't have a device to shoot things with." instead;
	if the noun is the slingshot, say "You have to specify what you want to use as ammo in the slingshot" instead;
	if the noun is the player, say "I don't believe you've thought that endeavor through." instead;
	if the second noun is the player, say "If you're that frustrated, you can always ask for a hint." instead;
	if the second noun is the slingshot, say "Okay Annie Oakley, this puzzle doesn't involve that level of marksmanship." instead;

Carry out shooting something with something:
	If the noun is termites:
		If the second noun is tree:
			If PanInTree is true:
				say "You fire the small insect to the base of the branch. It dutifully gnaws away until the pan is free!";
				now PanInTree is false;
			else:
				say "Destroying more of the tree will not benefit you.";
		If the second noun is the gold pan:
			if PanInTree is true:
				say "You fire the small insect to the base of the branch. It dutifully gnaws away until the pan is free!";
				now PanInTree is false;
			else:
				say "Denting the pan further wont help you.";
	If the second noun is gold pan:
		if PanInTree is true:
			say "The pan swings back and forth from your shot, but is not dislodged from the tree.";
	If the second noun is bee hive:
		if remainder after dividing FourSeasonSteps by 4 is 3:
			say "The [noun] clinks off the ice on the bee hive. It's not very effective.";
		else if BeeSleep is true:
			if GotHoneycomb is false:
				say "You knock a small part of the hive off. It appears to be a small honeycomb.";
				move honeycomb to Four Seasons Northwest;
				now GotHoneycomb is true;
			else if GotHoneycomb is true:
				say "There's no reason to further destroy the hive.";
		else if BeeSleep is false:
			say "Before you fire, all the times you've been stung by bees flash before your eyes. So much pain, so many tears. You should probably take care of the bees first to save you the anguish.";
	If noun is not termites:
		If second noun is not bee hive:
			say "The [noun] whizzes through the air and clinks off the [second noun] ineffectively.";
			now noun is in the location;

Chapter 4 - Puzzle Room Structure

PlayerLevel is a number that varies. PlayerLevel is initially 0.

LevelComplete is a truth state that varies. LevelComplete is initially true.

Instead of taking red button, say "I don't think it would be helpful to pry it off the wall."

Instead of taking lever, say "I don't think it would be helpful to pry it off the wall."

Instead of taking slot, say "I don't think it would be helpful to pry it off the wall."

Instead of pushing red button:
	if LevelComplete is true:
		increment PlayerLevel;
		now LevelComplete is false;
		say "A clue slides out of the slit in the wall.[line break] ";
		if PlayerLevel is 1:
			move Clue One to Puzzle Room;
		else if PlayerLevel is 2:
			move Clue Two to Puzzle Room;
		else if PlayerLevel is 3:
			move Clue Three to Puzzle Room;
		else if PlayerLevel is 4:
			move Clue Four to Puzzle Room;
		else if PlayerLevel is 5:
			move Clue Five to Puzzle Room;
		else if PlayerLevel is 6:
			move Clue Six to Puzzle Room;
		else if PlayerLevel is 7:
			move Clue Seven to Puzzle Room;
		else if PlayerLevel is 8:
			move Clue Eight to Puzzle Room;
		else if PlayerLevel is 9:
			move Clue Nine to Puzzle Room;
			say "You hear an electonic buzzing as a panel on the north side of the room lifts to reveal an entry to a large pool.";
			change the north exit of Puzzle Room to Infinity Pool;
			change the south exit of Infinity Pool to Puzzle Room;
	else if LevelComplete is false:
		say "Complete current clue first";

Instead of pulling lever:
	if PlayerLevel is 0:
		say "You can't use this until you start the game by getting a clue.";
	if PlayerLevel is 1:
		if kitchen towel is in large box:
			say "You hear a small fanfare and the towel is swallowed by the box. An iron key appears in the box.";
			now kitchen towel is nowhere;
			now LevelComplete is true;
			move iron key to large box;
		else:
			say "You hear a buzzer. By the sound of it, your solution to the clue was incorrect.";
	else if PlayerLevel is 2:
		if ants is in large box:
			say "You hear a small fanfare and the ants are swallowed by the box. A strange shaped key appears in the box";
			now ants is nowhere;
			now LevelComplete is true;
			move Peter key to large box;
		else:
			say "You hear a buzzer. By the sound of it, your solution to the clue was incorrect.";	
	else if PlayerLevel is 3:
		if gold pan is in large box:
			say "You hear a small fanfare and the pan is swallowed by the box. A leaf shaped key appears in the box";
			now gold pan is nowhere;
			now LevelComplete is true;
			move leaf key to large box;
		else:
			say "You hear a buzzer. By the sound of it, your solution to the clue was incorrect.";
	else if PlayerLevel is 4:
		if trunk is in the large box:
			say "You hear a small fanfare and the trunk is swallowed by the box. A lighter appears in the box";
			now the trunk is nowhere;
			now LevelComplete is true;
			move lighter to large box;
		else:
			say "You hear a buzzer. By the sound of it, your solution to the clue was incorrect.";
	else if PlayerLevel is 5:
		if honeycomb is in large box:
			say "You hear a small fanfare and the honeycomb is swallowed by the box.";
			now honeycomb is nowhere;
			now LevelComplete is true;
		else:
			say "You hear a buzzer. By the sound of it, your solution to the clue was incorrect.";
	else if PlayerLevel is 6:
		if nothing is in large box:
			say "You hear a small fanfare. The box continues to be empty.";
			now LevelComplete is true;
		else:
			say "You hear a buzzer. By the sound of it, your solution to the clue was incorrect.";
	else if PlayerLevel is 7:
		if walking photo is in large box:
			say "You hear a small fanfare and the photo is swallowed by the box.";
			now walking photo is nowhere;
			now LevelComplete is true;
		else:
			say "You hear a buzzer. By the sound of it, your solution to the clue was incorrect.";
	else if PlayerLevel is 8:
		if red book is in large box:
			say "You hear a small fanfare and the book is swallowed by the box.";
			now the red book is nowhere;
			now LevelComplete is true;
		else:
			say "You hear a buzzer. By the sound of it, your solution to the clue was incorrect.";

Chapter 5 - Clues

Clue One is an object. It has the description "A small card that reads 'Get me something that gets wet as it dries'". Understand "clue 1" as Clue One.

Clue Two is an object. It has the description "A small card that reads 'Get me workers. They may be found in a farm.'". Understand "clue 2" as Clue Two.

Clue Three is an object. It has the description "A small card that reads 'Get me a famous Peter; something you cook with.'". Understand "clue 3" as Clue Three.

Clue Four is an object. It has the description "A small card that reads 'Get me the base of a tree or the back of a car. If you were in it, you wouldn't know where you are.'". Understand "clue 4" as Clue Four.

Clue Five is an object. It has the description "A small card that reads 'Get me a sticky treat that bears enjoy.'". Understand "clue 5" as Clue Five.

Clue Six is an object. It has the description "A small card that reads 'Get me something that is greater than God, more evil than the devil, the poor have it, the rich need it, and if you eat it you will die.'". Understand "clue 6" as Clue Six.

Clue Seven is an object. It has the description "A small card that reads 'Get me something that reminds me of my favorite memory.'". Understand "clue 7" as Clue Seven.

Clue Eight is an object. It has the description "A small card that reads 'Get me something that is my favorite color. You may have to move the bookshelf.'". Understand "clue 8" as Clue Eight.

Clue Nine is an object. It has the description "A small card that reads 'Try something [fixed letter spacing] new [variable letter spacing] in the infinity pool. Bring the roast'". Understand "clue 9" as Clue Nine.

Chapter 6 - Four Seasons Room Fire Puzzle Code

a lighter is a object. It has the description "A small lighter with plenty of fluid. To use it, say 'burn <object>'."

Understand the commands "burn" and "light" as something new.

Setting A Flame is an action applying to one thing.

Understand "burn [something]" as Setting A Flame.

Understand "light [something]" as Setting A Flame.

Understand "Set [something] on fire" as Setting A Flame.

Understand "Burn down [something]" as Setting A Flame.

Check Setting A Flame something:
	if player does not have the lighter, say "You have nothing to light it with[line break]" instead;

Carry out Setting A Flame something:
	if noun is the lighter:
		say "The lighter is now lit";
		now LighterLit is true;
		douse lighter in three turns from now;
	else if noun is leaf pile:
		if remainder after dividing FourSeasonSteps by 4 is 3:
			say "The leaves are covered in too much snow to burn";
		else:
			now LeavesLit is true;
			if player is in Four Seasons Northwest:
				say "The leaf pile burns slowly, then coughs up a large cloud of smoke. The smoke reaches the hive and puts the bees to sleep";
				now BeeSleep is true;
				remove leaf pile from play;
			else:
				say "The leaves are now burning.";
				douse leaves in four turns from now;			
	else if noun is large tree southeast:
		say "The lighter is too small to burn down the tree, and your brain is too small to realize that a large tree engulfed in flames would be very dangerous to you.";
	else if noun is large tree northwest:
		say "The lighter is too small to burn down the tree, and your brain is too small to realize that a large tree engulfed in flames would be very dangerous to you.";
	else if noun is lamp:
		say "The broken lamp takes well to your lighter. A little too well. You throw it away just in time to have it not blow up in your hand";
		now the lamp is nowhere;
	else:
		say "Your attempt to burn the [noun] doesn't work and concerns your friends and family.";

At the time when douse lighter:
	say "The lighter flame has gone out. You'll have to relight it to use it again.";
	now LighterLit is false;

At the time when douse leaves:
	say "The leaf fire has gone out. It appears you can light them again if needed.";
	now LeavesLit is false;

Instead of dropping leaf pile:
	if player is in Four Seasons Northwest:
		if LeavesLit is true:
			say "The leaf pile burns slowly, then coughs up a large cloud of smoke. The smoke reaches the hive and puts the bees to sleep";
			now BeeSleep is true;
			remove leaf pile from play;
		else:
			continue the action;
	else:
		continue the action;

Instead of dropping lighter:
	if LighterLit is true:
		if player is in Four Seasons Northwest:
			if leaf pile is in Four Seasons Northwest:
				if remainder after dividing FourSeasonSteps by 4 is not 3:
					say "The leaves burn and the smoke from them carries up to the bee hive. The smoke should put them to sleep.";
					now BeeSleep is true;
					remove leaf pile from play;
				else:
					say "The leaves are covered in too much snow to burn.";
		else:
			say "You probably should drop a lit lighter unless you have a reason to burn something";
		if LighterLit is false:
			continue the action;

a leaf pile is an object. It has the description "[if remainder after dividing FourSeasonSteps by 4 is 1]a pile of green leaves[end if][if remainder after dividing FourSeasonSteps by 4 is 2]a pile of green leaves[end if][if remainder after dividing FourSeasonSteps by 4 is 0]a pile of green leaves[end if][if remainder after dividing FourSeasonSteps by 4 is 3]a pile of leaves covered in snow and ice[end if]". Understand "leaves" as leaf pile.

Instead of hinting about leaf pile, say "The leaves seem dry, but their green hue makes it seem like they'd give off a lot of smoke."

Before taking leaf pile:
	now LeavesTaken is true;
	continue the action;

Instead of going to Four Seasons Southeast:
	increment FourSeasonSteps;
	if remainder after dividing FourSeasonSteps by 4 is 2:
		if LeavesTaken is false:
			now leaf pile is in Four Seasons Southeast;
	continue the action;

Before going from Four Seasons Southeast:
	if LeavesTaken is false:
		now leaf pile is nowhere;
		continue the action;
	continue the action;


Chapter 7 - Generic Hint System

Hinting about is an action applying to one visible thing. Understand "hint about [visible thing]" as hinting about.

Carry out hinting about something:
	say "There is nothing interesting about the [noun]"

Understand "hint" as asking for a hint. Asking for a hint is an action out of world.

Carry out asking for a hint:
	if PlayerLevel is 0:	
		say "The puzzle and clues are in the Puzzle Room, at the northern most room of the manor.[line break]Would you like more clarification?";
		if player consents,
			say "When in the puzzle room, pressing the button dispenses a clue. After you have a clue, put the answer in the box and pull the lever";
		otherwise stop the action;
		stop the action;
	else if LevelComplete is true:
		say "Press the button in the Puzzle Room for another clue";
		stop the action;
	else if PlayerLevel is 1:
		say "Be sure to look inside of things like cabinets and drawers.[line break]Would you like another hint?";
		if player consents,
			say "Don't look for any keys just yet, the answer to the riddle isn't in a locked room.[line break]Would you like the solution?";
		otherwise stop the action;
		if player consents,
			say "The answer to the riddle is a towel. There should be one in the kitchen drawer.";
	else if PlayerLevel is 2:
		say "The answer to the riddle is not in the room you just got the key to.[line break]Would you like another hint?";
		if player consents,
			say "Continue to look inside drawers and objects.[line break]Would you like the solution?";
		otherwise stop the action;
		if player consents,
			say "The answer to the riddle is ants. There is a jar of ants under the lizard tank in the North. You need to take the jar, open it, and put the ants into the box.";
		otherwise stop the action;
	else if PlayerLevel is 3:
		say "You'll need items from both rooms you can unlock now. Be sure you find the door that corresponds with each key.[line break]Would you like another hint?";
		if player consents,
			say "The iron key is for the workshop and the Peter key is for the Pantree (the solution to the riddle was Pan)[line break]Would you like another hint?";
		otherwise stop the action;
		if player consents,
			say "You cannot go up the tree to the pan, you have to bring the pan down to you.[line break]Would you like another hint?";
		otherwise stop the action;
		if player consents,
			say "You need to shoot something specific at the pan to free it.[line break]Would you like the solution?";
		otherwise stop the action;
		if player consents,
			say "Get the termites from under the lizard tank and shoot them at the tree in the Pantree";
		otherwise stop the action;
	else if PlayerLevel is 4:
		say "Be sure to find the room that the leaf key opens.[line break]Would you like another hint?";
		if player consents,
			say "Be sure to figure out the mystery of the seasons in the Four Seasons Room. Knowing how to manipulate them will help you.[line break]Would you like another hint?";
		otherwise stop the action;
		if player consents,
			say "The seasons in the Four Seasons Room increment each time you move from one corner to another. Use this to your advantage, as some puzzles can only be solved when certian parts are in a certain season.[line break]Would you like the solution?";
		otherwise stop the action;
		if player consents,
			say "The answer to the riddle is trunk, and there is one at the bottom of the pond in the Four Seasons Room Northeast. Be mindful of what season it is, as the pond is frozen in winter and the chill will make you drop it if you try to enter during fall.";
		otherwise stop the action;
	else if PlayerLevel is 5:
		say "This puzzle takes a few steps, so the following hints are more spoiler heavy than previous ones.[line break]Would you like another hint?";
		if player consents,
			say "The answer to the riddle is 'honey.' There should be some in the bee hive in the Four Seasons Room Northwest.[line break]Would you like another hint?";
		otherwise stop the action;
		if player consents,
			say "You need to find some way to calm the bees down.[line break]Would you like another hint?";
		otherwise stop the action;
		if player consents,
			say "Smoke would calm down a hive of bees.[line break]Would you like another hint?";
		otherwise stop the action;
		if player consents,
			say "Once the bees are calm, you can knock off some of the hive with your slingshot.[line break]Would you like the solution?";
		if player consents,
			say "You need the leaves from the tree in Four Seasons Southeast. Bring them to Four Seasons Northwest and burn them with the lighter. Then shoot the hive with whatever you have on hand and get the honey.";
		otherwise stop the action;
	else if PlayerLevel is 6:
		say "This riddle has an abstract solution, think beyond the material world.[line break]Would you like another hint?";
		if player consents,
			say "You also can't feel or touch this object, if that helps at all.[line break]Would you like the solution?";
		otherwise stop the action;
		if player consents,
			say "The answer is nothing. Pull the lever while the box is empty.";
	else if PlayerLevel is 7:
		say "You were surrounded by memories when you first arrived.[line break]Would you like another hint?";
		if player consents,
			say "The solution is one of the photos from when you arrived. Take a guess as to which was the happiest for him.[line break]Would you like the solution?";
		otherwise stop the action;
		if player consents,
			say "His happiest memory is walking with his wife eating ice cream in the city. You should be able to find it in the Main Hallway North.";
		otherwise stop the action;
	else if PlayerLevel is 8:
		say "You first need to find the bookshelf. Moving it will help you.[line break]Would you like another hint?";
		if player consents,
			say "After pushing the bookshelf, enter the wall behind it to reach the Liebrary.[line break]Would you like another hint?";
		otherwise stop the action;
		if player consents,
			say "It  is called the 'Liebrary' because everything written in the books is a lie. Reading the books will help you.[line break]Would you like the solution?";
		otherwise stop the action;
		if player consents,
			say "Each book says a different color is Willy's favorite. Since it is the Liebrary, all the colors they give are incorrect. The only color they don't say is red, so the correct solution to the puzzle is the red book.";
		otherwise stop the action;
	else if PlayerLevel is 9:
		say "The roast was originally in the dining room.[line break]Would you like another hint?";
		if player consents,
			say "Carefully read the clue. There's a hint in the wording.[line break]Would you like another hint?";
		otherwise stop the action;
		if player consents,
			say "Pay careful attention to the word [fixed letter spacing] new [variable letter spacing][line break]Would you like the solution?";
		otherwise stop the action;
		if player consents,
			say "You need to enter the infinity pool and go north, east, and west. Move quickly, this section is timed.";
		otherwise stop the action;
	else if PlayerLevel is 10:
		say "Greet Willy using 'greet Willy' and then ask about any of the items you collected.[line break]Would you like another hint?";
		if player consents,
			say "Try to remember all the items you collected, one of them is not here.[line break]Would you like the solution?";
		otherwise stop the action;
		if player consents,
			say "The ants aren't there. Ask Willy about the ants!";
		otherwise stop the action;


Chapter 8 - Termite Situations

Instead of putting termites on [something], try dropping termites.

After dropping termites:
	if player is in Pantree:
		say "The termites start biting at the base of the tree, but their hunger is not infinite, and they get full quickly. They may be able to handle a thinner part of the tree.";
	if player is in Four Seasons Northwest:
		say "The termites start biting at the base of the tree, but their hunger is not infinite, and they get full quickly.";
	if player is in Four Seasons Southeast:
		say "The termites start biting at the base of the tree, but their hunger is not infinite, and they get full quickly.";
	if player is in Main Hallway North:
		if CabinetChewed is false:
			say "The termites chew at the base of the cabinet. Little do they know, there's a whole tank above them. You don't have much time to get whatever you want out of the cabinet before it breaks.";
			breaking cabinet in four turns from now;
			now CabinetChewed is true;
		else:
			say "The termites have already had their way with the cabinet.";
	if player is in Dining Hall:
		say "The termites look at the magnificent table and begin to chew on one of the legs. Before they even make a dent in their feast, they get full and stop eating.";
	if player is in Main Hallway Fork:
		if DoorEaten is false:
			say "The termites chew through the base of the wooden door, and then up the side. So much of the door is missing, the lock doesn't seem to work anymore.";
			now the Wooden Door is unlocked;
			now DoorEaten is true;
		else:
			say "You already destroyed the lock to the wooden door.";

At the time when breaking cabinet:
	say "You hear a crash and the cabinet in the hallway shatters, dropping the tank to the floor. Hopefully you didn't need anything in the cabinet.";
	now the cabinet is nowhere;
	if the square jar is in the cabinet:
		now the square jar is in the Main Hallway North;

Instead of locking the wooden door with [something]:
	if DoorEaten is false:
		continue the action;
	else:
		say "The termites have already destroyed the door lock.[line break]";

Instead of unlocking the wooden door with termites:
	if DoorEaten is false:
		say "The termites chew through the base of the wooden door, and then up the side. So much of the door is missing, the lock doesn't seem to work anymore.";
		now the Wooden Door is unlocked;
		now DoorEaten is true;
	else:
		say "The termites have already destroyed the door lock.[line break]";

Instead of unlocking the wooden door with [something]:
	if DoorEaten is false:
		continue the action;
	else:
		say "The termites have already destroyed the door lock.[line break]";

Chapter 9 - Misc

beth is an action applying to nothing.

Understand "beth" as beth.

Carry out beth:
	now player is in Lounge;
	now PlayerLevel is 10;
	
Greeting is an action applying to one visible thing. Understand "talk to [someone]" or "converse with [someone]" or "greet [someone]" as greeting.

Check greeting:
	say "[the noun] doesn't reply"

Understand "use [something preferably held] on [a locked lockable thing]" as unlocking it with (with nouns reversed).

Understand "use [something preferably held] on [an unlocked lockable thing]" as locking it with (with nouns reversed).

Instead of using button, try pushing button.

Instead of using lever, try pulling lever.

Understand "use [something]" as using. Using is an action applying to one thing. Carry out using: say "You will have to be more specific about your intentions."

Understand "about" as a mistake ("Written by Joshua Hetzel. Tested by Catherine Hetzel and Michael Chay. Cover art made using assets created by Lorc and Delapouite, used under CC By 3.0 license (https://creativecommons.org/licenses/by/3.0/)")

Understand "credits" as a mistake ("Written by Joshua Hetzel. Tested by Catherine Hetzel and Michael Chay. Cover art made using assets created by Lorc and Delapouite, used under CC By 3.0 license (https://creativecommons.org/licenses/by/3.0/)")

Understand "xyzzy" as a mistake ("You are now in the debris room...[line break]Sorry, wrong game. There is no cave here.")

zork is an action applying to nothing.

Understand "zork" or "zork i" or "zork 1" as zork.

Carry out zork:
	say "'Zork on a brick would sell 100,000 copies.' Bobby Kotick.[line break]You see a brick appear.";
	move brick to location of player;

a brick is an object. It has the description "A brick with 'Zork' on it. It is believed to have sold quite well."

Understand "help" as a mistake ("The possible commands in this game are:[line break][bold type]north, south, east, west, northeast, southeast, northwest, southwest, enter[roman type] and [bold type]exit[roman type] for movement[line break][bold type]look[roman type] to see the description of the room you're in[line break][bold type]inventory[roman type] to see what you are carrying[line break][bold type]examine, take, drop, open, close, push, pull, move[roman type] objects[line break][bold type]unlock 'object' with 'object'[roman type] to unlock things[line break][bold type]shoot 'object' at 'object'[roman type] once you have something to shoot with[line break][bold type]burn 'object'[roman type] once you have the correct tool[line break][bold type]credits, hint, hint about 'object,' undo, save, restore, restart,[roman type] and [bold type]quit[roman type] are also acceptable, and work as expected.")

Book 1 - First area

Chapter 1 - Start and Foyer

When play begins:
	say "You are a producer for the reality show Celebrity Houses. You were tasked to visit Willy's Manor, the abode of an eccentric billionare who became rich by founding an internationally beloved novelty company. He agreed to be on the show as long as a single person comes to his house and passes his 'test.' You drew the short straw and are now outside. You were given a lamp and a map to assist you.[line break]Would you like instructions?";
	if player consents,
		say "The possible commands in this game are:[line break][bold type]north, south, east, west, northeast, southeast, northwest, southwest, enter, exit[roman type] for movement[line break][bold type]look[roman type] to see the description of the room you're in[line break][bold type]inventory[roman type] to see what you are carrying[line break][bold type]examine, take, drop, open, close, push, pull[roman type] objects[line break][bold type]unlock 'object' with 'object'[roman type] to unlock things[line break][bold type]shoot 'object' at 'object'[roman type] once you have a tool to shoot things with[line break][bold type]burn 'object'[roman type] once you have the correct tool[line break][bold type]credits, hint, hint about 'object,' undo, save, restore, restart, quit[roman type] are also acceptable, and work as expected.";
	now the player has the broken lamp;
	now the player has the map;

help booklet is an object. It has the description "The booklet says:[line break]
'In this game, there are some commands you may be less used to. At any time, you can type [bold type]hint[roman type] to recieve a general hint about how to progress, or [bold type]hint about [roman type]'object' to get a hint about a specific item in the game (although not all objects are that interesting). Before asking for a hint about an object, be sure you [bold type]examine[roman type] it first.[line break]You can type [bold type]help[roman type] at any time to get a full list of commands needed to complete the game. Additional commands may lead ot fun extras, but nothing necessary to complete the game[line break]There is no turn limit, inventory limit, or way to make the game unwinnable, so have fun!'". help booklet is in Outside Manor.

a broken lamp is an object. It has the description "A broken oil lamp. It still has some oil in it, but doesn't look like you can turn it on"

a map is an object. It has the description "A map of all known locations in the manor. It can be read in the games files"

Outside Manor is a room. It has the description "You're standing to the south of a monsterously large house. Various whimsical decorations litter the lawn, but you have no time for them. Your job depends on you going inside and passing some test by the owner."

house is an object. it is scenery. house is in Outside Manor. house has the description "You're standing to the south of a monsterously large house. Various whimsical decorations litter the lawn, but you have no time for them." Understand "manor" as house.

decorations is an object. It is in Outside Manor. decorations are scenery. decorations have the description "You see a sign saying 'pull my finger' and a statue with a joy buzzer in its hand, but they are distracting you from the task at hand." Understand "whimsical decorations", "decoration", "lawn" as decorations.

finger is an object. It is in Outside Manor. finger is scenery. finger has the description "The finger of the statue appears to have extra parts in it, making it mobile."

Instead of pulling finger, say "pfft"

signs is an object. It is in Outside Manor. signs is scenery. Understand "sign" as signs. signs has the description "It is a breathtaking sign. It almost makes you forget that the point of the game is to enter the manor. Almost."

statue is an object. It is in Outside Manor. statue is scenery. Understand "joy buzzer" as statue. statue has the description "It is a large bronze statue that doesn't absolve you of your responsibilities inside the manor."

the front door is north of Outside Manor and south of Main Hallway South. front door is a door. It has the description "A door with [fixed letter spacing] Willy [variable letter spacing] carved in comic sans font."

Chapter 2 - Kitchen

Kitchen is a room. It is north of the Dining Hall and east of the Main Hallway North. Kitchen has the description "A large and spacious kitchen. It has two full ovens with gas stoves on one wall, while several drawers line the other wall. You see a metal door to the east, the dining room to the south, and the hallway to the west."

ovens is an object. It is scenery. It is in the Kitchen. ovens has the description "Beautiful chrome ovens that are spotlessly clean. The panel on them has so many switches and buttons that you don't think you could ever figure out how to work it.". Understand "oven", "stove", "stoves", "gas stove" and "gas stoves" as ovens.

Instead of opening ovens, say "The oven door appears to be locked. This place really is fancy!"

panel is an object. It is scenery. It is in the Kitchen. It has the description "The panel on the oven is too complicated, best not mess with it.". Understand "panels", "buttons" and "switches" as panel.

kitchen drawer is an object. It is scenery. It is a container and openable and closed. It has the description "A kitchen drawer with a simple handle.". Understand "kitchen drawers" and "drawers" as kitchen drawer. It is in the Kitchen.

handle is an object. It is scenery. It has the description "The handle makes it easy to open and close the drawer." It is in the Kitchen.

Instead of hinting about kitchen drawer, say "It is a drawer that you can open and close."

a spatula is an object. It is in the kitchen drawer. spatula has the description "It is a metal spatula with a head that spins freely. Looks fun, but pointless."

a mixing spoon is an object. It is in the kitchen drawer. mixing spoon has the description "It is a  wooden mixing spoon with Willy's company logo on it. Probably given away at some party."

a kitchen towel is an object. it is in the kitchen drawer. kitchen towel has the description "It is a cloth kitchen towel embroidered with Willy and Beth's wedding anniversary."

metal door is a door and scenery. metal door is east of the Kitchen and west of the Pantree. metal door is lockable and locked. The matching key of the metal door is the Peter key. metal door has the description "It is a door that says 'Pantree.' You would think with all this money he would have it spelled right."

Instead of hinting about metal door, say "The metal door has a picture of Peter Pan on it."

the Peter key is an object. It has the description "The key is in the shape of a very famous Peter."

Chapter 3 - Main Hallway South and Dining Hall

Main Hallway South is a room. Main Hallway South has the description "The walls are lined with photos of Willy's accomplishments and memories. The hallway continues north, there is a small reading area to the west, a dining hall to the east, and the front door is to the south."

photos are an object. They are scenery. They have the description "There are many photos on the wall. One is of Willy's patent for a pen that forces people to misspell words, as well as his trademark for his novelty company [fixed letter spacing] Willy's Wild World [variable letter spacing]. Another is him at a black tie event, sneaking Whoopee cushions onto the chairs. A third photo is of him meeting the US President, shaking his hand with a joy buzzer.". They are in Main Hallway South.

Instead of hinting about photos, say "Photos can represent human memories"

Before examining photos:
	if SouthPicEx is false:
		move trademark photo to Main Hallway South;
		move party photo to Main Hallway South;
		move president photo to Main Hallway South;
		now SouthPicEx is true;

trademark photo is an object. It has the description "It is a photo of Willy's patent for a pen that forces people to misspell words, as well as his trademark for his novelty company [fixed letter spacing] Willy's Wild World [variable letter spacing]"

Instead of hinting about trademark photo, say "Photos can represent memories"

party photo is an object. It has the description "It is a photo of Willy at a black tie event, sneaking Whoopee cushions onto the chairs."

Instead of hinting about party photo, say "Photos can represent memories"
	
president photo is an object. It has the description "It is a photo of Willy meeting the US President, shaking his hand with a joy buzzer."

Instead of hinting about president photo, say "Photos can represent memories"

Dining Hall is east of Main Hallway South and south of the Kitchen. Dining Hall has the description "A large dining hall with a long table able to seat more than a dozen people. To the north is a door to the kitchen, and to your west is the hallway."

the dining table is an object in the Dining Hall. dining table is scenery. It has the description "A long mahogany table. It is completely bare except for a roast at the center."

roast is an object. It is edible. It has the description "[if PlayerLevel is 10]The roast has been covered in a honey glaze and is being warmed on a slightly dented pan.[else]A succulent roast on a sliver platter. The platter has a simple flower pattern around the rim.". roast is in the dining hall. Understand "platter" as roast.

Instead of eating the roast, say "You're not very hungry, and you don't want to waste time when you should be solving puzzles."

Chapter 4 - Reading Area

Reading Area is west of Main Hallway South. Reading Area has the description "[if player is in wall]You are in an abyss, with overwhelming darkness surrounding you in all directions.[otherwise]A small room with comfortable chairs and soft, warm lighting. Perfect for settling down with a good book.[end if][if HasEnteredWall is true] There is a barren wall behind the bookshelf you pushed is to your west.[end if] The hallway is to your east."

chairs are an object. They are scenery in the Reading Area. chairs have the description "Plush, luxurious chairs are strewn about the room." Understand "chair" as chairs.

Instead of entering chairs, say "You'd love to dose off, but you have a job at hand."

large bookshelf is an object. It is in the Reading Area. It is pushable between rooms. large bookshelf has the description "There is an assortment of joke books and riddle collections. Nothing catches your eye.". Understand "books" and "book" and "joke book" and "joke books" and "riddle collections" and "riddle collection" and "collections" as large bookshelf.

Instead of hinting about large bookshelf:
	if HasBookshelfMoved is false:
		say "It is large, but not bolted down. You might be able to push it if you wanted to.";
	if HasBookshelfMoved is true:
		say "You've pushed it as far to the side as you can.";

Instead of taking bookshelf, say "It is far too big to take."

Instead of pushing bookshelf:
	if HasBookshelfMoved is false:
		continue the action;
	if HasBookshelfMoved is true:
		say "There's no reason to move the bookshelf further.";

After pushing bookshelf:
	say "moving the bookshelf revealed a suspiciously bare wall behind it[line break] ";
	move wall to Reading Area;
	now HasBookshelfMoved is true;

wall is a container. It is enterable. It has the description "A completely bare wall with no wallpaper or paint. It looks as though you could walk right into it"

Instead of touching wall, say "Your finger creates circular waves in the wall, like dropping a pebble into a lake."

Instead of hinting about wall:
	say "You touch the wall and it bends and warps like it is made of a thin cloth.[line break]Would you like more clarification?";
	if player consents,
		say "You can enter the wall with the command 'enter wall'";
	otherwise stop the action;

Understand "exit wall" as exiting.

Instead of entering wall:
	say "You phase through the wall like it was a fine mist.";
	if HasEnteredWall is false:
		now HasEnteredWall is true;
		change the west exit of Reading Area to Liebrary;
		change the east exit of Liebrary to Reading Area;
	continue the action;

After entering wall:
	now player is in Liebrary;

Chapter 5 - Main Hallway North and Fork

Main Hallway North is north of Main Hallway South. Main Hallway North has the description "There are photos of Willy lining the walls of the hallway, as well as a tank of lizards[if CabinetBroken is false] on top of a cabinet[end if]. The hallway continues south, there is a fork to the north, and the kitchen is to the east."

more photos is an object. It is scenery. It has the description "One of the photos if of him and his wife Beth walking on the city streets eating ice cream. Another photo is of his large tank of Sea Monkeys labeled [fixed letter spacing] Darryl [variable letter spacing]. A final photo is of him at his novely company's initial public offereing. In a bustling room of excitement, he wears a content smile. ". It is in Main Hallway North.

Before examining more photos:
	if NorthPicEx is false:
		move walking photo to Main Hallway North;
		move Darryl photo to Main Hallway North;
		move IPO photo to Main Hallway North;
		now NorthPicEx is true;

walking photo is an object. It has the description "It is a photo of Willy and his wife Beth walking on the city streets eating ice cream."

Darryl photo is an object. It has the description "It is a photo of a large tank of Sea Monkeys labeled [fixed letter spacing] Darryl [variable letter spacing]"

IPO photo is an object. It has the description "It is a photo of Willy at his novelty company's initial public offering. In a room of excitement, he wears a content smile."

a tank of lizards is an object. It is scenery. It has the description "A tank full of lizards [if CabinetBroken is false]sitting on top of a cabinet[end if]. You're not great with animals, so best to leave them alone". It is in the Main Hallway North. Understand "lizard" as tank of lizards.

Instead of hinting about tank of lizards, say "There's nothing interesting about the tank of lizards.[if CabinetBroken is false] It might be fruitful to explore the cabin beneath it.[end if]"

cabinet is an object. It is scenery and a container and openable and closed. It has the description "You see a wooden cabinet directly beneath the tank of lizards." It is in the Main Hallway North.

Instead of hinting about cabinet, say "You can open and close the cabinet."

a round jar is a container that is openable and transparent and closed. It has the description "It is a round glass jar labeled termites.". It is in the cabinet. The carrying capacity of a round jar is 1.

Instead of hinting about round jar, say "You can open and close the jar"

a square jar is a container that is openable and transparent and closed. It has the description "It is a square glass jar labeled ants.". It is inside the cabinet. The carrying capacity of a square jar is 1.

Instead of hinting about round jar, say "You can open and close the jar"

After opening round jar:
	if round jar contains termites:
		try silently taking termites;
		continue the action;
	else:
		continue the action;

termites is an object. It has the description "There are dozens of small, live termites". It is in the round jar. Understand "termite" as termites.

Instead of hinting about termites, say "Termites are known to eat through wood."

After opening square jar:
	if square jar contains ants:
		try silently taking ants;
		continue the action;
	else:
		continue the action;

ants is an object. It has the description "There are dozens of small, hard working ants". It is in the square jar. Understand "ant" as ants.

Instead of hinting about ants, say "They are known as worker ants."

Main Hallway Fork is north of Main Hallway North. Main Hallway Fork has the description "The hallway ends with many openings. To the west is a glass door, to the east is a wooden door, and there's also an opening to the north with a sign saying 'Puzzle Room' above it. The hallway continues to the south."

wooden door is east of Main Hallway Fork. wooden door is scenery and a door and lockable and locked. wooden door has the description "It is a sturdy wooden door labeled 'Workshop.'". The matching key of wooden door is the iron key.

the iron key is an object. It has the description "An antique looking iron key. There's a tag on it that says 'Workshop.'".

Instead of hinting about iron key, say "The iron key says workshop. It probably opens the workshop."

the glass door is west of Main Hallway Fork and east of Four Seasons Northeast. Glass Door is scenery and a door and lockable and locked. The matching key of the glass door is the leaf key. glass door has the description "A frosted glass door embellished with a leaf."

Instead of hinting about glass door, say "The leaf on the glass door is right above the lock. The key probably has something similar on it."

a sign is an object in the Main Hallway Fork. It is scenery. It has the description "This sign says 'Puzzle Room'"

the leaf key is an object. It has the description "A green key in the shape of a leaf with a long stem"

Instead of hinting about leaf key, say "Based on the odd shape, the corresponding door probably has a leaf on it as well."

Chapter 6 - Workshop

Workshop is east of wooden door. Workshop has the description "You enter a clean workshop with an array of tools on the wall and a large workbench."

a workbench is in the Workshop. workbench has the description "A sturdy wooden workbench. It appears to be well used[if WorkbenchCheck is false], but currently has a Whoopee cushion resting on it[end if]." Understand "bench" as workbench. workbench is not portable.

After examining workbench:
	if WorkbenchCheck is false:
		move Whoopee cushion to Workshop;
	now WorkbenchCheck is true;
	continue the action;

a Whoopee cushion is an object. It has the description "It's a novelty cushion that makes a farting sound when sat on...classy"

a slingshot is in the workshop. It has the description "A simple slingshot, but it doesn't appear to come with any ammo"

Instead of hinting about slingshot, say "You can shoot things by saying 'shoot (object) at (object)'"

a manual is in the workshop. It has the description "The manual reads 'Hey Little Timmy! Are you wondering how to rule the schoolyard with your very own slingshot? Simply say 'shoot' an object 'at' another object. If you wanted to shoot a rock at a window, you'd say 'shoot rock at window' It's really that easy, now go cause some mayhem!'"
	
Before examining tools:
	if ToolCheck is false:
		move screwdriver to Workshop;
		move wrench to Workshop;
	now ToolCheck is true;
	continue the action;

tools are in the workshop. tools are scenery. tools have the description "A vast array of tools. You see a screwdriver and a wrench." Understand "walls" and "wall" as tools.

a screwdriver is an object. It has the description "A refreshing drink made out of vodka and orange juice."

Instead of drinking screwdriver, say "While it would be delightful, you have a job to do."

a wrench is an object. It has the description "A normal wrench with the owner's name engraved on it."
	
Chapter 7 - Puzzle Room

Puzzle Room is north of Main Hallway Fork. It has the description "A small room with the walls covered in a large black and red checkerboard pattern, illuminated by a single bulb hanging overhead."

bulb is an object in Puzzle Room. bulb is scenery. It has the description "A single round lightbulb that too hot to touch"

Instead of touching the bulb, say "OUCH!"

a large box is a container in the Puzzle Room. The carrying capacity of the large box is 1. large box is not portable.

pattern is an object in the Puzzle Room. pattern is scenery. pattern has the description "A large checkerboard pattern with alternating red and black squares. Staring deeply into it, the wall appears to get closer and closer, but it's just an illusion." Understand "wall" and "walls" as pattern.

Instead of hinting about large box, say "Place your solution to the clue in the large box.";

a lever is an object in the Puzzle Room. It has the description "A lever marked 'Solve' that you could pull."

Instead of hinting about lever, say "After putting your answer in the box, pull this lever to see if you have the correct answer."

slot is an object in the Puzzle Room. It has the description "A narrow three inch slot. Looking in, you can see mechanisms for pushing paper out."

the red button is an object in the Puzzle Room. red button has the description "A red button on the wall that has 'Clue' printed on it.".

Instead of hinting about red button, say "Press the button to recieve the next clue."

a leaflet is an object in the large box. leaflet has the description "The small paper says[line break]'Welcome to my Manor![line break]Here you will have your wits tested and your funny bone tickled! Simply press the button for a clue, put your answer in the box, and pull the lever.[line break]Happy hunting!'".

Book 2 - Further In

Chapter 1 - Four Seasons Room

Four Seasons Northeast is a room. It has the description "[If remainder after dividing FourSeasonSteps by 4 is 1]There is a large pond shimmering in the heat.[end if][If remainder after dividing FourSeasonSteps by 4 is 2]There is a large pond with some leaves floating in it.[end if][If remainder after dividing FourSeasonSteps by 4 is 3]There is a large frozen pond.[end if][If remainder after dividing FourSeasonSteps by 4 is 0]There is a large pond, complete with lily pads.[end if] There are passages to the west, southwest and south, as well as a door to your east."

In the Four Seasons Northeast is a container called a pond. pond is scenery. It is enterable. It has the description "[If remainder after dividing FourSeasonSteps by 4 is 1]There is a large pond shimmering in the heat.[end if][If remainder after dividing FourSeasonSteps by 4 is 2]There is a large pond with some leaves floating in it.[end if][If remainder after dividing FourSeasonSteps by 4 is 3]There is a large frozen pond.[end if][If remainder after dividing FourSeasonSteps by 4 is 0]There is a large pond, complete with lily pads.[end if][line break][if WentSwimming is false]You see something at the bottom of the pond.[end if]"

lily pads is a object in Four Seasons Northeast. It is scenery. It has the description "[If remainder after dividing FourSeasonSteps by 4 is 1]You can't see any such thing.[end if][If remainder after dividing FourSeasonSteps by 4 is 2]You can't see any such thing.[end if][If remainder after dividing FourSeasonSteps by 4 is 3]You can't see any such thing.[end if][If remainder after dividing FourSeasonSteps by 4 is 0]Lily pads are scattered throughout the surface of the pond[end if]"

Instead of taking lily pads:
	say "There is no reason to disturb their natural beauty."

Understand "exit pond" as exiting.

Instead of entering the pond:
	If remainder after dividing FourSeasonSteps by 4 is 3:
		say "The pond is frozen, you have no means to get in."; 
	otherwise:
		continue the action;

After entering the pond:
	say "You are in the pond in the Four Seasons room. Hopefully you had a reason to go down here.";
	If WentSwimming is false:
		move trunk to the pond;
		say "[line break]There appears to be a trunk at the bottom of the pond";
	now WentSwimming is true;

Before exiting:
	If player is in pond:
		Increment FourSeasonSteps;
		If remainder after dividing FourSeasonSteps by 4 is 3:
			say "Bursting through the ice you emerge back into the room.[if player has trunk][line break]The freezing impact of the ice made you drop the trunk.[end if]";
			if player has trunk:
				move trunk to pond;

Instead of hinting about pond, say "It seems to freeze over every winter, but you should be able to enter it any other season."

a trunk is a object. a trunk has the description "[if PlayerLevel is 10]A trunk that has been forced open, filled with notes that Willy's wife would put in his lunches.[else]A large trunk that has been rusted closed. You see a small note with a heart on it sticking out. Hopefully it will be of some use, even if you can't reach the contents."

Instead of opening a trunk:
	say "The latch on the trunk has been rusted shut."

Four Seasons Northwest is west of Four Seasons Northeast and northwest of Four Seasons Southeast. It has the description "[If remainder after dividing FourSeasonSteps by 4 is 1]There is a large tree with a bee hive hanging from one of its branches. The heat makes the smell of honey palpable.[end if][If remainder after dividing FourSeasonSteps by 4 is 2]There is a large tree whose leaves have changes to a variety of colors. There is a bee hive hanging from one of the branches of the tree.[end if][If remainder after dividing FourSeasonSteps by 4 is 3]There is a large tree, the base of which is covered by a blanket of fresh snow. There is a bee hive that is covered in ice.[end if][If remainder after dividing FourSeasonSteps by 4 is 0]There is a large tree surrounded by beautiful flowers. There is a bee hive hanging from one of the branches of the tree.[end if] There are passages to the east, southeast, and south."

flowers northwest is an object in Four Seasons Northwest. It is scenery. It has the description "The flowers are all daisies, made to be varous colors. You remember their name at the florist: Crazy Daisies."

Instead of taking flowers northwest:
	say "The flowers look so pretty, you decide to not disturb them.";

large tree northwest is an object in Four Seasons Northwest. It is scenery. It has the description "It is a mighty oak tree with a bee hive hanging off a high branch. There are low branches you might be able to climb up.[if remainder after dividing FourSeasonSteps by 4 is 2] The leaves are a plethora of different colors.[end if]"

Instead of climbing large tree northwest:
	if BeeSleep is false:
		say "You climb most of the way, but the buzzing of the bees in the hive makes you lose your nerve and you decend.";
	if BeeSleep is true:
		if GotHoneycomb is true:
			say "There's no reason to go back up the tree";
		if GotHoneycomb is false:
			say "You climb the tree safely, knock a small honeycomb off the hive, and then head back to solid ground.";
			move honeycomb to Four Seasons Northwest;
			now GotHoneycomb is true;

Four Seasons Southwest is south of Four Seasons Northwest and west of Four Seasons Southeast and southwest of Four Seasons Northeast. It has the description "[If remainder after dividing FourSeasonSteps by 4 is 1]There is a large fountain making brown liquid dance in the hot air.[end if][If remainder after dividing FourSeasonSteps by 4 is 2]There is a large fountain of brown liquid, but its difficult to discern the pattern as the tree leaves behind it are a similar hue.[end if][If remainder after dividing FourSeasonSteps by 4 is 3]There is a large fountain with frozen brown liquid covering it in a glaze.[end if][If remainder after dividing FourSeasonSteps by 4 is 0]There is a large fountain making brown liquid dance. There are flowers nearby that occasionally get splashed by the festivities.[end if] There are passages to the north, northeast, and east." 

flowers southwest is an object in Four Seasons Southwest. It is scenery. It has the description "The flowers are all daisies, made to be varous colors. You remember their name at the florist: Crazy Daisies."

Instead of taking flowers southwest:
	say "The flowers look so pretty, you decide to not disturb them.";

Before examining fountain:
	move root beer to Four Seasons Southwest;

fountain is an object. It is in Four Seasons Southwest. It is scenery. It has the description "It is a fountain that inexplicably uses root beer. The owner's exquisite taste knows no bounds."

root beer is an object. It has the description "It is a sugary drink, popular with young children."

Instead of drinking root beer:
	if remainder after dividing FourSeasonSteps by 4 is 3:
		say "It's frozen solid, do you want your tongue to get stuck?";
	else:
		say "Taking a sip, you are reminded of many birthday parties you went to as a child.";

Instead of taking root beer, say "[if remainder after dividing FourSeasonSteps by 4 is 3]The frozen root beer is stuck to the fountain.[else]Good luck trying to grab a stream of liquid!"

Four Seasons Southeast is south of Four Seasons Northeast and southeast of Four Seasons Northwest. It has the description "[If remainder after dividing FourSeasonSteps by 4 is 1]There are a number of trees surrounding you. The sun's blistering rays are blocked by their foliage.[end if][If remainder after dividing FourSeasonSteps by 4 is 2]The trees around you are a masterpiece of orange, yellow and brown.[end if][If remainder after dividing FourSeasonSteps by 4 is 3]You are surrounded by trees stripped of their leaves. Their trunks shield you from the frigid wind.[end if][If remainder after dividing FourSeasonSteps by 4 is 0]You are surrounded by trees with flowers at their base.[end if] There are passages to the west, northwest, and north."

flowers southeast is an object in Four Seasons Southeast. It is scenery. It has the description "The flowers are all daisies, made to be varous colors. You remember their name at the florist: Crazy Daisies."

Instead of taking flowers southeast:
	say "The flowers look so pretty, you decide to not disturb them.";

large tree southeast is an object in Four Seasons Southeast. It is scenery. It has the description "A large tree with a heart carved in it. Inside the heart is [fixed letter spacing] W+B [variable letter spacing]"

a bee hive is an object. It is scenery. It is in Four Seasons Northwest. bee hive has the description "A bee hive that is too high to reach.[if BeeSleep is true] The bees inside are deeply asleep."

Instead of hinting about bee hive:
	say "It contains bees and honey. It is too far to climb up to, but maybe you can bring it down[line break]Would you like another hint?";
	if player consents,
		say "You need to find some way to calm down the bees.";
	otherwise stop the action;

a honeycomb is an object. It has the description "[if PlayerLevel is 10]A beautiful honey glaze on the roast.[else]A honey comb glistening with sweet, sweet honey". Understand "honey" as honeycomb.

Instead of eating honeycomb, say "You go to take a bite, but you stop out of fear that a bee or two are still in there."

Chapter 2 - Pantree

Pantree is east of the Metal Door. Pantree has the description "There is an enormous tree in the center of the room.[if PanInTree is true] There appears to be a gold pan hanging on one of the high branches.[end if] There's also a skylight above the tree showing a full moon."

a skylight is an object. It is scenery. It is in the Pantree. skylight has the description "Looking through the skylight you can see the bare butt cheeks of the owner of the house. Full moon indeed.". Understand "moon" and "full moon" as skylight.

Instead of climbing tree:
	say "The limbs of the tree are too high for you to reach";

the pan tree is an object. It is scenery. It is in Pantree. It has the description "A large tree that has inexplicably been living in this room. The branches reach up as if to plea for more sunlight." Understand "branches", "branch", or "high branch" as tree.

Instead of hinting about pan tree, say "Its trunk and branches are made out of wood, there may be something in the manor well suited for that."

Instead of taking gold pan:
	If PanInTree is False:
		continue the action;
	otherwise:
		say "You can't reach the pan from here"

a gold pan is an object. It has the description "[if PlayerLevel is 10]The pan is warming the roast you retrieved. It's covered in a glaze made from the honey you got.[otherwise if PanInTree is true]A beautiful pan hanging from a high branch on the tree[else]A beautiful pan with a slight dent from your escapade." It is in the Pantree.

Instead of hinting about gold pan, say "You can't knock it down directly, but you may be able to shoot the right object at the tree to free it."

Chapter 3 - Liebrary

Liebrary is a room. It has the description "A large room with walls covered in shelves upon shelves of books. At the center of the room is a large pedestal. The bare wall you just emerged from is to your east."

shelves is an object. It is scenery. It is in the Liebrary. shelves has the description "Getting closer and it seems that the shelves are actually just a very detailed wallpaper on the wall. Outside of the ones on the pedestal, there appear to be no books in the room." Understand "books" and "wall" and "walls" as shelves.

pedestal is a supporter. It is scenery. It has the description "[if TableEx is false]A grand marble pedestal with four books on it. Each book is the same size, shape, and has the same ruggid texture. The only difference is their color, with one being red, one being blue, one being green, and one being yellow.[else]A grand marble pedestal with spaces for four books." It is in the Liebrary.

After examining pedestal:
	if TableEx is false:
		move red book to pedestal;
		move blue book to pedestal;
		move yellow book to pedestal;
		move green book to pedestal;
		now TableEx is true;

the red book is an object. It has the description "[if the player is in Liebrary]It is a red book. Inside it says 'Willy's favorite color is green'.[otherwise]It is a book that says 'Beth Journal.' It's filled with stories about Willy and his wife.".

Instead of hinting about red book, say "It is a red book. It might be helpful to read it."

the blue book is an object. It has the description "[if the player is in Liebrary]It is a bule book. Inside it says 'Willy's favorite color is yellow'.[otherwise]It is a book that says 'Work Journal.' It's filled with stories about his inventions and creations.".

Instead of hinting about blue book, say "It is a blue book. It might be helpful to read it."

the yellow book is an object. It has the description "[if the player is in Liebrary]It is a yellow book. Inside it says 'Willy's favorite color is blue'.[otherwise]It is a book that says 'Joke Journal.' It's filled with jokes that Willy has come up with over the years.".

Instead of hinting about yellow book, say "It is a yellow book. It might be helpful to read it."

the green book is an object. It has the description "[if the player is in Liebrary]It is a green book. Inside it says 'Willy's favorite color is black'.[otherwise]It is a book that says 'Business Journal.' It's filled with a deep history of Willy's business.".

Instead of hinting about green book, say "It is a green book. It might be helpful to read it."

Chapter 4 - Infinity Pool

Instead of going to Infinity Pool when player does not have roast:
		say "You can't enter the Inifinty Pool yet, you forget the roast.";

Infinity Pool is a room. It has the description "You're in a pool that stretches to the horizon in all directions. South is the entrace of the Puzzle Room.". Southwest, west, northwest, northeast, east, southeast of Infinity Pool is Pool Room X. North of Infinity Pool is Deep in Infinity Pool.

Instead of going to Pool Room X:
	say "You swim around aimlessly and eventually end up back at the entrance.";
	move player to Infinity Pool;

Deep in Infinity Pool is a room. It has the description "You're in a pool that stretches to the horizon in all directions.". Southwest, west, northwest, north, northeast, southeast, south of Deep in Infinity Pool is Pool Room X.

Pool Room X is a room. It has the description "If you can read this, something broke."

Deeper in Infinity Pool is a room. It has the description "You're in a pool that stretches to the horizon in all directions.". Southwest, northwest, north, northeast, east, southeast, south of Deeper in Infinity Pool is Pool Room X. Deeper in Infinity Pool is east of Deep in Infinity Pool.

Chapter 5 - End Game

Before going to Lounge:
	now PlayerLevel is 10;

Lounge is a room. It is west of the Deeper in Infinity Pool. It has description "The lounge large room with a box similar to the one in the puzzle room. Willy is standing nearby, ready to greet you. (Use 'greet Willy' and 'ask Willy about (something)' to converse with Willy)"

Willy is a man in Lounge. Willy has the description "Willy is wearing a very loud shirt under a sensible sport coat. You can tell he's trying to look mature, but his wild hair and demeanor make that difficult."

Instead of asking Willy about "towel":
	say "Willy sighs, 'Oh, that brings back memories. That towel was a wedding gift, a simple reminder of our anniversary.'"

Instead of asking Willy about "kitchen towel":
	say "Willy sighs, 'Oh, that brings back memories. That towel was a wedding gift, a simple reminder of our anniversary.'"

Instead of asking Willy about "gold pan":
	say "He says, 'It was a beautiful pan, until you got your hands on it. Still excellent for cooking a special meal.'"

Instead of asking Willy about "pan":
	say "He says, 'It was a beautiful pan, until you got your hands on it. Still excellent for cooking a special meal.'"

Instead of asking Willy about "trunk":
	say "He says, 'While I was working at the company, Beth would put notes in my lunch. I saved all of them, and put them in a trunk. It's nice to go back and read them again from time to time.'"

Instead of asking Willy about "photo":
	say "He explains, 'That was a special night. It was raining, and we had to wait for the bus back to college, so we decided to get some ice cream and take this photo while we waited. I would later propose to her near this spot.'"

Instead of asking Willy about "walking photo":
	say "He explains, 'That was a special night. It was raining, and we had to wait for the bus back to college, so we decided to get some ice cream and take this photo while we waited. I would later propose to her near this spot.'"

Instead of asking Willy about "red book":
	say "He chuckles, 'That was the journal I kept of our relationship. I started it in college thinking I'd make it about all of my relationships, but she was the only one. Guess I was lucky to find her first.'"

Instead of asking Willy about "book":
	say "He chuckles, 'That was the journal I kept of our relationship. I started it in college thinking I'd make it about all of my relationships, but she was the only one. Guess I was lucky to find her first.'"

Instead of asking Willy about "roast":
	say "He tells you, 'That was finished the morning before you got here so it was still fresh. I'm just glad you didn't eat it!'"
		
Instead of asking Willy about "honeycomb/honey":
	say "He smiles, 'Thanks for getting that. I didn't have any in the kitchen and was hoping you'd be vigorous enough to get it. I don't see a sting on you, nice work.'"

Instead of asking Willy about "what is missing":
	say "He shruggs, 'I think everything I asked for is here. Feel free to ask about anything I had you get for me.'"
	
Instead of asking Willy about "what's missing":
	say "He shruggs, 'I think everything I asked for is here. Feel free to ask about anything I had you get for me.'"

Instead of asking Willy about "ants":
	say "Willy's eyes shoot open as he realizes his mistake. 'Was that card still in there?! I meant to get rid of it. Oh no!'[line break][line break]Suddenly, an army of ants crawl menacingly over to the meal, and carry it away. Willy slowly turns to you and says 'Would you be willing to do me another favor?' with a smirk. You consider it, but decide you've had enough fun and games for one day.";
	end the story finally;

Instead of asking Willy about "the ants":
	say "Willy's eyes shoot open as he realizes his mistake. 'Was that card still in there?! I meant to get rid of it. Oh no!'[line break][line break]Suddenly, an army of ants crawl menacingly over to the meal, and carry it away. Willy slowly turns to you and says 'Would you be willing to do me another favor?' with a smirk. You consider it, but decide you've had enough fun and games for one day.";
	end the story finally;

Instead of greeting Willy:
	say "He says 'Thank you so much for getting everything together. It's my anniversary today, and I'm not as young and spry as I used to be.' He steps back with his arm swung out to reveal a beautiful roast in a golden pan with a honey glaze. The trunk is open and filled with notes with hearts on them. The red book is sitting eagerly to be perused through by the couple. The towel is hung with todays date seven years ago embroidered on it, and below it is a photo of Willy and Beth walking around the city eating ice cream. He continues 'You've passed my test! You're welcome to film whenever you'd like. Now, is everything you gathered here?'[line break][line break]You can't shake the feeling that something is missing. You should ask Willy about what is missing.";
	now towel is in Lounge;
	now pan is in Lounge;
	now trunk is in Lounge;
	now walking photo is in Lounge;
	now red book is in Lounge;
	now roast is in Lounge;
	now honeycomb is in Lounge;


Book 3 - Release Instructions

Release along with cover art, source text, a website, an interpreter, a file of "Walkthrough" called "Walkthrough.pdf", a file of "Spoiler Free Map" called "Spoiler Free Map.pdf", and a file of "Spoiler Full Map" called "Spoiler Full Map.pdf".